Сортировка массива с использованием указателей.

program Project1;
 
type
  TData = Double;
  TPData = ^TData;
 
{Поиск первого наибольшего элемента в массиве и возвращение указателя на него.
Так как параметр aArr отмечен спецификатором var, то в процедуру будет передан
указатель на объект aArr, а не сам объект aArr. Это называется - передача
параметра по ссылке.
Параметр aArr объявлен, как параметр типа "открытый массив". Через такой
параметр в процедуру можно передавать массивы разных размеров. При этом,
в теле процедуры индексация элементов открытого массива всегда начинается
от нуля: Low(aArr) = 0 - не зависимо от того, как определён диапазон индексов
в вызывающем коде.
Верхний индекс aArr определяется обычным образом через вызов High(aArr).
Нижний индекс Low(aArr), как уже говорилось, для открытого массива
всегда равен нулю.}
function FirstPMax(var aArr : array of TData) : TPData;
var
  PCur, PMax : TPData;
  i : Integer;
begin
  PMax := @aArr;
  PCur := PMax;
  for i := 0 + 1 to High(aArr) do begin
    Inc(PCur);
    if PCur^ > PMax^ then PMax := PCur;
  end;
  FirstPMax := PMax;
end;
 
{Сортировка массива методом пузырька по возрастанию.}
procedure SortAsc(var aArr : array of TData);
var
  PStart, PEnd, PCur, PNext : TPData;
  Data : TData;
begin
  PStart := @aArr;           {Указатель на первый элемент массива.}
  PEnd := @aArr[High(aArr)]; {Указатель на последний элемент массива.}
  while PStart <> PEnd do begin
    PCur := PStart; {Указатель на текущий элемент.}
    PNext := PCur;
    Inc(PNext);     {PNext - указатель на следующий элемент.}
    while PCur <> PEnd do begin
      if PCur^ > PNext^ then begin
        Data := PCur^;
        PCur^ := PNext^;
        PNext^ := Data;
      end;
      {Получаем указатели на следующую пару элементов.}
      Inc(PCur);
      Inc(PNext);
    end;
    Dec(PEnd); {Неотсортированная часть массива уменьшилась на 1 элемент.}
  end;
end;
 
const
  M = 8; {Количество элементов в массиве.}
var
  Arr : array[1..M] of TData;
  PMax : TPData;
  i : Integer;
  S : String;
begin
  repeat
    {Заполняем массив случайными целыми числами и выполняем распечатку.}
    Writeln('Исходный массив:');
    Randomize;
    for i := 1 to High(Arr) do begin
      Arr[i] := Random * 10; {0..9}
      if i > 1 then Write(#9);
      Write(Arr[i]:0:3);
    end;
    Writeln;
 
    {Поиск первого наибольшего элемента.}
    PMax := FirstPMax(Arr);
    Writeln('Первый наибольший элемент: ', PMax^:0:3, ', адрес: ', Longint(PMax));
 
    {Сортировка по возрастанию.}
    SortAsc(Arr);
    Writeln('Массив после сортировки по возрастанию:');
    for i := 1 to High(Arr) do begin
      if i > 1 then Write(#9);
      Write(Arr[i]:0:3);
    end;
    Writeln;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

FUNCTION MaxArray(p: RealPtr; n: WORD; VAR adr: RealPtr): REAL;
VAR
  i: WORD;
BEGIN
  adr := p;
  FOR i := 2 TO n DO
    BEGIN
      Inc(p);
      IF p^ > adr^ THEN
        adr := p;
    END;
  MaxArray := adr^;
END;