Определить количество строк матрицы, не содержащих ни одного нулевого элемента

uses  Crt;
const n=5; m=6;
type  Tmatr=array[1..n,1..m] of integer;
function F1(aa:Tmatr;d:integer;ai,aj:integer):boolean;
var   x,y:integer;
      e:boolean;
begin
      e:=false;
       for y:=aj+1 to m do
        if aa[ai,y]=d then
         begin
           e:=true;
           Break
         end;
       if not e then
        for x:=ai+1 to n do
         for y:=1 to m do
          if aa[x,y]=d then
           begin
             e:=true;
             Break;
           end;
        F1:=e;
end;
var   a:Tmatr;
      i,j,t,k,max:integer;
begin
      ClrScr;
      Writeln('Matrix A:'); Writeln; Randomize;
      for i:=1 to n do
       begin
         for j:=1 to m do
          begin
            a[i,j]:=Random(50);
            Write(a[i,j]:4);
          end;
         Writeln;
        end;
       Writeln;
      k:=0; i:=1;
        repeat
           t:=0;
           for j:=1 to m do
            if a[i,j]=0 then Inc(t);
           if t=0 then Inc(k);
           Inc(i);
        until i>n;
       max:=-MaxInt;
        for i:=1 to n do
         for j:=1 to m do
          if a[i,j]>max then
           if F1(a,a[i,j],i,j) then max:=a[i,j];
      if k=0
       then Writeln('Net strok bez noley')
       else Writeln('Bez noley ',k,' strok');
      if max=-MaxInt
       then Writeln('Net max bolee odnogo raza')
       else Writeln('Max bolee odnogo raza = ',max);
      ReadKey;
end.

{$mode objfpc}
uses Crt;
 
const n=5; m=6;
type
  Vector = array[1 .. m] of integer;
  Matrix = array[1 .. n] of Vector;
 
procedure CreateMatrix(var mx : Matrix);
var i, j : integer;
begin
  randomize;
  for i := 1 to n do
    for j := 1 to m do mx[i, j] := random(20);
end;
 
procedure PrintMatrix(mx : Matrix);
var
  v : vector;
  x : integer;
begin
  for v in mx do
  begin
    for x in v do write(x:3);
    writeln;
  end;
end;
 
function CheckZero(row : vector) : boolean;
var x : integer;
begin
  result := true;
  for x in row do result := result and (x <> 0);
end;
 
function MaxVal(mx : Matrix) : integer;
var
  v : vector;
  x : integer;
  s : set of byte;
begin
  result := -(maxint - 1);
  s := [];
 
  for v in mx do
    for x in v do
      if (X in s) and (X > result) then result := x
      else s := s + [X];
end;
 
var
  mx : Matrix;
  v : Vector;
  NonZero : integer = 0;
  Max : integer;
begin
  CreateMatrix(mx);
  PrintMatrix(mx);
  for v in mx do if CheckZero(v) then Inc(NonZero);
  writeln('non-zero rows count: ', NonZero);
 
  max := MaxVal(mx);
  if max = - (maxint - 1) then writeln('no duplicates in matrix')
  else writeln('max duplicated value = ', max);
end.