ShowBalloonTip не отображает кириллицу

@VcoderB · Регистрация: 02.06.2015

Студворк — интернет-сервис помощи студентам

есть код:

Delphi

procedure ShowBalloonTip(Control: TWinControl; Icon: integer; BackCL, TextCL: TColor; 
Title: String; Text: PWideChar);
const
  TOOLTIPS_CLASS = 'tooltips_class32';
  TTS_ALWAYSTIP = $01;
  TTS_NOPREFIX = $02;
  TTS_BALLOON = $40;
  TTF_SUBCLASS = $0010;
  TTF_TRANSPARENT = $0100;
  TTF_CENTERTIP = $0002;
  TTM_ADDTOOL = $0400 + 50;
  TTM_SETTITLE = (WM_USER + 32);
  ICC_WIN95_CLASSES = $000000FF;
type
  TOOLINFO = packed record
    cbSize: integer;
    uFlags: integer;
    hWnd: THandle;
    uId: integer;
    rect: TRect;
    hinst: THandle;
    lpszText: PWideChar;
    lParam: integer;
  end;
 
var
  hWnd : THandle;
  ti: TOOLINFO;
  hWndTip: THandle;
begin
  if hWndTip <> 0 then  DestroyWindow(hWndTip);
 
  hWnd := Control.Handle;
  hWndTip := CreateWindow(TOOLTIPS_CLASS, nil, WS_POPUP  or TTS_NOPREFIX or TTS_BALLOON or 
  TTS_ALWAYSTIP, 0, 0, 0, 0, hWnd, 0, HInstance, nil);
  if hWndTip <> 0 then begin
    SetWindowPos(hWndTip, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
    ti.cbSize := SizeOf(ti);
    ti.uFlags :=  TTF_SUBCLASS;
    ti.hWnd := hWnd;
    ti.lpszText := PWideChar((Text));
 
    GetClientRect(hWnd, ti.rect);
    SendMessage(hWndTip,TTM_SETDELAYTIME, TTDT_INITIAL ,100);
    SendMessage(hWndTip,TTM_SETDELAYTIME, TTDT_AUTOPOP ,20000);
    if BackCL <> clDefault then SendMessage(hWndTip, TTM_SETTIPBKCOLOR, BackCL, 0);
    if TextCL <> clDefault then SendMessage(hWndTip, TTM_SETTIPTEXTCOLOR, TextCL, 0);
    SendMessage(hWndTip, TTM_ADDTOOL, 1, integer(@ti));
    SendMessage(hWndTip, TTM_SETTITLE, Icon, integer(PWideChar(Title)));
  end;
end;
 
procedure TForm1.Button1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
  ShowBalloonTip(Button1, 0,  2, clRed, 'Балун', 'пример балуна');
end;

с текстом в кодировке ansi никаких проблем, но вот с кириллицей труба. Никак не получается вывести сообщения.

@volvo · 03.04.2016, 02:49

Внимательно читаем комментарии, в процедуру были внесены изменения

Pascal

var
  hWndTip: THandle = 0; // перенес сюда, чтобы компилятор не вякал о неинициализированной переменной
 
procedure ShowBalloonTip(Control: TWinControl; Icon: integer; BackCL, TextCL: TColor;
                         Title: String; Text: string); // передаем строки как обычный String
 
// все описания констант есть в CommCtrl, не нужно дублировать их
 
var
  hWnd : THandle;
  ti: TOOLINFOW; // Юникодная версия !!!
begin
  if hWndTip <> 0 then  DestroyWindow(hWndTip);
 
  hWnd := Control.Handle;
  hWndTip := CreateWindow(TOOLTIPS_CLASS, nil, WS_POPUP  or TTS_NOPREFIX or TTS_BALLOON or
  TTS_ALWAYSTIP, 0, 0, 0, 0, hWnd, 0, HInstance, nil);
  if hWndTip <> 0 then begin
    SetWindowPos(hWndTip, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
    ti.cbSize := SizeOf(ti);
    ti.uFlags :=  TTF_SUBCLASS;
    ti.hWnd := hWnd;
    ti.lpszText := PWideChar(UTF8ToUTF16(Text)); // Вот таким вот образом конвертируем строку в PWideChar
 
    GetClientRect(hWnd, ti.rect);
    SendMessage(hWndTip,TTM_SETDELAYTIME, TTDT_INITIAL ,100);
    SendMessage(hWndTip,TTM_SETDELAYTIME, TTDT_AUTOPOP ,20000);
    if BackCL <> clDefault then SendMessage(hWndTip, TTM_SETTIPBKCOLOR, BackCL, 0);
    if TextCL <> clDefault then SendMessage(hWndTip, TTM_SETTIPTEXTCOLOR, TextCL, 0);
 
    SendMessage(hWndTip, TTM_ADDTOOLW, 1, integer(@ti)); // Здесь тоже Юникодная версия сообщения
    SendMessage(hWndTip, TTM_SETTITLEW, Icon, integer(PWideChar(UTF8ToUTF16(Title)))); // и тут тоже
  end;
end;
 
procedure TForm1.Button1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: integer);
begin
  ShowBalloonTip(Button1, 0, 2, clRed, 'Балун', 'пример балуна');
end;

Чтобы использовать UTF8ToUTF16 нужно подключить LazUTF8 в список Uses. Вот результат:

Опции темы

ShowBalloonTip не отображает кириллицу

Решение