Выбрать из заданного текста все слова, содержащие заданный символ

program Project1;
 
const
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13]; {Множество разделителей слов.}
var
  S : String;
  Ch : Char;
  i, Len, LenW, Cnt : Integer;
  IsFound : Boolean;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
    Writeln('Задайте символ:');
    Readln(Ch);
 
    Writeln('Перечень слов, которые содержат заданный символ:');
    Len := Length(S); {Длина строки.}
    LenW := 0; {Длина очередного слова.}
    Cnt := 0; {Количество слов, которые содержат заданный символ.}
    IsFound := False; {Обнаружен ли заданный символ в текущем слове?}
    for i := 1 to Len do {Перебор символов строки.}
      {Если символ не является разделителем, значит он принадлежит слову.}
      if not (S[i] in D) then
      begin
        Inc(LenW); {Учитываем очередную букву в длине слова.}
        if S[i] = Ch then {Отслеживаем заданный символ.}
          IsFound := True;
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          {Если в текущем слове заданный символ обнаружен, то распечатываем это слово.}
          if IsFound then
          begin
            Inc(Cnt); {Подсчёт слов, удовлетворяющих условию.}
            if Cnt > 1 then {Печатаем разделитель, если это уже не первое распечатанное слово.}
              Write(', ');
            Write(Copy(S, i - LenW + 1, LenW)); {Распечатка слова.}
          end;
          LenW := 0; {Сброс длины слова.}
          IsFound := False; {Сброс флага.}
        end;
      end;
    Writeln;
    Writeln('Количество слов, которые содержат заданный символ: ', Cnt);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.