Синхронизация потоков (Delphi XE6)

@geopos · Регистрация: 16.10.2013

Author24 — интернет-сервис помощи студентам

Вылетает с ошибкой, проблема из синхронизацией.
Возможно я ошибаюсь, но дабы не копировать весь код программы, привел пример кода, который работал на ХЕ5.

Delphi

unit Main;
 
interface
 
uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants, 
  FMX.Types, FMX.Graphics, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.StdCtrls,
  FMX.Layouts, FMX.Memo;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
  end;
 
  TMYThread = class (TTHread)
  private
    FStr: string;
  public
    procedure Execute; override;
    procedure UpdateMemo;
  end;
 
var
  Form1: TForm1;
  NewThread: TMYThread;
 
implementation
 
{$R *.fmx}
 
{ TMYThread }
 
procedure TMYThread.Execute;
var I: Integer;
begin
//  inherited;
  I:= 0;
  while I < High(Integer) do begin
    Inc(I);
    FStr := IntToStr(I);
//    Sleep(10);  // с ним работает
    Synchronize(NewThread,UpdateMemo);
  end;
end;
 
procedure TMYThread.UpdateMemo;
begin
  Form1.Memo1.Lines.Add(NewThread.FStr) ;
  Form1.Memo1.GoToTextEnd;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  NewThread := TMYThread.Create(true);
  NewThread.FreeOnTerminate := true;
  NewThread.Priority := tpLower;
  NewThread.Start;
end;
 
 
 
end.

@krapotkin · 25.04.2014, 07:32

Delphi

1	Synchronize(NewThread,UpdateMemo);

????
в методе класса - ссылка на конкретный экзаемпляр?

Delphi

1	Synchronize(UpdateMemo);

@geopos · 25.04.2014, 11:46 **[ТС]**

Если речь идет про

Delphi

1	Synchronize(UpdateMemo);

, то такой вариант тоже вылетает с ошибкой.
Перепробовал

Delphi

1	Synchronize(nil,UpdateMemo);

и

Delphi

   Synchronize(procedure
     begin
       Form1.Memo1.Lines.Add(NewThread.FStr) ;
       Form1.Memo1.GoToTextEnd;
    end);

в результате - ошибка

@krapotkin · 25.04.2014, 14:01

а так ?

Delphi

1 2	Form1.Memo1.Lines.Add(FStr) ; Form1.Memo1.GoToTextEnd;

@geopos · 25.04.2014, 14:58 **[ТС]**

Особой разницы не увидел - вроде как работает, но если потаскать форму, изменить ее размер и т.д. - ошибка.
Складывается впечатление, что абракадабра через каждые 5 мин. штампует очередные версии делфи, меняя при этом внешний вид, как того требует менеджмент с новыми глюками в придачу, не устраняя старые.

@krapotkin · 26.04.2014, 00:42

Если бы не работал TThread, вообще бы ничего не работало. Это основа основ.
Я активно использую потоки. Жив пока. Вопрос по XE6 конечно может стоять. Но я сильно сомневаюсь...

А я правильно понимаю, что идет запись в Memo 2147483647 строк???
А оно должно влезать вообще?

@geopos · 26.04.2014, 01:11 **[ТС]**

А я правильно понимаю, что идет запись в Memo 2147483647 строк???
А оно должно влезать вообще?

С влезать вообще, я согласен. Но у меня до 1000 может ошибка вылезти, если например скроллом поиграться в мемо.
~~Мне кажется именно Memo1.GotoTextEnd одна из причин~~

@krapotkin · 26.04.2014, 08:12

вот это точно работает на XE5

Delphi

unit Main;
 
interface
 
uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Graphics, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.StdCtrls,
  FMX.Layouts, FMX.Memo;
 
type
  TMYThread = class (TTHread)
  private
    FStr: string;
  public
    procedure Execute; override;
    procedure UpdateMemo;
  end;
 
  TForm1 = class(TForm)
    b1: TButton;
    memo1: TMemo;
    procedure b1Click(Sender: TObject);
    procedure ThreadTerminate(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    NewThread:TMYThread;
    FExit:Boolean;
  public
  end;
 
 
var
  Form1: TForm1;
 
implementation
 
{$R *.fmx}
 
{ TMYThread }
 
procedure TMYThread.Execute;
var I: Integer;
begin
//  inherited;
  I:= 0;
  while (not Terminated) and (I < 5000) do begin
    Inc(I);
    FStr := IntToStr(I);
    Synchronize(UpdateMemo);
  end;
end;
 
procedure TMYThread.UpdateMemo;
begin
  Form1.Memo1.Lines.Add(FStr) ;
  Form1.Memo1.GoToTextEnd;
end;
 
 
procedure TForm1.b1Click(Sender: TObject);
begin
  if NewThread<>NIL then
    Exit;
  NewThread := TMYThread.Create(true);
  NewThread.FreeOnTerminate := true;
  NewThread.Priority := tpLower;
  NewThread.OnTerminate := ThreadTerminate;
  NewThread.Start;
end;
 
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  if NewThread<>NIL then
  begin
    CanClose := false;
    FExit := true;
    NewThread.Terminate;
  end;
end;
 
procedure TForm1.ThreadTerminate(Sender: TObject);
begin
  NewThread := NIL;
  if FExit then
    Close;
end;
 
end.

@geopos · 26.04.2014, 11:38 **[ТС]**

Вот и я про что говорю, а на XE6 не хочет.
В целях обучения буду копать дальше: мьютексы, критические секции, винапи. Хотя насчет первых двух не уверен, потому как TThread уже показал себя.
krapotkin, спасибо. А то я в силу своей неопытности сомневался в себе: обычно глючит между креслом и клавиатурой, а здесь вон оно как получается...

@geopos 0 / 0 / 0 Регистрация: 16.10.2013 Сообщений: 46
	25.04.2014, 14:58 [ТС]	5
	Особой разницы не увидел - вроде как работает, но если потаскать форму, изменить ее размер и т.д. - ошибка. Складывается впечатление, что абракадабра через каждые 5 мин. штампует очередные версии делфи, меняя при этом внешний вид, как того требует менеджмент с новыми глюками в придачу, не устраняя старые. 0

@krapotkin 5786 / 4528 / 1431 Регистрация: 14.04.2014 Сообщений: 20,157 Записей в блоге: 20
	26.04.2014, 00:42	6
	Если бы не работал TThread, вообще бы ничего не работало. Это основа основ. Я активно использую потоки. Жив пока. Вопрос по XE6 конечно может стоять. Но я сильно сомневаюсь... А я правильно понимаю, что идет запись в Memo 2147483647 строк??? А оно должно влезать вообще? 0

@geopos 0 / 0 / 0 Регистрация: 16.10.2013 Сообщений: 46
	26.04.2014, 01:11 [ТС]	7
	А я правильно понимаю, что идет запись в Memo 2147483647 строк??? А оно должно влезать вообще? С влезать вообще, я согласен. Но у меня до 1000 может ошибка вылезти, если например скроллом поиграться в мемо. ~~Мне кажется именно Memo1.GotoTextEnd одна из причин~~ 0

@geopos 0 / 0 / 0 Регистрация: 16.10.2013 Сообщений: 46
	26.04.2014, 11:38 [ТС]	9
	Вот и я про что говорю, а на XE6 не хочет. В целях обучения буду копать дальше: мьютексы, критические секции, винапи. Хотя насчет первых двух не уверен, потому как TThread уже показал себя. krapotkin, спасибо. А то я в силу своей неопытности сомневался в себе: обычно глючит между креслом и клавиатурой, а здесь вон оно как получается... 0