Задан треугольник с точкой, надо узнать, лежит ли точка в треугольнике или нет. Написать на делфи...

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Panel1: TPanel;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
  //Тип, задающий точку.
  TDot = record
    X         : Integer;
    Y         : Integer;
  end;
 
  //Тип, задающий треугольник (ABC).
  TTriangle = record
    A         : TDot;
    B         : TDot;
    C         : TDot;
    //Длина основания.
    Base      : Extended;
  end;
 
  //Тип массива для хранения равносторонних треугольников. Вид массива - динамический.
  TArrTriangle   = array of TTriangle;
  //Указатель на динамический массив треугольников.
  TPArrTriangle  = ^TArrTriangle;
 
const
  //Значение радиана (в градусах):
  Radian         : Extended = 180 / Pi;
  //Точность сравнения углов. В градусах.
  EpsilonAngle   : Extended = 0.001;
 
var
  Form1: TForm1;
 
implementation
 
uses Math;
 
{$R *.dfm}
 
//Рисование на канве.
 
//Рисует треугольник aTri на канве aCanvas.
//При прорисовке применяет масштаб aZoom.
procedure DrawTri(aCanvas : TCanvas; aZoom : Integer; aTri : TTriangle);
begin
  aCanvas.MoveTo(aTri.A.X * aZoom, aTri.A.Y * aZoom);
  aCanvas.LineTo(aTri.B.X * aZoom, aTri.B.Y * aZoom);
  aCanvas.LineTo(aTri.C.X * aZoom, aTri.C.Y * aZoom);
  aCanvas.LineTo(aTri.A.X * aZoom, aTri.A.Y * aZoom);
end;
 
//Рисует точку aDot на канве aCanvas.
//При прорисовке применяет масштаб aZoom.
procedure DrawDot(aCanvas : TCanvas; aZoom : Integer; aDot : TDot);
var
  DotZoom : TDot;
  Rect : TRect;
  LastPenStyle : TPenStyle;
begin
  //Точка с учётом масштаба.
  DotZoom.X := aDot.X * aZoom;
  DotZoom.Y := aDot.Y * aZoom;
 
  //Квадрат который будет изображать точку - чтобы сделать точку более крупной.
  //Это нужно для того чтобы точку было хорошо видно на канве.
  Rect.TopLeft.X      := DotZoom.X - 2;
  Rect.TopLeft.Y      := DotZoom.Y - 2;
  Rect.BottomRight.X  := DotZoom.X + 2;
  Rect.BottomRight.Y  := DotZoom.Y + 2;
  aCanvas.Rectangle(Rect);
 
  //Запоминаем текущий стиль пера.
  LastPenStyle := aCanvas.Pen.Style;
 
  //Устанавливаем стиль в виде пунктирных линий.
  aCanvas.Pen.Style := psDash;
 
  //Рисуем асимптоты.
  aCanvas.MoveTo(0, DotZoom.Y);
  aCanvas.LineTo(DotZoom.X, DotZoom.Y);
  aCanvas.MoveTo(DotZoom.X, 0);
  aCanvas.LineTo(DotZoom.X, DotZoom.Y);
 
  //Возвращаем предыдущий стиль пера.
  aCanvas.Pen.Style := LastPenStyle;
 
end;
 
//Вычисления.
 
//Возвращает значение угла ABC. (В градусах).
function GetAngleABC(aA, aB, aC : TDot) : Extended;
var
  LineBA    : Extended;
  LineBC    : Extended;
  LineAC    : Extended;
  CosABC    : Extended;
begin
 
  // Теорема косинусов:
  //AC^2 = BA^2 + BC^2 - 2*BA*BC*cosABC
  //-> cosABC = (AC^2 - BA^2 - BC^2)/2*BA*BC
  //-> ABC = ArcCos( cosABC ) - В радианах
  //-> ABC = ArcCos( cosABC ) * Radian - В градусах.
 
  LineBA := Sqrt( Sqr(aB.X - aA.X) + Sqr(aB.Y - aA.Y) );
  LineBC := Sqrt( Sqr(aB.X - aC.X) + Sqr(aB.Y - aC.Y) );
  LineAC := Sqrt( Sqr(aA.X - aC.X) + Sqr(aA.Y - aC.Y) );
 
  CosABC := ( - Sqr(LineAC) + Sqr(LineBA) + Sqr(LineBC) ) / ( 2 * LineBA * LineBC );
 
  //Так как функция ArcCos(CosABC) не определена для аргументов CosABC > 1 и CosABC < -1, а при
  //вычисленях с плавающей точкой возможны небольшие "заскоки" за область допустимых значений, то
  //такие случаи предусмотрим в коде.
  if CosABC > 1 then begin
    CosABC := 1;
  end else if CosABC < -1 then begin
    CosABC := -1;
  end;
 
  Result := Radian * ArcCos(CosABC);
 
end;
 
