Автоматическое изменение количества в одной таблице при выборе позиции из другой таблицы

'КОЛИЧЕСТВО_ТОВАРА  > 0.
'-1 - успешное завершение.
'-3 - необрабатываемая ошибка или слишком большое количество попыток обновления, ошибка передается через объект Err.
 
Public Function ФУНКЦИЯ_УМЕНЬШЕНИЕ_ОСТАТКА_ТОВАРА_БЕЗУСЛОВНОЕ _
    (ByVal КОД_ТОВАРА As Long, ByVal КОД_СКЛАДА As Long, ByVal КОЛИЧЕСТВО_ТОВАРА As Long) _
    As Long
    
    Dim КОЛИЧЕСТВО_ПОПЫТОК As Integer
    
    Dim ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ  As Recordset
        Set ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ = БАЗА_ТАБЛИЦЫ_СИСТЕМЫ.OpenRecordset("Товары_Склады_Остатки", dbOpenTable, 0, dbOptimistic)
        ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Index = "Товар_Склад"
    
        Err.Clear
        For КОЛИЧЕСТВО_ПОПЫТОК = 1 To МАКСИМАЛЬНОЕ_КОЛИЧЕСТВО_ПОПЫТОК
            ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Seek "=", КОД_ТОВАРА, КОД_СКЛАДА
            If ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.NoMatch Then
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.AddNew
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ("Товар_Код") = КОД_ТОВАРА
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ("Склад_Код") = КОД_СКЛАДА
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ("Товар_Остаток") = -КОЛИЧЕСТВО_ТОВАРА
                On Error Resume Next
                    ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Update
                    Select Case Err.Number
                    Case 0
                        On Error GoTo 0
                        ФУНКЦИЯ_УМЕНЬШЕНИЕ_ОСТАТКА_ТОВАРА_БЕЗУСЛОВНОЕ = -1
                        Exit For
                    Case ПОВТОРЯЮЩИЙСЯ_ИНДЕКС
                        Err.Clear
                        On Error GoTo 0
                    Case Else
                        ФУНКЦИЯ_УМЕНЬШЕНИЕ_ОСТАТКА_ТОВАРА_БЕЗУСЛОВНОЕ = -3
                        Exit For
                    End Select
                On Error GoTo 0
            Else
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Edit
                ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ("Товар_Остаток") = ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ("Товар_Остаток") - КОЛИЧЕСТВО_ТОВАРА
                On Error Resume Next
                    ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Update
                    Select Case Err.Number
                    Case 0
                        On Error GoTo 0
                        ФУНКЦИЯ_УМЕНЬШЕНИЕ_ОСТАТКА_ТОВАРА_БЕЗУСЛОВНОЕ = -1
                        Exit For
                    Case КОФЛИКТ_ЗАПИСИ, ЗАПИСЬ_ИЗМЕНЕНА
                        Err.Clear
                        On Error GoTo 0
                    Case Else
                        ФУНКЦИЯ_УМЕНЬШЕНИЕ_ОСТАТКА_ТОВАРА_БЕЗУСЛОВНОЕ = -3
                        Exit For
                    End Select
                On Error GoTo 0
            End If
        Next КОЛИЧЕСТВО_ПОПЫТОК
        If (КОЛИЧЕСТВО_ПОПЫТОК > МАКСИМАЛЬНОЕ_КОЛИЧЕСТВО_ПОПЫТОК) And (Err.Number = 0) Then
            Err.Raise vbObjectError + 1, "Изменение остатка товара", "Не удается изменить остаток товара менее чем за " & МАКСИМАЛЬНОЕ_КОЛИЧЕСТВО_ПОПЫТОК & " попыток."
        End If
        
        
        ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ.Close
        Set ТАБЛИЦА_ТОВАРЫ_СКЛАДЫ_ОСТАТКИ_ЛОКАЛЬНАЯ = Nothing
        
        
    Exit Function
    
End Function