Программа для перевода чисел из 16 сс в 10 сс

program Project1;
 
(*Возвращает число, соответствующее цифре.*)
function DigToNum(const aDig : Char) : Byte;
begin
  case aDig of
    '0' : DigToNum := 0;
    '1' : DigToNum := 1;
    '2' : DigToNum := 2;
    '3' : DigToNum := 3;
    '4' : DigToNum := 4;
    '5' : DigToNum := 5;
    '6' : DigToNum := 6;
    '7' : DigToNum := 7;
    '8' : DigToNum := 8;
    '9' : DigToNum := 9;
    'A', 'a' : DigToNum := 10;
    'B', 'b' : DigToNum := 11;
    'C', 'c' : DigToNum := 12;
    'D', 'd' : DigToNum := 13;
    'E', 'e' : DigToNum := 14;
    'F', 'f' : DigToNum := 15;
  end;
end;
 
(*Возвращает цифру, соответствующую числу.*)
function NumToDig(const aNum : Byte) : Char;
begin
  case aNum of
    0 : NumToDig := '0';
    1 : NumToDig := '1';
    2 : NumToDig := '2';
    3 : NumToDig := '3';
    4 : NumToDig := '4';
    5 : NumToDig := '5';
    6 : NumToDig := '6';
    7 : NumToDig := '7';
    8 : NumToDig := '8';
    9 : NumToDig := '9';
    10 : NumToDig := 'A';
    11 : NumToDig := 'B';
    12 : NumToDig := 'C';
    13 : NumToDig := 'D';
    14 : NumToDig := 'E';
    15 : NumToDig := 'F';
  end;
end;
 
(*Возвращает представление числа в десятичной системе счисления.*)
function HexToDec(const aStrHex : String) : String;
const
  (*Основание шестнадцатиричной системы счисления.*)
  BaseHex = 16;
  (*Основание десятичной системы счисления.*)
  BaseDec = 10;
  (*Точноть перевода дробной части - Prec десятичных цифр после запятой.*)
  Prec = 15;
var
  (*Знак, счётчик для циклов и позиция десятичной точки.*)
  Sign, i, Pos1 : Integer;
  (*Строка с представлением шестнадцатиричной записи без знака и строка
  с представлением десятичной записи без знака.*)
  StrHex, StrDec : String;
  (*Само интересующее нас число, вес разряда и переменная для промежуточных вычислений.*)
  Num, Weight, NumTmp : Extended;
begin
  (*Если на входе пустая строка.*)
  if Length(aStrHex) = 0 then begin
    HexToDec := '';
    Exit;
  end;
 
  (*Определяем знак числа.*)
  if aStrHex[1] = '-' then begin
    Sign := -1;
    StrHex := Copy(aStrHex, 2, Length(aStrHex) - 1);
  end else begin
    Sign := 1;
    StrHex := aStrHex;
  end;
 
  (*Ищем десятичную точку.*)
  Pos1 := Length(StrHex) + 1;
  for i := 1 to Length(StrHex) do begin
    if StrHex[i] in ['.', ','] then begin
      Pos1 := i;
      Break;
    end;
  end;
 
  Num := 0;
 
  (*Учитываем в числе дробную часть шестнадцатиричной записи.*)
  Weight := 1;
  for i := Pos1 + 1 to Length(StrHex) do begin
    Weight := Weight / BaseHex;
    Num := Num + DigToNum(StrHex[i]) * Weight;
  end;
 
  (*Учитываем в числе целую часть шестнадцатиричной записи.*)
  Weight := 1;
  for i := Pos1 - 1 downto 1 do begin
    Num := Num + DigToNum(StrHex[i]) * Weight;
    Weight := Weight * BaseHex;
  end;
 
  (*Переводим полученное число в десятичную систему счисления.*)
 
  StrDec := '';
 
  (*Переводим дробную часть.*)
  NumTmp := Frac(Num);
  i := 0;
  while (NumTmp <> 0) and (i < Prec) do begin
    NumTmp := NumTmp * BaseDec;
    StrDec := StrDec + NumToDig( Round(Int(NumTmp)) );
    NumTmp := Frac(NumTmp);
    Inc(i);
  end;
 
  (*Если дробная часть не нулевая, то добавляем десятичную точку.*)
  if StrDec <> '' then StrDec := '.' + StrDec;
 
  (*Переводим целую часть.*)
  NumTmp := Int(Num);
  repeat
    StrDec := NumToDig( Round(NumTmp) mod BaseDec ) + StrDec;
    NumTmp := Round(NumTmp) div BaseDec;
  until NumTmp = 0;
 
  (*Добавляем сведения о знаке.*)
  if Sign = -1 then StrDec := '-' + StrDec;
 
  HexToDec := StrDec;
end;
 
var
  StrTmp : String;
begin
  repeat
    Writeln('Введите число в шестнадцатиричной системе.');
    Readln(StrTmp);
 
    StrTmp := HexToDec(StrTmp);
 
    Writeln('Запись этого числа в десятичной системе счисления имеет вид:');
    Writeln(StrTmp);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(StrTmp);
  until StrTmp <> '';
end.