//Проверяет: попадает ли точка aDot внутрь треугольника aTri.
function DotInTriangle(aTri : TTriangle; aDot : TDot) : Boolean;
begin
  //Если точка D расположена внутри треугольника ABC, то выполнятся следующие 3 условия:
  //1. Углы: ABD + CBD = ABC
  //2. Углы: ACD + BCD = ACB
  //3. Углы: BAD + CAD = BAC
  //Если точка D расположена вне треугольника ABC, то какие-то два из трёх приведенных
  //выше условий будут нарушены таким образом:
  //1. Углы: ABD + CBD > ABC
  //2. Углы: ACD + BCD > ACB
  //3. Углы: BAD + CAD > BAC
  //Если при последовательной проверке трёх обнаружено первое нарушение -
  //это однозначно говорит о том, что точка D лежит за пределами треугольника ABC.
  //На этом и построим алгоритм.
  //
  //                     <A>
  //                     /|\
  //                    / | \
  //                   /  |  \
  //                  /   |   \
  //                 /    |    \
  //                /    <D>    \
  //               /   /     \   \
  //              /  /         \  \
  //             / /             \ \
  //            //                 \\
  //          <B>-------------------<C>
 
  Result := False;
 
  //Углы ABD, AСD, BAD неопределены, в случае, если точка D совпадает с любой
  //из вершин треугольника ABC. Поэтому предусмотрим этот случай.
  if
    ( (aTri.A.X = aDot.X) and (aTri.A.Y = aDot.Y) )
    or ( (aTri.B.X = aDot.X) and (aTri.B.Y = aDot.Y) )
    or ( (aTri.C.X = aDot.X) and (aTri.C.Y = aDot.Y) )
  then begin
    Result := True;
    Exit;
  end;
 
  //1. Если углы: ABD + CBD > ABC -> точка D за пределами треугольника.
  if
    Abs(
      GetAngleABC(aTri.A, aTri.B, aDot) + GetAngleABC(aTri.C, aTri.B, aDot)
      - GetAngleABC(aTri.A, aTri.B, aTri.C)
    ) > EpsilonAngle
  then begin
    Exit;
  end;
 
  //2. Если углы: ACD + BCD > ACB -> точка D за пределами треугольника.
  if
    Abs(
      GetAngleABC(aTri.A, aTri.C, aDot) + GetAngleABC(aTri.B, aTri.C, aDot)
      - GetAngleABC(aTri.A, aTri.C, aTri.B)
    ) > EpsilonAngle
  then begin
    Exit;
  end;
 
  //3. Если углы: BAD + CAD > BAC -> точка D за пределами треугольника.
  if
    Abs(
      GetAngleABC(aTri.B, aTri.A, aDot) + GetAngleABC(aTri.C, aTri.A, aDot)
      - GetAngleABC(aTri.B, aTri.A, aTri.C)
    ) > EpsilonAngle
  then begin
    Exit;
  end;
 
  //4. Точка D лежит внутри треугольника.
 
  Result := True;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  //Треугольник.
  Tri            : TTriangle;
  //Точка.
  Dot            : TDot;
begin
 
  Tri.A.X := 1;
  Tri.A.Y := 1;
  Tri.B.X := 1;
  Tri.B.Y := 10;
  Tri.C.X := 10;
  Tri.C.Y := 10;
 
  Dot.X := 3;
  Dot.Y := 5;
 
  //Рисуем точку.
  Image1.Canvas.Pen.Color := RGB(255, 0, 0);
  DrawDot(Image1.Canvas, 30, Dot);
 
  //Треугольник рисуем синим цветом.
  Image1.Canvas.Pen.Color := RGB(0, 0, 255);
  DrawTri(Image1.Canvas, 30, Tri);
 
  if DotInTriangle(Tri, Dot) then begin
    ShowMessage('Заданная точка лежит внутри треугольника');
  end else begin
    ShowMessage('Заданная точка не лежит внутри треугольника');
  end;
 
end;
 
end.

type Tpoint= record
    x:Integer;
    y:Integer;
    end;
var t:array [1..4] of tpoint;
    i:Integer;
    s1,s2,s3,s4:Real;
function s(x1,y1,x2,y2,x3,y3:real):Real;
var a,b,c,p:Real;
begin
a:=sqrt(sqr(x1-x2)+ sqr(y1-y2));
b:=sqrt(sqr(x2-x3)+ sqr(y2-y3));
c:=sqrt(sqr(x3-x1)+ sqr(y3-y1));
p:=(a+b+c)/2;
s:=Sqrt(p*(p-a)*(p-b)*(p-c));
end;
 
begin
 for i:=1 to 4 do
 begin
   Readln(t[i].x);
   Readln(t[i].y);
 end;
 s1:= s(t[1].x,t[1].y,t[2].x,t[2].y,t[3].x,t[3].y);
 s2:= s(t[4].x,t[4].y,t[2].x,t[2].y,t[3].x,t[3].y);
 s3:=s(t[1].x,t[1].y,t[4].x,t[4].y,t[3].x,t[3].y);
 s4:=s(t[1].x,t[1].y,t[2].x,t[2].y,t[4].x,t[4].y);
 
 if Abs(s1-(s2+s3+s4))<0.1 then writeln('Yes')
  else Writeln('no');
 readln;
end.

Function WherePoint(ax,ay,bx,by,px,py:real):integer;
var s :real;
begin
    s:=(bx-ax)*(py-ay)-(by-ay)*(px-ax);
    if s>0 then WherePoint:=1
    else if s<0 then WherePoint:=-1
    else WherePoint:=0;
end;
 
Function PointInsideTreangle(ax,ay,bx,by,cx,cy,px,py:real):boolean;
var s1,s2,s3 :integer;
begin
    PointInsideTreangle:=FALSE;
    s1:=WherePoint(ax,ay,bx,by,px,py);
    s2:=WherePoint(bx,by,cx,cy,px,py);
    if s2*s1<=0 then EXIT;
    s3:=WherePoint(cx,cy,ax,ay,px,py);
    if s3*s2<=0 then EXIT;
    PointInsideTreangle:=TRUE;
end;
 
Begin
   writeln(PointInsideTreangle(1,1,8,1,1,8,2,2)); {Inside}
   writeln(PointInsideTreangle(1,1,8,1,1,8,6,6)); {Outside}
End.