Работа с файловой системой. Поиск файлов, определение размеров файлов и подсчёт среднего арифметического размера.

uses
  FileCtrl;
 
var
  gPath : String = ''; //Путь к папке.
 
//Если размер каждого файла не превышает 2 Гбайт.
procedure TForm1.Button1Click(Sender: TObject);
var
  Sr : TSearchRec;
  Attr, Cnt : Integer;
  SizeSum : Int64;
begin
  //Путь к папке, в которой нужно произвести поиск. Начальное значение выбираем
  //равным пути к той папке, в которой расположена наша программа.
  if gPath = '' then gPath := ExtractFilePath(ParamStr(0));
  //Диалог выбора папки.
  if not SelectDirectory('Выбор папки', '', gPath) then Exit;
  //Если конечный слеш отсутствует, то добавляем его.
  gPath := IncludeTrailingPathDelimiter(gPath);
 
  Memo1.Lines.Add('------------------------------');
  Memo1.Lines.Add('Папка: ' + gPath);
  //Атрибуты - все файлы, исключая тома и папки.
  Attr := faAnyFile - faVolumeID - faDirectory;
  Cnt := 0; //Счётчик найденных файлов.
  SizeSum := 0; //Суммарный размер файлов.
  try
    if FindFirst(gPath + '*', Attr, Sr) = 0 then
    repeat
      Inc(Cnt);
      SizeSum := SizeSum + Sr.Size;
      Memo1.Lines.Add('Размер, байт: ' + IntToStr(Sr.Size) + ', Имя: ' + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
 
  //Ответ.
  Memo1.Lines.Add('---');
  if Cnt > 0 then begin
    Memo1.Lines.Add('Всего файлов: ' + IntToStr(Cnt));
    Memo1.Lines.Add('Суммарный размер файлов, байт: ' + FloatToStr(SizeSum));
    Memo1.Lines.Add('Средний размер файла, байт: ' + FloatToStr(SizeSum/Cnt));
  end
  else
    Memo1.Lines.Add('В папке нет ни одного файла.');
end;

uses
  FileCtrl;
 
var
  gPath : String = ''; //Путь к папке.
 
//Если могут встретиться файлы с размером больше 2 Гбайт.
procedure TForm1.Button1Click(Sender: TObject);
var
  Sr : TSearchRec;
  Attr, Cnt : Integer;
  Size, SizeSum : Int64;
begin
  //Путь к папке, в которой нужно произвести поиск. Начальное значение выбираем
  //равным пути к той папке, в которой расположена наша программа.
  if gPath = '' then gPath := ExtractFilePath(ParamStr(0));
  //Диалог выбора папки.
  if not SelectDirectory('Выбор папки', '', gPath) then Exit;
  //Если конечный слеш отсутствует, то добавляем его.
  gPath := IncludeTrailingPathDelimiter(gPath);
 
  Memo1.Lines.Add('------------------------------');
  Memo1.Lines.Add('Папка: ' + gPath);
  //Атрибуты - все файлы, исключая тома и папки.
  Attr := faAnyFile - faVolumeID - faDirectory;
  Cnt := 0; //Счётчик найденных файлов.
  SizeSum := 0; //Суммарный размер файлов.
  try
    if FindFirst(gPath + '*', Attr, Sr) = 0 then
    repeat
      Inc(Cnt);
      {Размер файла в байтах. Размер представляет собой целое число типа Int64.
      Int64 - это целочисленный тип со знаком, который во внутреннем представлении
      занимает 8 байт. Значение этого типа записано в структуре Sr в виде двух переменных:
      Sr.FindData.nFileSizeHigh - содержит 4 старших байта;
      Sr.FindData.nFileSizeLow - содержит 4 младших байта.}
      Size := Int64(Sr.FindData.nFileSizeHigh) shl 32 + Sr.FindData.nFileSizeLow;
      SizeSum := SizeSum + Size;
      Memo1.Lines.Add('Размер, байт: ' + IntToStr(Size) + ', Имя: ' + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
 
  //Ответ.
  Memo1.Lines.Add('---');
  if Cnt > 0 then begin
    Memo1.Lines.Add('Всего файлов: ' + IntToStr(Cnt));
    Memo1.Lines.Add('Суммарный размер файлов, байт: ' + FloatToStr(SizeSum));
    Memo1.Lines.Add('Средний размер файла, байт: ' + FloatToStr(SizeSum/Cnt));
  end
  else
    Memo1.Lines.Add('В папке нет ни одного файла.');
end;

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, Windows, FileCtrl;
 
var
  Sr : TSearchRec;
  Attr, Cnt : Integer;
  Size, SizeSum : Int64;
  Res : Boolean;
  S, Path : String;
begin
  {Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  Если после переключения русские буквы показываются неверно,
  следует открыть системное меню консольного окна - щелчком мыши в левом
  верхнем углу окна консоли и выбрать:
  Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".}
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  repeat
    Writeln('------------------------------');
    repeat
      Writeln('Задайте путь к папке, в которой следует выполнить поиск:');
      Readln(Path);
      //Если конечный слеш отсутствует, то добавляем его.
      Path := IncludeTrailingPathDelimiter(Path);
      //Проверка существования пути.
      Res := DirectoryExists(Path);
      if not Res then
        Writeln('Заданный путь не найден. Повторите ввод.');
    until Res;
    //Атрибуты - все файлы, исключая тома и папки.
    Attr := faAnyFile - faVolumeID - faDirectory;
    Cnt := 0; //Счётчик найденных файлов.
    SizeSum := 0; //Суммарный размер файлов.
    try
      if FindFirst(Path + '*', Attr, Sr) = 0 then
      repeat
        Inc(Cnt);
        {Размер файла в байтах. Размер представляет собой целое число типа Int64.
        Int64 - это целочисленный тип со знаком, который во внутреннем представлении
        занимает 8 байт. Значение этого типа записано в структуре Sr в виде двух переменных:
        Sr.FindData.nFileSizeHigh - содержит 4 старших байта;
        Sr.FindData.nFileSizeLow - содержит 4 младших байта.}
        Size := Int64(Sr.FindData.nFileSizeHigh) shl 32 + Sr.FindData.nFileSizeLow;
        SizeSum := SizeSum + Size;
        Writeln('Размер, байт: ', Size, ', Имя: ', Sr.Name);
      until FindNext(Sr) <> 0;
    finally
      SysUtils.FindClose(Sr); //"SysUtils." - т. к., в модуле Windows объявлена функция с таким же именем.
    end;
 
    //Ответ.
    Writeln('---');
    if Cnt > 0 then begin
      Writeln('Всего файлов: ', Cnt);
      Writeln('Суммарный размер файлов, байт: ', SizeSum);
      Writeln('Средний размер файла, байт: ', SizeSum/Cnt:0:3);
    end
    else
      Writeln('В папке нет ни одного файла.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.