Определенный интеграл

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TIntFunc = function(X: Double): Double;
function TrapezeInt(a, b: Double; eps: Double; IntF: TIntFunc): Double;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
function TrapezeInt(a, b: Double; eps: Double; IntF: TIntFunc): Double;
var
  //S - площадь на предыдущей итерации,
  //x - текущее значение аргумента
  //base - высота трапеции
  //n - число трапеций, удваивается на каждой итерации
  S, x, base: Double;
  i, n: Integer;
begin
  //Сначала приближение одной трапецией
  base := b - a;
  Result := (IntF(a) + IntF(b)) / 2 * base;
  eps := eps / 10; //Вообще говоря, величина делителя зависит от функции
  n := 1;
  repeat
    S := Result;
    base := base / 2;
    n := n * 2;
    //Новая площадь вычисляется на основе старой
    Result := Result / 2;
    //Ниже - просто вычисляем площади новых трапеций
    for i := 1 to n div 2 do
    begin
      x := a + base * (i * 2 - 1);
      Result := Result + IntF(x) * base;
    end;
  until abs(S - Result) <= eps;
end;
 
function intSin(x: Double): Double;
begin
  Result := sin(x);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := FloatToStr(TrapezeInt(0, Pi, 0.00001, intSin));
end;
 
end.