Произведение тех чисел, которые в двоичном представлении имеют неравное число нулей и единиц.

program Project1;
 
const
  FileName = 'data.txt';
var
  F : Text;
  (*Счётчик для циклов.*)
  i : Integer;
  (*Cnt < 0 - больше нулей.
  Cnt > 0 - больше единиц.
  Cnt = 0 - равное количество нулей и единиц.*)
  Cnt : Integer;
  (*Переменные для алгоритма перевода между системами счисления.*)
  Num1, Num2 : Integer;
  (*True - есть хотябы одно число с неравным количеством нулей и единиц.
  False - иначе.*)
  IsFound : Boolean;
  (*Произведение чисел, двоичное представление которых содержит неравное
  количество нулей и единиц.*)
  Mult : Integer;
  (*Для алгоритма распечатки двоичного представления и для прочих нужд.*)
  StrTmp : String;
begin
  repeat
    (*Запись в файл случайных целых чисел и показ их на экране.*)
    Assign(F, FileName);
    Rewrite(F); (*Создаём/пересоздаём файл и открываем его для записи.*)
    Writeln('Заданные числа:');
    Randomize;
    for i := 1 to 5 do begin
      Num1 := 1 + Random(10); //Dec: 1..10 -> Bin: 1..1010
      Writeln(F, Num1);
 
      (*Распечатка числа на экране.*)
      Write(Num1:4); (*Десятичное представление.*)
      StrTmp := '';
      repeat
        case Num1 mod 2 of
          0 : StrTmp := '0' + StrTmp;
          1 : StrTmp := '1' + StrTmp;
        end;
        Num1 := Num1 div 2;
      until Num1 = 0;
      Write('(', StrTmp:4, ')'); (*Двоичное представление.*)
    end;
    Writeln;
 
    Reset(F); (*Открываем файл для чтения.*)
    Mult := 1;
    IsFound := False;
    while not Eof(F) do begin
      Readln(F, Num2);
      Num1 := Num2;
      Cnt := 0;
      repeat
        case Num1 mod 2 of
          0 : Cnt := Cnt - 1;
          1 : Cnt := Cnt + 1;
        end;
        Num1 := Num1 div 2;
      until Num1 = 0;
      if Cnt <> 0 then begin
        Mult := Mult * Num2;
        IsFound := True;
      end;
    end;
    Close(F); (*Закрываем файл.*)
 
    if IsFound then
      Writeln('Произведение чисел, которые в двоичном представлении содержат неравное'
        + ' количество нулей и единиц, равно: ', Mult
      )
    else
      Writeln('Не найдено ни одного числа, которое бы в двоичном представлении содержало неравное'
        + ' количество нулей и единиц'
      )
    ;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(StrTmp);
  until StrTmp <> '';
end.