База данных, которая не база данных

memo1.lines.items[0]:=edit1.text;
//и так до 15
memo1.lines.items[14]:=edit15.text;
//и сохранение
memo1.lines.savetofile('блокнот.nottxt');
//и так же возможность загрузить
memo1.lines.loadfromfile('блокнот.nottxt')
edit1.text:=memo1.lines.items[0];
//и так до 15
edit15.text:=memo1.lines.items[14];

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, XPMan;
 
type
  TForm1 = class(TForm)
    ComboBox1: TComboBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label6: TLabel;
    Edit2: TEdit;
    Edit3: TEdit;
    Edit4: TEdit;
    Edit5: TEdit;
    Edit1: TEdit;
    Label7: TLabel;
    Label8: TLabel;
    Button1: TButton;
    Button4: TButton;
    XPManifest1: TXPManifest;
    Label9: TLabel;
    procedure zgr(ds: integer);
    procedure ComboBox1Change(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
  sg: TStringGrid;
 
implementation
 
{$R *.dfm}
 // Модуль для работы с COM-объектами MS Office
uses
  ComObj;
 
  // Функция чтения данных из XLS(XLSX) файлов и запись их в StringGrid
function Xls_To_StringGrid(AGrid: TStringGrid; AXLSFile: string): Boolean;
const
  xlCellTypeLastCell = $0000000B;
var
  XLApp, Sheet: OLEVariant;
  RangeMatrix: Variant;
  x, y, k, r: Integer;
begin
  Result := False;
  // Создаем MS Excel-OLE объект
  XLApp := CreateOleObject('Excel.Application');
  try
   // Делаем окно MS Excel невидимым
    XLApp.Visible := False;
   // Открываем книгу
    XLApp.Workbooks.Open(AXLSFile);
    Sheet := XLApp.Workbooks[ExtractFileName(AXLSFile)].WorkSheets[1];
   // Чтобы узнать номер рабочего листа, количество строк и столбцов
   // активируем последнюю непустую ячейку
    Sheet.Cells.SpecialCells(xlCellTypeLastCell, EmptyParam).Activate;
   // Получаем значение последней строки
    x := XLApp.ActiveCell.Row;
   // Получаем значение последнего столбца
    y := XLApp.ActiveCell.Column;
   // Задаем кол-во строк и столбцов в Stringgrid
    AGrid.RowCount := x;
    AGrid.ColCount := y;
   // Создаем матрицу, связанную с рабочим листом
    RangeMatrix := XLApp.Range['A1', XLApp.Cells.Item[x, y]].Value;
   //  Определяем цикл для заполнения TStringGrid
    k := 1;
    repeat
      for r := 1 to y do
        AGrid.Cells[(r - 1), (k - 1)] := RangeMatrix[k, r];
      Inc(k, 1);
      AGrid.RowCount := k + 1;
    until k > x;
    // Освобождаем матрицу
    RangeMatrix := Unassigned;
  finally
    // Закрываем MS Excel
    if not VarIsEmpty(XLApp) then
    begin
      // Свойство, которое убирает диалоговые окна, типа "Сохранить файл и т.д."
      // Если значение True - окна будут показаны
      XLApp.DisplayAlerts := False;
      // Закрываем Excel
      XLApp.Quit;
      // Освобождаем XLApp
      XLApp := Unassigned;
      // Освобождаем Sheet
      Sheet := Unassigned;
      // Выводим результат
      Result := True;
    end;
  end;
end;
 
  // Функция чтения данных из StringGrid и запись их в XLS(XLSX) файл
function SgToExcel(aSg: TStringGrid; aExSh: OleVariant; const aRow, aCol: Integer): OleVariant;
var
  vArr: Variant;
  exCell: OleVariant;
  i, j: Integer;
begin
  //Создаём вариантный массив с размером, соответствующим размеру таблицы
  vArr := VarArrayCreate([1, aSg.RowCount, 1, aSg.ColCount], varOleStr);
  //Записываем в вариантный массив данные таблицы
  for i := 1 to aSg.RowCount do
    for j := 1 to aSg.ColCount do
      vArr[i, j] := aSg.Cells[j - 1, i - 1];
  //Ссылка на ячейку, в которой расположится левый верхний угол таблицы
  exCell := aExSh.Cells[aRow, aCol];
  //Определяем диапазон, в который мы запишем данные таблицы
  Result := aExSh.Range[exCell, exCell.Offset[aSg.RowCount - 1, aSg.ColCount - 1]];
  //Записываем данные вариантного массива в диапазон
  Result.Value := vArr;
end;
 
  // Процедура сохранения данных из StringGrid в MS Excel
procedure Save_SG_XLS();
const
  //Толщина линий
  xlThin = 2; //Тонкая линия
  xlMedium = -4138; //Линия средней толщины
  // Тид линии
  xlContinuous = 1; // Непрерывная линия
var
  exApp, exBook, exSh, exRng: OleVariant;
  XLSFile: string;
begin
  // Создаем MS Excel-OLE объект
  exApp := CreateOleObject('Excel.Application');
  // Открываем файл Test.xlsx (находится в папке рядом с программой
  XLSFile := extractFileDir(ParamSTR(0)) + '\test.xlsx';
  // Делаем невидимым окно MS Excel
  exApp.Visible := False;
  // Открываем файл рабочей книги и получаем ссылку на её интерфейс
  exBook := exApp.WorkBooks.Open(XLSFile);
  // Получаем ссылку на интерфейс первого листа рабочей книги
  exSh := exBook.Worksheets[1];
  // Записываем данные из StringGrid на лист MS Excel, начиная с ячейки "A1"
  // Функция возвращает ссылку на интерфейс диапазона, в который записались данные таблицы
  exRng := SgToExcel(sg, exSh, 1, 1);
  // Формируем таблицу - устанавливаем рамку для ячеек таблицы
  exRng.Borders.LineStyle := xlContinuous;
  exRng.Borders.Weight := xlThin;
  // Выравниваем ширину столбцов в XLS документе по содержимому
  exRng.Columns.AutoFit;
  // Сохраняем рабочую книгу
  exBook.Save;
  // Закрываем рабочую книгу
  exBook.Close;
  // Отключаем OLE-объект MS Excel
  exApp.Quit;
  // Освобождаем exApp
  exApp := Unassigned;
end;
 
  // Процедура для заполнения Edit-ов данными из StringGrid
procedure TForm1.zgr(ds: integer);
begin
  Edit1.Text := sg.Rows[ds][0];
  Edit2.Text := sg.Rows[ds][2];
  Edit3.Text := sg.Rows[ds][3];
  Edit4.Text := sg.Rows[ds][4];
  Edit5.Text := sg.Rows[ds][5];
end;
 
  // Изменение выбора строк в StringGrid
procedure TForm1.ComboBox1Change(Sender: TObject);
begin
  zgr(ComboBox1.ItemIndex + 1);
end;
 
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  // Создаем StringGrid
  sg := TStringGrid.Create(self);
  // Делаем созданный StringGrid не видимым
  sg.Visible := false;
  // Читаем файл Text.XLSX и записываем данные из него в StringGrid
  Xls_To_StringGrid(sg, extractFileDir(ParamSTR(0)) + '\test.xlsx');
  // Считаем строки StringGrid
  sg.RowCount := sg.RowCount - 2;
  // Очищаем ComboBox
  Combobox1.Clear;
  // Добавляем записи из 1 столбца из StringGrid в ComboBox
  Combobox1.Items.AddStrings(sg.Cols[1]);
  Combobox1.Items.Delete(0);
  // Показываем в ComboBox индекс со значением 0
  Combobox1.ItemIndex := 0;
  // Выводим количество записей (строк) в документе XLS
  Label9.Caption := 'Всего записей - ' + IntToStr(sg.RowCount - 1);
  zgr(1);
end;
 
// Передача данных из таблицы типа TStringGrid на лист рабочей книги MS Excel.
// Функция возвращает ссылку на интерфейс диапазона MS Excel, в который записалась таблица.
// aSg - экземпляр типа TStringGrid, из которого берутся данные.
// aExSh - ссылка на интерфейс рабочего листа MS Excel, на который следует поместить данные.
// aRow, aCol - координаты ячейки на листе aExSh, начиная с которой следует разместить таблицу.}
 
//Освобождаем созданный StringGrid
procedure TForm1.FormDestroy(Sender: TObject);
begin
  sg.Free;
end;
 
// Добавление в таблицу данных по ячейкам
procedure TForm1.Button1Click(Sender: TObject);
var
  value: string;
begin
  sg.RowCount := sg.RowCount + 1;
  value := InputBox('Марка автомобиля', 'Введите марку автомобиля', '');
  sg.cells[1, sg.RowCount - 1] := value;
  value := InputBox('Владелец автомобиля', 'Введите Ф.И.О. владельца автомобиля', '');
  sg.cells[0, sg.RowCount - 1] := value;
  value := InputBox('Год выпуска автомобиля', 'Введите год выпуска автомобиля', '');
  sg.cells[2, sg.RowCount - 1] := value;
  value := InputBox('Объем двигателя', 'Введите объем двигателя автомобиля', '');
  sg.cells[3, sg.RowCount - 1] := value;
  value := InputBox('Цвет автомобиля', 'Введите цвет автомобиля', '');
  sg.cells[4, sg.RowCount - 1] := value;
  value := InputBox('Пробег автомобиля', 'Введите пробег автомобиля', '');
  sg.cells[5, sg.RowCount - 1] := value;
  Label9.Caption := 'Всего записей в базе - ' + IntToStr(sg.RowCount - 1);
  // Записываем в XLS документ данные, которые были введены в StringGrid
  Save_SG_XLS;
  // Снова открываем уже обновлённый файл XLS
  Xls_To_StringGrid(sg, extractFileDir(ParamSTR(0)) + '\test.xlsx');
  sg.RowCount := sg.RowCount - 2;
  Combobox1.Clear;
  Combobox1.Items.AddStrings(sg.Cols[1]);
  Combobox1.Items.Delete(0);
  Combobox1.ItemIndex := 0;
  // Пересчитываем количество записей в XLS документе
  Label9.Caption := 'Всего записей - ' + IntToStr(sg.RowCount - 1);
  zgr(1);
end;
 
procedure TForm1.Button4Click(Sender: TObject);
begin
  Close;
end;
 
end.

///////////////////////// ДОБАВЛЕНО /////////////////////////////////////////////
 
  // Процедура "Сохранить как" данные из таблицы в XLSX(XLS) файл из StringGrid.
  // Данная процедура необходима для сохранения строк в XLSX документе.
  // Если использовать процедуру Save_SG_XLS, то в файле XLSX(XLS) будет.
  // вместо каждой удаленной строки будет дописываться идущая за ней строка.
  // Отличие от процедуры Save_SG_XLS состоит в том, что XLSX(XLS) документ
  // создается заново и в него заносятся данные после удаления строк и StringGrid.
 
procedure Save_AS_SG_XLS();
const
  //Толщина линий
  xlThin = 2; //Тонкая линия
  xlMedium = -4138; //Линия средней толщины
  // Тип линии
  xlContinuous = 1; // Непрерывная линия
var
  exApp, exBook, exSh, exRng: OleVariant;
begin
  // Создаем MS Excel-OLE объект
  exApp := CreateOleObject('Excel.Application');
  // Делаем невидимым окно MS Excel
  exApp.Visible := False;
  // Убиваем всплывающие сообщения о пересохранении файла
  exApp.DisplayAlerts := False;
  // Открываем файл рабочей книги и получаем ссылку на её интерфейс
  exBook := exApp.WorkBooks.Add;
  // Получаем ссылку на интерфейс первого листа рабочей книги
  exSh := exBook.Worksheets[1];
  // Записываем данные из StringGrid на лист MS Excel, начиная с ячейки "A1"
  // Функция возвращает ссылку на интерфейс диапазона, в который записались данные таблицы
  exRng := SgToExcel(sg, exSh, 1, 1);
  // Формируем таблицу - устанавливаем рамку для ячеек таблицы
  exRng.Borders.LineStyle := xlContinuous;
  exRng.Borders.Weight := xlThin;
  // Выравниваем ширину столбцов в XLS документе по содержимому
  exRng.Columns.AutoFit;
  // Сохраняем рабочую книгу в папку с программой
  exBook.SaveAs(extractFileDir(ParamSTR(0)) + '\test.xlsx');
  // Закрываем рабочую книгу
  exBook.Close;
  // Отключаем OLE-объект MS Excel
  exApp.Quit;
  // Освобождаем exApp
  exApp := Unassigned;
end;
 
  // Процедура внесения изменений в существующих записях
procedure TForm1.Button2Click(Sender: TObject);
var
  // Переменная которая определяет какая строка выбрана
  EdRow: Integer;
begin
  // Значение переменной получаем по индексу, выбираемого в ComboBox + 1
  // FixRow (фиксированная строка) она же заголовок в самой таблице XLS
  EdRow := ComboBox1.ItemIndex + 1;
 // Записываем данные в StringGrid
  // Пишем марку машины - данные из ComboBox1
  sg.cells[1, EdRow] := ComboBox1.Text;
  // Пишем данные о владельце - данные из Edit1
  sg.cells[0, EdRow] := Edit1.Text;
  // Пишем год выпуска - данные из Edit2
  sg.cells[2, EdRow] := Edit2.Text;
  // Пишем год объем двигателя - данные из Edit3
  sg.cells[3, EdRow] := Edit3.Text;
  // Пишем цвет кузова - данные из Edit4
  sg.cells[4, EdRow] := Edit4.Text;
  // Пишем пробег - данные из Edit5
  sg.cells[5, EdRow] := Edit5.Text;
    // Сохраняем изменения
  Save_AS_SG_XLS;
  // Загружаем сохраненный файл Text.XLSX и записываем данные из него в StringGrid
  Xls_To_StringGrid(sg, extractFileDir(ParamSTR(0)) + '\test.xlsx');
  // Считаем строки StringGrid
  sg.RowCount := sg.RowCount - 2;
  // Очищаем ComboBox
  Combobox1.Clear;
  // Добавляем записи из 1 столбца из StringGrid в ComboBox
  Combobox1.Items.AddStrings(sg.Cols[1]);
  Combobox1.Items.Delete(0);
  // Показываем в ComboBox индекс со значением 0
  Combobox1.ItemIndex := 0;
  // Выводим количество записей (строк) в документе XLS
  Label9.Caption := 'Всего записей - ' + IntToStr(sg.RowCount - 1);
  zgr(1);
end;
 
  // Процедура удаления строк в StringGrid
procedure GridDeleteRow(RowNumber: Integer; Grid: TstringGrid);
var
  i: Integer;
begin
  Grid.Row := RowNumber;
  if (Grid.Row = Grid.RowCount - 1) then
    Grid.RowCount := Grid.RowCount - 1
  else
  begin
    for i := RowNumber to Grid.RowCount - 1 do
      Grid.Rows[i] := Grid.Rows[i + 1];
    Grid.RowCount := Grid.RowCount - 1;
  end;
end;
 
  // Удаляем строки в StrnigGrid по индексу
  // Суть работы такова, при нажатии на кнопку удалить, будет удалена
  // та строка, значение которой выбрано в ComboBox
procedure TForm1.Button3Click(Sender: TObject);
var
  // Переменная для определения индекса удаляемой строки
  EdRow, i: integer;
begin
  // Заполняем переменную, ее значение будет индекс ComboBox + 1
  // так как первая строка в StringGrid идет заголовок таблицы.
  EdRow := ComboBox1.ItemIndex + 1;
  //Если осталась одна строка, операцию удаления не выполнять
  if (sg.RowCount = 2) then
    exit;
  // Удаляем выбранную строку
  GridDeleteRow(EdRow, sg);
  // Сохраняем данные которые остались в StringGrid
  Save_AS_SG_XLS;
  // Очищаем StringGrid
  with sg do
    for i := 0 to RowCount - 1 do
      Rows[i].Clear;
  // Загружаем сохраненный файл Text.XLSX и записываем данные из него в StringGrid
  Xls_To_StringGrid(sg, extractFileDir(ParamSTR(0)) + '\test.xlsx');
  // Считаем строки StringGrid
  sg.RowCount := sg.RowCount - 2;
  // Очищаем ComboBox
  Combobox1.Clear;
  // Добавляем записи из 1 столбца из StringGrid в ComboBox
  Combobox1.Items.AddStrings(sg.Cols[1]);
  Combobox1.Items.Delete(0);
  // Показываем в ComboBox индекс со значением 0
  Combobox1.ItemIndex := 0;
  // Выводим количество записей (строк) в документе XLS
  Label9.Caption := 'Всего записей - ' + IntToStr(sg.RowCount - 1);
  zgr(1);
end;