Чтение данных из файла типа record

@Makarrrr · Регистрация: 30.01.2014

Author24 — интернет-сервис помощи студентам

Исходные данные

5 кол-во покупателей
Laima Pusyte 4 13 15.5 8 45.4 12 5 31 4
Morka Morkute 1 15 5.1
Jurgis Puskus 2 1 5.4 22 15.78
Petras Rytinis 3 2 45.6 13 125.45 22 45.41
Algis Greitakojis 2 12 444.4 30 2.5

1 столбик-имена
2 столбик-сколько раз он ходил в магазин за один месяц
3,5,7.. столбик-день месяца
4,6,8.. столбик-сколько заплатил в тот день

Нужно считать данные из файла типа record. Сколько не пытался, никак не получается. Помогите придумать считывание для всех случаев, а не для определенного.

Pascal

program Noname1;
const fin='duom2.txt';
    fout='rez2.txt';
type pokupateli=record
    imia:string[20];
    kol:integer;
end;
mas=array[1..100] of pokupateli;
var f,ff:text;
    i,n,j,dni,h:integer;
    a:mas;
//==============================
procedure chtenie;
begin
    assign(f,fin);
    reset(f);
    readln(f,n);
    for i:=1 to n do
        readln(f,a[i].imia,a[i].kol);
        ???
end;

@volvo · 02.04.2014, 03:23

И что надо в массиве record-ов хранить? kol - это что такое?

Добавлено через 14 минут
В общем случае - так:

Pascal

program Noname1;
const fin='duom2.txt';
    fout='rez2.txt';
type pokupateli=record
    imia:string[20];
    kol:integer;
end;
mas=array[1..100] of pokupateli;
var f,ff:text;
    i,n,j,dni,h:integer;
    a:mas;
//==============================
procedure chtenie;
var
  data : integer;
  price : double;
begin
  assign(f,fin);
  reset(f);
  readln(f,n);
  for i:=1 to n do
  begin
    read(f,a[i].imia, a[i].kol);
    writeln(a[i].imia);
    for j := 1 to a[i].kol do
    begin
      read(f, data, price);
      writeln('den : ', data:2, ', price :', price:7:3); // для проверки, что прочиталось действительно все...
    end;
    readln(f);
  end;
end;
 
begin
  chtenie;
end.

На твоем файле выдало:

Bash

Running "d:\test\makarrrr.exe"
Laima Pusyte
den:13, price: 15.500
den: 8, price: 45.400
den:12, price:  5.000
den:31, price:  4.000
Morka Morkute
den:15, price:  5.100
Jurgis Puskus
den: 1, price:  5.400
den:22, price: 15.780
Petras Rytinis
den: 2, price: 45.600
den:13, price:125.450
den:22, price: 45.410
Algis Greitakojis
den:12, price:444.400
den:30, price:  2.500

Можно было обойтись и без указания количества походов в магазин, используя цикл while not eoln(f) - читать до конца строки. Как строка закончилась - переход к следующему покупателю...

Сообщение от Makarrrr

Нужно считать данные из файла типа record

Только это не файл типа record, а совершенно обычный текстовый файл...

@Makarrrr · 02.04.2014, 03:30 **[ТС]**

В массиве record хранить все данные. Понимаю, что не хватает переменных в record, но ничего толкового написать в чтении не получается. Kol- кол-во походов в магазин. Мне к сожалению нужно именно, чтобы данные были типа record

@volvo · 02.04.2014, 11:32

Я написал тебе, как читаются данные из файла. Причем все. Что не устраивает? Надо сделать так, чтобы структура хранила всю прочитанную информацию? Делай так:

Pascal

{$mode objfpc}
 
program Noname1;
uses sysutils;
const fin='duom2.txt';
    fout='rez2.txt';
type
  tshoppingday =
  record
    data:integer;
    price:double;
  end;
  pokupateli=
  record
    imia:string[20];
    kol:integer;
    days:array of tshoppingday;
  end;
 
operator := (rhs : pokupateli) : string;
var
  i : integer;
  sh : tshoppingday;
begin
  with rhs do
  begin
    result := format('%20s %d', [imia, kol]);
    for sh in days do
      result := result + Format(' %d %f', [sh.data, sh.price]);
  end;
end;
 
type
mas=array[1..100] of pokupateli;
var f,ff:text;
    i,n,j,dni,h:integer;
    a:mas;
//==============================
procedure chtenie;
var
  data : integer;
  price : double;
  s : string;
begin
  assign(f,fin);
  reset(f);
  readln(f,n);
  for i:=1 to n do
  begin
    with a[i] do
    begin
      read(f, imia, kol);
      setlength(days, kol);
      for j := 0 to pred(kol) do
      with days[j] do
        read(f, data, price);
 
      s := a[i]; // test
      writeln(s);
      readln(f);
    end;
  end;
end;
 
begin
  chtenie;
end.

, теперь структура хранит всё, включая и все данные о походах в магазин. Или опять что-то не так? Тогда уж говори, что именно, с примером, "как хотелось бы, но это не получается". Или делай сам.

Странные люди, выбрасывают какой-то кусок кода, а потом еще и всё им не так, когда показываешь, как правильно. Хотя сами молчат как рыбы, и непонятно, чего хотят добиться в конечном итоге.

@Makarrrr 0 / 0 / 0 Регистрация: 30.01.2014 Сообщений: 3
	02.04.2014, 03:30 [ТС]	3
	В массиве record хранить все данные. Понимаю, что не хватает переменных в record, но ничего толкового написать в чтении не получается. Kol- кол-во походов в магазин. Мне к сожалению нужно именно, чтобы данные были типа record 0

	02.04.2014, 11:32