==Автоматизация процесса==

#!/usr/bin/perl
 
use 5.8.8; use strict; use warnings;
use IO::File; use Getopt::Long;
 
 
#####################################################################
# Functions
 
sub main();
sub print_help();
sub do_parselog($$);
sub print_snb($$$);
 
 
######################################################################
# Variables
 
my $debug= 0;
my $program_version= '0.9.0';
 
 
######################################################################
# Start
 
eval { main(); };
if ( $@ ) { print STDERR "$@"; exit 1; }
exit 0;
 
 
#### sub ####
sub main() {
my ($opt_help,$cmd);
 
# Parse arguments
GetOptions( 'help' => \$opt_help, 'verbose+' => \$debug );
if ( defined $opt_help ) { goto print_help; }
if ( scalar( @ARGV ) == 0 ) { goto print_help; }
 
$cmd= $ARGV[0];
if ( $cmd eq "parselog" ) {
    unless ( scalar( @ARGV ) == 3 ) { goto print_help; }
    do_parselog( $ARGV[1], $ARGV[2] );
} else {
    goto print_help;
}
 
# Return
return;
 
print_help:
print_help();
exit 2;
 
} #### main()
 
 
#### sub ####
sub print_help() {
 
print STDERR <<"EOF";
phone_tool.pl $program_version  Copyright (c) 2009 by ODiP
Phone Tool
 
Usage: phone_tool.pl [options] <command>
 
<Commands>
 
Parse logfile:
phone_tool.pl parselog logfile.txt outfile.txt
 
<Options>
--help           print this help
--verbose        increase verbose level
EOF
 
} #### print_help()
 
 
#### sub ####
sub do_parselog($$) {
my ($log_name,$out_name)= @_;
my ($flog,$fout);
my (@snb,$snb_index);
my ($state,$snb,%scl);
 
 
# Init
@snb= ( [], [], [], [] );
 
# Open
$flog= new IO::File $log_name, "<";
unless ( defined $flog ) { die "Error opening $log_name\n"; }
 
# Create
$fout= new IO::File $out_name, ">";
unless ( defined $fout ) { die "Error creating $out_name\n"; }
 
# Loop
$state= 0;
$snb= undef; %scl= ();
for ( ; ; ) {
    $_= $flog->getline(); last unless defined $_;
    chomp;
    if ( /^ +WO +(.*) +PAGE +(\d+)$/ ) { next; }
    if ( $state == 0 ) {
        if ( /^ +SUBSCRIBER DATA$/ ) {
            $state= 1;
            $snb= undef; %scl= ();
        }
    } elsif ( $state == 1 ) {
        if ( /^ +SNB +DEV +DETY +SUT +SCL +MIS +COS$/ ) {
            $state= 2;
        } else {
            die "Invalid format at line $.\n";
        }
    } elsif ( $state == 2 ) {
        if ( /^ +(\d+) +(\S+) +(\S+)$/ ) {
            $state= 3;
            $snb= $1; $scl{$3}= 1;
        } elsif ( /^ +(\d+) +(NC)$/ ) {
            $state= 3;
            $snb= $1; $scl{$2}= 1;
        } else {
            die "Invalid format at line $.\n";
        }
    } elsif ( $state == 3 ) {
        if ( /^ +END$/ ) {
            if ( $debug>=1 ) {
                print $fout "snb=$snb scl=", join( " ", sort keys %scl ), "\n";
            }
 
            # Store
            $snb_index= 0;
            $snb_index+= 1 if exists $scl{"OBA-55"};
            $snb_index+= 2 if exists $scl{"TBI-1"};
            push @{$snb[$snb_index]}, $snb;
 
            $state= 0;
            $snb= undef; %scl= ();
        } elsif ( /^ +(\S+)$/ ) {
            $scl{$1}= 1;
        } elsif ( /^ +$/ ) {
            # Skip
        } else {
            die "Invalid format at line $.\n";
        }
    }
}
 
# Post loop
unless ( $state == 0 ) { die "Invalid format at line $.\n"; }
 
# Print
print_snb( $snb[0], "# No OTB & TBI", $fout );
print_snb( $snb[1], "# OTB", $fout );
print_snb( $snb[2], "# TBI", $fout );
print_snb( $snb[3], "# OTB & TBI", $fout );
 
# Close
$fout->close();
$flog->close();  
 
} #### do_parselog()
 
 
#### sub ####
sub print_snb($$$) {
my ($psnb,$title,$fout)= @_;
 
print $fout $title, "\n";
if ( scalar( @{$psnb} ) > 0 ) {
    print $fout join( "\n", sort @{$psnb} ), "\n", "\n";
} else {
    print $fout "\n";
}
 
} #### print_snb()
 
 
__END__