Отсортировать последовательность по убыванию и вывести результат на экран

program sequence_of_num;
{задача по заданию https://www.cyberforum.ru/free-pascal/thread1749351.html}
{$mode objfpc}{$H+}
 
 
type
  SeqOfNum = array of integer;
 
  procedure readSeq(out a: SeqOfNum);
  const
    N: integer = 256;
 
  var
    cur, Value: integer;
  begin
    SetLength(a, N);
    cur := 0;
    repeat
      readln(Value);
      if High(a) = cur then
        SetLength(a, Length(a) + N);
      a[cur] := Value;
      Inc(cur);
    until (Value = 0);
    SetLength(a, pred(cur));
  end;
 
  procedure sortMySeq(var a: SeqOfNum); // сортировка пузырьком
  var
    i, p, n: integer;
    b: boolean;
  begin
    n := Length(a);
    if n < 2 then
      exit;
    repeat
      b := False;
      Dec(n);
      if n > 0 then
        for i := 0 to n - 1 do
          if a[i] < a[i + 1] then
          begin
            p := a[i];
            a[i] := a[i + 1];
            a[i + 1] := p;
            b := True;
          end;
    until not b;
  end;
 
  procedure showMySeq(const a: SeqOfNum);
  var
    i, rep, Value: integer;
  begin
    rep := 1;
    Value := a[0];
    Write(Value);
    for i := 1 to High(a) do
    begin
      if a[i] = Value then
      begin
        Inc(rep);
        Continue;
      end;
      if rep > 1 then
      begin
        Write('(', rep, ')');
        rep := 1;
      end;
      Value := a[i];
      Write(' ', Value);
 
    end;
    writeln;
  end;
 
var
  seqStore: SeqOfNum;
begin
  writeln('Enter sequence:');
  readSeq(seqStore);
  sortMySeq(seqStore);
  Write('Result: ');
  showMySeq(seqStore);
  readln;
end.