Вычислить с заданной точностью, вывести количество итераций

@svenchik · Регистрация: 19.11.2014

Студворк — интернет-сервис помощи студентам

Даны действительные числа x, ε (x не равно 0, ε>0). Вычислить с точностью ε, в конце надо вывести количество итераций, как это сделать?

$https://www.cyberforum.ru/cgi-bin/latex.cgi?\sum_{k=0}^{\infty}\frac{(-1)^kx^{4k+1}}{2k!(4k+1)}$

Pascal

var x,st,sp,eps:real;
k,i,f:integer;
begin
Write ('X=');
readln(x);
Write ('eps=');
readln(eps);
k:=0;
st:=x/1;
repeat
inc(k);
sp:=st;
f:=1;
for i:=1 to 2*k do
f:=f*i;
if k mod 2=0 then st:=st+(exp((4*k+1)*ln(x))/(f*(4*k+1)))
else st:=st+(-exp((4*k+1)*ln(x))/(f*(4*k+1)));
until abs(st-sp)>=eps;
writeln ('Summ=',st:0:2);
readln
end.

@Cyborg Drone · 01.12.2014, 18:42

Сообщение от svenchik

for i:=1 to 2*k do f:=f*i;

В Вашей программе невозможно вычисление более 10 членов, так как более чем 20! в тип integer не помещается. Также при x≤0 программа завершится аварийно из-за попытки вычислить ln(x), который при x≤0 не определён. Похвально, что Вы привели код программы, но, следует признать, что код этот ни на что не пригоден. JokeR.BY в Вашей теме Вычислить сумму ряда с заданной точностью написал для Вас куда как более верный код, вполне удовлетворяющий Вашему заданию. Даже и количество итераций выводится, только не в конце, а при каждой итерации. Чуть подправить - и будет то, что надо. Однако, Вы не приняли код от JokeR.BY во внимание, видимо, по причине Вашей малой осведомлённости. Про рекуррентные соотношения слышали когда-нибудь? Удобная штука. Это когда следующий член последовательности вычисляется, исходя из предыдущего. обычно для этого делится (k+1)-й член на k-й член, либо k-й член выражается через (k+1)-й. Предпочитаю последнее. Итак, находим рекуррентное соотношение.

$https://www.cyberforum.ru/cgi-bin/latex.cgi?S=\sum_{k=0}^\infty\frac{(-1)^kx^{4k+1}}{2k!(4k+1)}=\sum_{k=0}^\infty a_k$

$https://www.cyberforum.ru/cgi-bin/latex.cgi?a_0=x\ ;\ \ a_k=\frac{(-1)^kx^{4k+1}}{2k!(4k+1)}\ ;$

$https://www.cyberforum.ru/cgi-bin/latex.cgi?a_{k+1}=\frac{(-1)^{k+1}x^{4(k+1)+1}}{(2(k+1))!(4(k+1)+1)}=\frac{(-1)^{k+1}x^{4k+5}}{(2k+2)!(4k+5)}=\frac{(-1)(-1)^kx^4x^{4k+1}}{(2k+1)(2k+2)(2k)!(4k+5)}=\\\\=\frac{-x^4(4k+1)a_k}{(2k+1)(2k+2)(4k+5)}=\frac{-x^4(k+0.25)a_k}{4(k+0.5)(k+1)(k+1.25)}$

Рекуррентное соотношение получено. Мой вариант программы, с проверкой корректности входных данных:

Pascal

var k: integer;
    x, a, s, eps: real;
begin
  repeat
    write('x = ');
    readln(x);
    if x = 0 then writeln('Error: x = 0, reenter.')
  until x <> 0;
  repeat
    write('eps = ');
    readln(eps);
    if eps <= 0 then writeln('Error: eps <= 0, reenter.')
  until eps > 0;
  k := 0;
  a := x;
  s := a;
  while abs(a) >= eps do
    begin
      a := -a * x * x * x * x * (k + 0.25) / 4 / (k + 0.5) / (k + 1) / (k + 1.25);
      s := s + a;
      inc(k)
    end;
  writeln('Sum = ', s);
  writeln('Count of iteration = ', k + 1);
  readln
end.

Сумма и количество итераций, естественно, получаются те же самые, что и в программе от JokeR.BY. Я в недоумении. Никак не могу найти причину, по которой Вас не устроила программа от JokeR.BY. Разве что, к Вашей неосведомлённости следует ещё добавить Ваше нежелание в чём-либо разбираться.

	01.12.2014, 18:42

Опции темы