Микропроцессорная система измерения температуры на TMP-03 и MSC-51

TRANS: ;Подпрограмма преобразования данных
S1 data 44H ;Единицы отображения
S10 data 45H ;Десятки отображания
S100 data 46H ;Сотни оотображения
SN bit 2FH.0 ;Знак числа
T1XH data 47H ;Старший байт результата 200*T1
T1XM data 48H ;Средний байт результата 200*T1
T1XL data 49H ;Младший байт результата 200*T1
call MULT ;Вызов подпрограммы умножения 200 на T1
;Сдвиг T2 на 1 разряд вправо (деление на 2), чтобы домножать надо не на 400(два байта) по спецификации, а на 200 (один байт)
;Поиск величины температуры в Кельвинах
HK data 4AH ;Переменная подбора текущей температуры в кельвин*2
mov HK,#254 ;Задание начальной величины цикла подбора температуры
NK: mov a,#254
clr c
subb a,HK
mov r2,a
mov r0,th1
mov r1,tl1
call MULT2X1
;Сравнение 200T1 и (254-K/2)T2
clr c
mov a,r5
subb a,T1XL
mov a,r4
subb a,T1XM
mov a,r3
subb a,T1XH
jnc FOUND ;если 200T1 стало меньше(254-K/2)T2, то температура найдена
djnz HK,NK
FOUND: clr c ;Сравнение HK c 273/2 (определение знака температуры)
mov a,#137
subb a,HK
jnc POS
NEG: setb SN ;Знак числа - минус
DCG data 4BH ;Градусы Цельсия (по модулю)
;Определение модуля температуры в гр.Цельсия при отрицательной температуре
mov a,#136
clr c
subb a,HK
rlc a
inc a
mov dcg,a
jmp NNN
POS: clr SN ;Знак числа - плюс
;Определение модуля температуры в гр.Цельсия при положительной температуре
mov a,HK
clr c
subb a,#136
rlc a
dec a
mov dcg,a
NNN: ;Выделение сотен, десятков, единиц
mov a,dcg ;Сотни
mov b,#100
div ab
mov S100,a
mov a,b ;Десятки
mov b,#10
div ab
mov S10,a
mov S1,b ;Единицы
ret ;Возврат из подпрограммы
 
 
MULT: ;Подпрограмма умножения на 200 на T1
mov r0,th0
mov r1,tl0
mov r2,#200 ;Подготовка множителя
call MULT2X1 ;Вызов подпрограммы множения 2байтового на однобайтовое число
mov T1XH,r3
mov T1XM,r4
mov T1XL,r5
ret
 
MULT2X1: ;Подпрограммы умножения 2байтового на однобайтовое число
;Первое число R0,R1 Второе число R3 Результат R4, R5, R6
mov a,r1
mov b,r2
mul ab
mov r5,a
mov r4,b
 
mov a,r0
mov b,r2
mul ab
mov r3,b
add a,r4
mov r4,a
mov a,r3
addc a,#0
mov r3,a
ret