Спутники Юпитера - просьба поругать/подсказать

program jovi;
uses crt, math,sysutils;
type    sp=record
            x:real;
            n:integer;
            end;
const n=4;
var JD,Dd,ms : real;
        A,B,V,M,Nj,Jr,K,Rz,Rj,Xz_j,Psi,L,L_1,L_2,rab,De,Ds,
        u1,u2,u3,u4,G,H,r1,r2,r3,r4,y1,y2,y3,y4 : extended;
        i,j,c:integer;
        s:array[1..4] of sp;
        x:sp;
 
function mysin(x:extended):extended;
begin
    mysin:=sin(degtorad(x));
end;
    
function mycos(x:extended):extended;
begin
    mycos:=cos(degtorad(x));
end;
 
function MyArcSin(x:extended):extended;
begin
    MyArcSin:=radtodeg(arcsin(x));
end;
 
function adj360(deg:extended):extended;
begin
    while(deg<0)or(deg>360) do
        if deg<0 then deg:=deg+360
        else if deg>360 then deg:=deg-360;
    adj360:=deg;
end;
 
procedure julday;
var Y,M,D,H,min,sec,ms:word;
        A,B:real;
begin
    DeCodeDate (Date,Y,M,D);
    write('Сегодня: ',D);
    if M<10 then
        write('.0',M)
    else
        write('.',M);
    writeln(Y);
    DecodeTime(Time,H,min,sec,ms);
    writeln(H,' часов ',min,' минут');
    if M<2 then
        begin
            Y:=Y-1;
            M:=M+12;
        end;
    Dd:=D+(H+(M/60))/24;        // Часы и доли дня
    A:=trunc(Y/100);
    B:=2-A+trunc(A/4);
    JD:=trunc(365.25*Y)+trunc(30.6001*(M+1))+Dd+1720994.5+B;        // Юлианский день
    writeln('Юлианский день: ',JD:0:1);
    JD:=JD-2415020;
