Динамические структуры данных. Списки

uses
  crt;
type
  PNode = ^TNode;
  TNode = record
  Symb : Char;
  Next : PNode;
  end;
  TList = record
  First, Last : PNode
  end;
//инициация списка  
procedure InitList(var aList : TList);
begin
  aList.First := nil; aList.Last := nil;
end;  
//процедура добавляет символ в список
procedure AddList(var aList : TList; C : Char);
var PElem : PNode;
begin
  New(PElem); 
  PElem^.Symb := C;  
  if aList.First = nil then begin
     aList.First := PElem;
     aList.Last := aList.First;
  end else begin
     aList.Last^.Next := PElem;
     aList.Last := PElem;    
  end;  
  aList.Last^.Next := nil;  
end;  
//выводит список
procedure PrintList(aList : TList);
begin
  if aList.First = nil then begin
    writeln('Список пуст.');
    exit;
  end;
  while aList.First<>nil do begin
    write(aList.First^.Symb:4);
    aList.First := aList.First^.Next;
  end;
  writeln;
end;
//выводит список в обратном порядке
procedure RevPrintList(aList : TList);
var PElem : PNode;
begin
  while aList.Last <> aList.First do begin
  PElem := aList.First;
  while PElem^.Next <> aList.Last do PElem := PElem^.Next;
  write(aList.Last^.Symb:4);
  aList.Last := PElem;
  end;
  writeln(aList.First^.Symb:4);
end;
//вставляет символ в список после заданного адреса
procedure InsElemList(var aList : TList; aPElem : PNode; c : char);
var aPElem1 : PNode;
begin
  New(aPElem1);
  aPElem1^.Symb := C;
  if aList.Last = aPElem then begin
    aList.Last^.Next := aPElem1;
    aList.Last := aPElem1;
    aList.Last^.Next := nil;
  end else begin
    aPElem1^.Next := aPElem^.Next;
    aPElem^.Next := aPElem1;
  end;
end;
var 
  List : TList;
  c : char;
  PElem : PNode;
begin
  clrscr;
  InitList(List);
  repeat
    write('Введите символ : ');
    readln(c);
    AddList(List,c);
    write('Повторить ввод : да - "Enter"; нет - "н"/"n" ');
    c := readkey;
    GotoXY(1,WhereY);
    Clreol;
  until (c='n') or (c='н');
  writeln('Исходный список : ');
  PrintList(List);
  writeln('Список в обратном порядке : ');
  RevPrintList(List);
  PElem := List.First;
  while PElem <> nil do begin
    If (PElem^.Symb = 'A') or (PElem^.Symb = 'А') then 
      InsElemList(List,PElem,'#');
    PElem := PElem^.Next;
  end;
  writeln('После каждого символа "А" символ "#" : ');
  PrintList(List);
  readln;
end.