В чем разница между этими двумя документами ?

Sub mm180908()
Dim fld As Field, j1 As Long
For Each fld In Word.ActiveDocument.Fields
j1 = j1 + 1
Debug.Print j1; Len(fld.Result); fld.Type; fld.Code
fld.Select
''Debug.Print Selection.Range.Font.ColorIndex, Selection.Range.Font.Size
Selection.Range.Font.Size = 12
Selection.Range.Font.ColorIndex = wdRed
Selection.Range.Font.Scaling = 100
Selection.Range.Font.Spacing = 0
 
Next fld
End Sub

Sub макрос()
    
    Dim cursor As Range, chars As String
    ' Знак подчёркивания на конце, чтобы не совпадало с объектом Word.
        ' Иначе не понятно, как это всё состыкуется.
    Dim word_ As Range, text As String, counter As Long
    
    
    ' Символы, между которыми макрос обрабатывает текст.
    chars = " " & Chr(7) & Chr(12) & Chr(13)
    
    ' Отключение монитора (может это ускорит макрос и не будет мерцать).
    Application.ScreenUpdating = False
    
    '1. Установка невидимого курсора в начало файла.
    Set cursor = ActiveDocument.Range(0, 0)
    
    '2. Смещение курсора до первого символа, не являющегося пробелом, разрывом и зна-ком абзаца.
    cursor.MoveWhile Cset:=chars, Count:=wdForward
    
    '3. Движение по файлу.
    Do
        '1) Выделение фрагмента от символа, который не является пробелом, разрывом и зна-ком абзаца, до
            ' пробела, разрыва или знака абзаца.
        cursor.MoveEndUntil Cset:=chars, Count:=wdForward
        
        '2) Присваивание имени "word_" найденному тексту.
            ' Duplicate - чтобы при изменении переменной "word_" не изменялась переменная "cursor".
        Set word_ = cursor.Duplicate
    
        '3) Смещение невидимого курсора вправо, чтобы установить невидимый курсор
            ' после найденного текста, чтобы продолжить движение от невидимого курсора до конца файла.
        cursor.Collapse Direction:=wdCollapseEnd
        
        '4) Проверка, что слово начинается с буквы.
        If Not word_.text Like "[А-Яа-яA-Za-z]*" Then
            GoTo metka_NextWord
        End If
        
        '5) Копирование слова в переменную. С переменной макрос быстрее работает, чем с объектами.
        text = word_.text
        
        '6) Проверка, что в слове не менее 4-х символов. Если справа есть знак препинания,
            ' то он тоже подсчитывается.
        If Len(text) < 4 Then
            GoTo metka_NextWord
        End If
        
        '7) Подсчёт, сколько уже встретилось таких слов.
        counter = counter + 1
        
        '8) Интересует каждое третье слово.
        If counter Mod 3 <> 0 Then
            GoTo metka_NextWord
        End If
        
        '9) Удаление слова и вставка на его место поля.
        With word_.Fields.Add(Range:=word_, Type:=wdFieldEmpty)
            .Code.text = "eq " & text
        End With
        
        '10) Установка невидимого курсора справа от вставленного поля. После вставки поля,
            ' невидимый курсор устанавливается перед вставленнным полем.
        cursor.MoveUntil Cset:=chars, Count:=wdForward
 
metka_NextWord:
 
        '11) Смещение курсора вправо до первого символа, который не являетя пробелом,
            ' разрывом и знаком абзаца. Если будет возвращён 0, значит невидимый
            ' курсор не сдвинулся. Это означает, что достигнут конец файла.
        If cursor.MoveWhile(Cset:=chars, Count:=wdForward) = 0 Then
            Exit Do
        End If
        
    Loop
    
    '4. Сообщение.
    Application.ScreenUpdating = True
    MsgBox "Готово.", vbInformation
 
End Sub