Как задать строгое расположение иконок в трее для своего приложения?

// Для начала - функция, которая вернет True, когда иконка с хинтом "MyMinuteTray" 
// находится ЛЕВЕЕ, чем иконка с хинтом MySecondTray
 
{$IFNDEF UNIX}
function FirstIsMinute : Boolean;
const
  BUFFER_SIZE = $1000;
var
  OpProc : THandle;
  ProcID : THandle;
  ToolBar : THandle;
  ButtonsCount : integer;
  i : Integer;
  Buffer : Pointer;
  DButton : TTBButton;
  RBytes : PtrUInt;
  BTextLength : Integer;
  R : array [-1 .. 1] of Windows.RECT;
  BText :  WideString;
  ix : integer;
begin
  ToolBar := FindWindow('Shell_TrayWnd', nil);
  ToolBar := FindWindowEx(ToolBar, 0, 'TrayNotifyWnd', nil);
  ToolBar := FindWindowEx(ToolBar, 0, 'SysPager', nil);
  ToolBar := FindWindowEx(ToolBar, 0, 'ToolbarWindow32', nil);
  if ToolBar = 0 then Exit;
 
  ButtonsCount := SendMessage(ToolBar, TB_BUTTONCOUNT, 0, 0);
  GetWindowThreadProcessId(ToolBar, @ProcID);
  OpProc := OpenProcess(PROCESS_ALL_ACCESS, False, ProcID);
  try
    Buffer := VirtualAllocEx(OpProc, nil, BUFFER_SIZE, MEM_COMMIT, PAGE_READWRITE);
    for i := 0 to ButtonsCount - 1 do
      begin
        SendMessage(ToolBar, TB_GETBUTTON, i, LPARAM(Buffer));
        RBytes := 0;
        ReadProcessMemory(OpProc, Buffer, @DButton, SizeOf(TTBButton), RBytes);
        BTextLength := SendMessage(ToolBar, TB_GETBUTTONTEXTW, DButton.idCommand, Integer(Buffer));
        SetLength(BText, BTextLength);
        ReadProcessMemory(OpProc, Buffer, @(BText[1]), BTextLength * SizeOf(BText[1]), RBytes);
 
        ix := IndexStr(UTF8Decode(BText), ['MyMinuteTray', 'MySecondTray']);
        if SendMessage(ToolBar, TB_GETITEMRECT, i, LPARAM(Buffer)) > 0 then
        begin
          ReadProcessMemory(OpProc, Buffer, @(R[ix]), SizeOf(Windows.RECT), RBytes);
        end;
      end;
  finally
    VirtualFreeEx(OpProc, Buffer, 0, MEM_RELEASE);
    CloseHandle(OpProc);
  end;
  Result := R[0].Left < R[1].Left;
end;
{$ENDIF}
 
// теперь изменение в обработчике таймера
procedure TForm1.Timer1Timer(Sender: TObject);
var
  bFirstIsMinute : Boolean;
begin
  // получение значения bFirstIsMinute можно, конечно, вынести из таймера, но вдруг Windows возьмет и переупорядочит иконки?
  {$IFDEF UNIX}
    bFirstIsMinute := TrayIcon1.GetPosition.x < TrayIcon2.GetPosition.x; // вот этого достаточно для того, чтобы определить взаимное расположение иконок у меня под Debian-ом (XFCE, если что)
  {$ELSE}
    bFirstIsMinute := FirstIsMinute;
  {$ENDIF}
  Caption := tm.ToString;
  Application.Title := tm.ToString;
  DrawTime(IfThen(bFirstIsMinute, tm div 60, tm mod 60), TrayIcon1); // uses Math для использования этой функции
  DrawTime(IfThen(bFirstIsMinute, tm mod 60, tm div 60), TrayIcon2);
  Dec(tm);
  Timer1.Enabled := tm <> 0;
end;
 
// ну и назначаем хинты:
procedure TForm1.FormCreate(Sender: TObject);
begin
  tm := 380; // время в секундах
  TrayIcon1.Hint := 'MyMinuteTray'; // <---
  TrayIcon2.Hint := 'MySecondTray'; // <---
end;