end;
 
 
begin
    G:=0;
    H:=0;
    julday;
    writeln('-------------');
    writeln;
    V:=0.00111587*JD+134.63;            // аргумент долгопериодического члена Юпитера
    M:=358.476+0.9856003*JD;            // средняя аномалия Земли
    M:=adj360(M);
    Nj:=225.328+0.0830853*JD+0.33*mysin(V); //средняя аномалия Юпитера
    Nj:=adj360(Nj);
    Jr:=221.647+0.9025179*JD+0.33*mysin(V); // разность средних гелиоцентрических долгот Земли и Юпитера
    A:=1.916*mysin(M)+0.020*mysin(2*M);     // уравнение центра Земли
    B:=5.552*mysin(Nj)+0.167*mysin(2*Nj);       // уравнение центра Юпитера
    K:=Jr+A-B;                                      // определяем угол
    K:=adj360(K);
    Rz:=1.00014-0.01672*mycos(M)-0.00014*mycos(2*M);    // радиус-вектор Земли
    Rj:=5.20867-0.25192*mycos(Nj)-0.00610*mycos(2*Nj);  // радиус-вектор Юпитера
    Xz_j:=sqrt(sqr(Rj)+sqr(Rz)-2*Rj*Rz*mycos(K));   // расстояние от Земли до Юпитера
    Psi:=MyArcSin((Rz/Xz_j)*mysin(K));      // фазовый угол Юпитера
    if K>0 then
        rab:=0-(57.3*sqr(mysin(Psi/2)))
    else
        rab:=57.3*sqr(mysin(Psi/2));
{ Долгота центрального меридиана Юпитера }
    L_1:=268.28+877.8169088*(JD-Xz_j/173)+Psi-B+rab;        // в системе долгот 1
    L_1:=adj360(L_1);
    L_2:=290.28+870.1869088*(JD-Xz_j/173)+Psi-B+rab;        // в системе долгот 2
    L_2:=adj360(L_2);
    L:=238.05+0.083091*JD+0.33*mysin(V)+B;
    L:=adj360(L);
    Ds:=3.07*mysin(L+44.5);
    De:=Ds-2.15*mysin(Psi)*mycos(L+24)-1.31*((Rj-Xz_j)/Xz_j)*mysin(L-99.4);
    rab:=JD-Xz_j/173;
{ угол, отсчитываемый от нижнего соединения спутников с Юпитером }
    u1:=adj360(84.5506+203.4058630*rab+Psi-B);
    u2:=adj360(41.5015+101.2916323*rab+Psi-B);
    u3:=adj360(109.9770+50.2345169*rab+Psi-B);
    u4:=adj360(176.3586+21.4879802*rab+Psi-B);
{ расстояние спутников от центра Юпитера в единицах его экваториального радиуса }
    r1:=5.9061-0.0244*mycos(2*(u1-u2));
    r2:=9.3972-0.0889*mycos(2*(u2-u3));
    r3:=14.9894-0.0227*mycos(G);
    r4:=26.3649-0.1944*mycos(H);
{ рассчитывам и прибавляем поправки }
    G:=adj360(187.3+50.310674*rab);
    H:=adj360(311.1+21.569229*rab);
    u1:=u1+0.472*mysin(2*(u1-u2));
    u2:=u2+1.073*mysin(2*(u2-u3));
    u3:=u3+0.174*mysin(G);
    u4:=u4+0.846*mysin(H);
{ видимые прямоугольные координаты спутников, взятые относительно центра диска
* Юпитера и выраженные в единицах его экваториального радиуса }
    s[1].x:=r1*mysin(u1);
    s[2].x:=r2*mysin(u2);
    s[3].x:=r3*mysin(u3);
    s[4].x:=r4*mysin(u4);
    y1:=0-r1*mycos(u1)*mysin(De);
    y2:=0-r2*mycos(u2)*mysin(De);
    y3:=0-r3*mycos(u3)*mysin(De);
    y4:=0-r4*mycos(u4)*mysin(De);
    writeln('(еэр) - единицы экваториального радиуса Юпитера');
    writeln('+-------------------------------------------------------------------+');
    writeln('|                         |    Ио   |  Европа  | Ганимед | Каллисто |');
    writeln('+-------------------------------------------------------------------+');
    writeln('| Расстояние спутников от |',r1:7:2,'|':3,r2:8:2,'|':3,r3:8:2,'|':2,r4:8:2,'|':3);
    writeln('| центра Юпитера (еэр)    |         |          |         |          |');
    writeln('+-------------------------------------------------------------------+');
    writeln('| Угол  от нижнего соеди- |',u1:7:2,'|':3,u2:8:2,'|':3,u3:8:2,'|':2,u4:8:2,'|':3);
    writeln('| спутников с Юпитером    |         |          |         |          |');
    writeln('+-------------------------------------------------------------------+');   
    writeln('| Видимые  прямоугольные  |',s[1].x:7:2,'|':3,s[2].x:8:2,'|':3,s[3].x:8:2,'|':2,s[4].x:8:2,'|':3);
    writeln('| координаты X (еэр)      |         |          |         |          |');
    writeln('+-------------------------------------------------------------------+');   
    writeln('| Видимые  прямоугольные  |',y1:7:2,'|':3,y2:8:2,'|':3,y3:8:2,'|':2,y4:8:2,'|':3);
    writeln('| координаты Y (еэр)      |         |          |         |          |');
    writeln('+-------------------------------------------------------------------+');   
//-----------------------------------------------------------
{Честно стырено с форума с согласия автора - Puporev'a}
    for i:=1 to n do
        begin
            s[i].n:=i;
        end;
    for i:=1 to n-1 do
for j:=i+1 to n do
if s[i].x>s[j].x then
 begin
  x:=s[i];
  s[i]:=s[j];
  s[j]:=x;
 end;
c:=40;
ms:=40/(s[n].x-s[1].x+1);
for i:=1 to n do
 begin
  gotoXY(c+round(s[i].x*ms),23);
  write(s[i].n);
 end;
writeln;
for i:=1 to n do
 begin
  gotoXY(c+round(s[i].x*ms),24);
  write('*');
 end;
writeln;
gotoXY(c,24);
write('O');
    
    readkey;
end.