Как синхронно прокручивать два скроллбокса?

uses ..., LMessages;
type
  { TScrollBox }
  TScrollExEvent = procedure(Sender: TObject; var ScrollPos: Integer) of object;
  TScrollBox = class(Forms.TScrollBox)
  strict private
    FOnVScroll: TScrollExEvent;
    FOnHScroll: TScrollExEvent;
  protected
    procedure WMHScroll(var Message : TLMHScroll); message LM_HScroll;
    procedure WMVScroll(var Message : TLMVScroll); message LM_VScroll;
    procedure DoHScroll(var aScrollPos: integer);
    procedure DoVScroll(var aScrollPos: integer);
  published
    property OnVScroll: TScrollExEvent read FOnVScroll write FOnVScroll;
    property OnHScroll: TScrollExEvent read FOnHScroll write FOnHScroll;
  end;
 
// дальше идет класс формы без изменений
  { TForm1 }
  TForm1 = class(TForm)
  // ...
 
 
// реализация методов после Implementation
{ TScrollBox }
procedure TScrollBox.WMHScroll(var Message: TLMHScroll);
begin
  inherited;
  DoHScroll(Message.Pos);
end;
 
procedure TScrollBox.WMVScroll(var Message: TLMVScroll);
begin
  inherited;
  DoVScroll(Message.Pos);
end;
 
procedure TScrollBox.DoHScroll(var aScrollPos: integer);
begin
  if Assigned(FOnHScroll) then FOnHScroll(Self, aScrollPos);
end;
 
procedure TScrollBox.DoVScroll(var aScrollPos: integer);
begin
  if Assigned(FOnVScroll) then FOnVScroll(Self, aScrollPos);
end;

  TForm1 = class(TForm)
  // этой секцией рулит Лазарус
  private
    { private declarations }
  public
    { public declarations }
    procedure MakeVScroll(Sender: TObject; var ScrollPos: Integer); // Вот это !!!
  end;
 
// ...
procedure TForm1.FormCreate(Sender: TObject);
begin
  // связываем между собой оба ScrollBox-а и назначаем им обработчики OnVScroll
  // если нужно - то по той же схеме можно реализовать и обработку горизонтальной прокрутки
 
  ScrollBox1.OnVScroll := @MakeVScroll;
  ScrollBox2.OnVScroll := @MakeVScroll;
  ScrollBox1.Tag := PtrInt(ScrollBox2);
  ScrollBox2.Tag := PtrInt(ScrollBox1);
end;
 
// собственно, самое главное:
procedure TForm1.MakeVScroll(Sender: TObject; var ScrollPos: Integer);
var box : TScrollBox;
begin
  box := Sender as TScrollBox;
  TScrollBox(box.Tag).VertScrollBar.Position := box.VertScrollBar.Position; // выставляем одинаковые позиции
end;