Автоматически сделать повторяющиеся слова в документе гиперссылками на закладку в документе

@ЕвгеНикоСок · Регистрация: 06.05.2016

В документе сделана закладка. В документе слово "хлеб" встречается много раз. Как сделать "хлеба" гиперссылками на эту закладку в документе, но не вручную? ))

@ViterAlex · 08.01.2018, 02:12

Можно попытаться макросом: поиск по тексту закладки со всеми словоформами. Но не уверен.

@Казанский · 08.01.2018, 12:49

ЕвгеНикоСок, попробовал "Все словоформы" - оказалось практически бесполезно (Word 2007).
Вариант с подстановочными знаками - к разным падежам слова "хлеб" гиперссылка добавляется, а словам "нахлебник", "хлебница" - нет.

Visual Basic

Sub Макрос2()
Dim r As Range
  Set r = ActiveDocument.Range
  With r.Find
    .ClearFormatting
    .Text = "<[Хх][Лл][Ее][Бб]*>"
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchAllWordForms = False
    .MatchSoundsLike = False
    .MatchWildcards = True
    While .Execute
      If Len(r.Text) < 7 Then
        ActiveDocument.Hyperlinks.Add Anchor:=r, Address:="", SubAddress:="Закл1" 'имя закладки
        r.Collapse wdCollapseEnd
      End If
    Wend
  End With
End Sub

@Казанский · 24.01.2018, 23:37

По просьбам трудящихся добавил работу только с выделенным диапазоном

Visual Basic

Sub Макрос21()
Dim r As Range, endSel&
  Set r = Selection.Range
  endSel = r.End
  With r.Find
    .ClearFormatting
    .Text = "<[Хх][Лл][Ее][Бб]*>"
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchAllWordForms = False
    .MatchSoundsLike = False
    .MatchWildcards = True
    While .Execute
      If r.End > endSel Then Exit Sub
      If Len(r.Text) < 7 Then
        ActiveDocument.Hyperlinks.Add Anchor:=r, Address:="", SubAddress:="Закл1" 'имя закладки
        r.Collapse wdCollapseEnd
      End If
    Wend
  End With
End Sub

@vivka · 25.01.2018, 01:32

Казанский, пре-пре-преогромнейшее спасибо!
Я - самоучка, и Ваши решения мне очень помогают (думаю, не только мне)!

@ЕвгеНикоСок 0 / 0 / 0 Регистрация: 06.05.2016 Сообщений: 9
		1
	Автоматически сделать повторяющиеся слова в документе гиперссылками на закладку в документе 08.01.2018, 00:58. Показов 2616. Ответов 4 Метки нет (Все метки) В документе сделана закладка. В документе слово "хлеб" встречается много раз. Как сделать "хлеба" гиперссылками на эту закладку в документе, но не вручную? )) __________________ Помощь в написании контрольных, курсовых и дипломных работ, диссертаций здесь 0

@ViterAlex 8907 / 4820 / 1884 Регистрация: 11.02.2013 Сообщений: 10,246
	08.01.2018, 02:12	2
	Можно попытаться макросом: поиск по тексту закладки со всеми словоформами. Но не уверен. 0

@vivka 2 / 2 / 0 Регистрация: 01.10.2015 Сообщений: 39
	25.01.2018, 01:32	5
	Казанский, пре-пре-преогромнейшее спасибо! Я - самоучка, и Ваши решения мне очень помогают (думаю, не только мне)! 0

Опции темы