Поиск в Delphi. Написать программу для поиска всех файлов и каталогов, названия которых начинаются на заданную букву

implementation
 
{$R *.dfm}
 
uses
  FileCtrl;
 
type
  TDCh = set of char;
 
var
  gPath : String = ''; //Начальный путь к папке.
 
//Рекурсивная процедура для поиска папок и файлов по заданной маске.
//Папки, которые не удовлетворяют условию поиска тоже выводятся в список,
//но заключаются в скобки. Это нужно для того, чтобы список отражал
//целостную древовидную структуру.
//aPath - начальная папка для поиска.
//aDCh - набор символов с которых должны начинаються имена искомых записей.
//aInd - отступ для показа древовидной структуры.
//aSl - список - потомок класса TStrings, в который добавляются найденные записи.
procedure GetFiles(const aPath : String; const aDCh : TDCh;
  const aInd : String; aSl : TStrings);
var
  Sr : TSearchRec;
  Attr : Integer;
  Path : String;
begin
  //Если завершающего слеша нет, то добавляем его.
  Path := IncludeTrailingPathDelimiter(aPath);
  //Все атрибуты файлов.
  Attr := faAnyFile;
  try
    if FindFirst(Path + '*', Attr, Sr) = 0 then
    repeat
      //Если найдена запись, соответствующая папке.
      if Sr.Attr and faDirectory = faDirectory then begin
        //Если запись не является ссылкой на текущую папку ".." или на
        //родительскую папку ".", то обрабатываем папку и выполняем для неё
        //рекурсивный вызов.
        if not ((Sr.Name = '.') or (Sr.Name = '..')) then begin
          //Папки с именами, удовлетворяющими маске.
          if Sr.Name[1] in aDCh then
            aSl.Add(aInd + Sr.Name + '\')
          //Папки с именами, НЕ удовлетворяющими маске, записываем в скобках.
          else
            aSl.Add(aInd + '( ' + Sr.Name + '\ )');
          //Рекурсивный вызов.
          GetFiles(Path + Sr.Name + '\', aDCh, aInd + '  ', aSl);
        end;
      //Если найдена запись, соответствующая файлу.
      end else if Sr.Name[1] in aDCh then
        aSl.Add(aInd + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  //Путь к папке, в которой нужно произвести поиск. Начальное значение выбираем
  //равным пути к той папке, в которой расположена наша программа.
  if gPath = '' then gPath := ExtractFilePath(ParamStr(0));
  //Диалог выбора папки.
  if not SelectDirectory('Выбор папки', '', gPath) then Exit;
  //Если конечный слеш отсутствует, то добавляем его.
  gPath := IncludeTrailingPathDelimiter(gPath);
 
  Memo1.Clear;
  Memo1.Lines.Add('Маска: все файлы, начинающиеся с букв:');
  Memo1.Lines.Add('русские: "а", "А", английские: "a", "A".');
  Memo1.Lines.Add('Начальная папка:');
  Memo1.Lines.Add(gPath);
  Memo1.Lines.Add('Список:');
  GetFiles(gPath, ['а', 'А', 'a', 'A'], '', Memo1.Lines);
end;
 
end.