Типы, Функции и ввод с клавиатуры

data LibE = Book      {title :: String, author ::  String}
          | Magazine  {title :: String, date   :: (Int, Int)}
          | Newspaper {title :: String, date   :: (Int, Int), day :: Int}
            deriving Show
 
isPeriodic :: LibE -> Bool
isPeriodic (Book _ _) = False
isPeriodic _          = True
 
getByTitle :: String -> [LibE] -> [LibE]
getByTitle t = filter ((t ==) . title)
 
getByMonth :: (Int, Int) -> [LibE] -> [LibE]
getByMonth dt = filter (\t -> isPeriodic t && ok t)
  where ok t = date t == dt
 
getByMonths :: [(Int, Int)] -> [LibE] -> [LibE]
getByMonths dts xs = concatMap (flip getByMonth xs) dts
 
getAuthors :: [LibE] -> [String]
getAuthors = map author . filter (not . isPeriodic)
 
-- База данных с двумя журналами
library :: [LibE]
library = [Magazine "Progz" (1,2011),
           Magazine "Progz" (3,1917)]
 
-- Заранее сформированный запрос к БД
janAndFeb2011Stuff = getByMonths [(01,2011), (02,2011)] library

*Main> janAndFeb2011Stuff
[Magazine {title = "Progz", date = (1,2011)}]

import System.Environment (getArgs)
 
height :: Double -> Double -> Double
height a b = sqrt $ a ^ 2 - b ^ 2 / 4
 
main :: IO ()
main = do args <- getArgs
          case args of [a, b] -> do putStr "Высота, опущенная на основание: "
                                    print $ height (read a) (read b)
                       _      -> putStrLn "Некорректные данные, \
                                          \программа ожидает боковую сторону (a) и основание (b)"

Prelude> :load "sample.hs"
[1 of 1] Compiling Main             ( sample.hs, interpreted )
Ok, modules loaded: Main.
-- Без компиляции
*Main> :main 5 8
Высота, опущенная на основание: 3.0
-- С компиляцией
*Main> :! ghc --make sample.hs
*Main> :! sample.exe 5 8
Высота, опущенная на основание: 3.0
*Main> :! sample.exe 123
Некорректные данные, программа ожидает боковую сторону (a) и основание (b)

height :: Double -> Double -> Double
height a b = sqrt $ a ^ 2 - b ^ 2 / 4
 
main :: IO ()
main = do putStr "Введите боковую сторону: "
          a <- readLn
          putStr "Введите основание: "
          b <- readLn
          putStr "Высота, опущенная на основание: "
          print $ height a b

Prelude> :load "sample.hs"
[1 of 1] Compiling Main             ( sample.hs, interpreted )
Ok, modules loaded: Main.
*Main> :main
Введите боковую сторону: 5
Введите основание: 8
Высота, опущенная на основание: 3.0