Удалить из списка все элементы с нечетными номерами

@ighor · Регистрация: 13.11.2014

Студворк — интернет-сервис помощи студентам

Можете переделать эту програму так :
дано указатель Р1 на первый элемент двухсвязного списка, содержащего не менее двух элементов. Удалить из списка все элементы с нечетными номерами и вывести указатель на первый элемент преобразованного списка. После удаления элементов освободить память, что они занимали

Pascal

type
  TElement=Integer;
  PNode=^TNode;
  TNode=record
    next: PNode;
    data: TElement;
  end;
 
function NewNode(n: TElement; aNext: PNode): PNode;
var p: PNode;
begin
  New(p);
  with p^ do begin
    next:=aNext; data:=n;
    NewNode:=p;
  end;
end;
 
procedure sPush(var lst: PNode; n: TElement);
begin
  lst:=NewNode(n,lst);
end;
 
function sPop(var lst: PNode): TElement;
var t: PNode;
begin
  if lst=nil then RunError(204);
  with lst^ do begin
   sPop:=data;
   t:=lst; lst:=next; Dispose(t);
  end;
end;
 
procedure sWrite(lst: PNode);
begin
  while lst<>nil do with lst^ do begin
    Write(' ',data); lst:=next;
  end;
end;
 
procedure sDeleteEven(list: PNode);
var t: PNode;
begin
  while (list<>nil) and (list^.next<>nil) do begin
    t:=list^.next;
    list^.next:=list^.next^.next;
    Dispose(t);
    list:=list^.next;
  end;
end;
var
  st: PNode;
  e: TElement;
  i: Integer;
begin
  Randomize;
  for i:=1 to 10 do sPush(st,-Random(101)+50);
  sWrite(st); WriteLn;
  sDeleteEven(st);
  sWrite(st); WriteLn;
  while st<>nil do sPop(st);
end.

@volvo · 28.02.2015, 13:11

Добавь вот такую процедуру:

Pascal

procedure sDeleteOdd(var list : PNode);
var t : PNode;
begin
  if assigned(list) then
  begin
    t := list^.next;
    dispose(list);
    list := t;
    sDeleteEven(list); // и вызывай то, что у тебя уже есть ...
  end;
end;

Только при чем тут двухсвязный список, если у тебя в программе - односвязный?

@ighor · 28.02.2015, 13:56 **[ТС]**

volvo, Если вам не трудно, можете всю программу целеком написать.

@volvo · 28.02.2015, 14:02

Pascal

type
  TElement=Integer;
  PNode=^TNode;
  TNode=record
    next: PNode;
    data: TElement;
  end;
 
function NewNode(n: TElement; aNext: PNode): PNode;
var p: PNode;
begin
  New(p);
  with p^ do begin
    next:=aNext; data:=n;
    NewNode:=p;
  end;
end;
 
procedure sPush(var lst: PNode; n: TElement);
begin
  lst:=NewNode(n,lst);
end;
 
function sPop(var lst: PNode): TElement;
var t: PNode;
begin
  if lst=nil then RunError(204);
  with lst^ do begin
   sPop:=data;
   t:=lst; lst:=next; Dispose(t);
  end;
end;
 
procedure sWrite(lst: PNode);
begin
  while lst<>nil do with lst^ do begin
    Write(' ',data); lst:=next;
  end;
end;
 
procedure sDeleteEven(list: PNode);
var t: PNode;
begin
  while (list<>nil) and (list^.next<>nil) do begin
    t:=list^.next;
    list^.next:=list^.next^.next;
    Dispose(t);
    list:=list^.next;
  end;
end;
procedure sDeleteOdd(var list : PNode);
var t : PNode;
begin
  if assigned(list) then
  begin
    t := list^.next;
    dispose(list);
    list := t;
    sDeleteEven(list);
  end;
end;
 
var
  st: PNode;
  e: TElement;
  i: Integer;
begin
  Randomize;
  for i:=1 to 10 do sPush(st,-Random(101)+50);
  sWrite(st); WriteLn;
  // sDeleteEven(st);
  sDeleteOdd(st);
  sWrite(st); WriteLn;
  while st<>nil do sPop(st);
end.

(тестировалось на FPC 2.6.4)

@Jener · 28.02.2015, 16:14

тоже самое, только для двухсвязного

Pascal

uses
   crt;
type
  TElement=Integer;
 
  PNode=^TNode;
  TNode=record
    prev, next: PNode;
    data: TElement;
  end;
 
function NewNode(n: TElement; pFirst : PNode): PNode;
begin
  If pFirst = nil then begin
    New(pFirst);
    pFirst^.Next := nil; pFirst^.Prev := nil;
  end else begin
    New(pFirst^.Prev);
    pFirst^.Prev^.Next := pFirst;
    pFirst^.Prev^.Prev := nil;
    pFirst := pFirst^.Prev;
  end;
  pFirst^.data := n;
  NewNode := pFirst;
end;
 
procedure sPush(var lst: PNode; n: TElement);
begin
  lst:=NewNode(n,lst);
end;
 
function sPop(var lst: PNode): TElement;
var t : PNode;
begin
  if lst=nil then RunError(204);
  with lst^ do begin
   sPop:=data;
   t:=lst; lst:=next; Prev := nil; Dispose(t);
  end;
end;
 
procedure sWrite(lst: PNode);
begin
  while lst<>nil do begin
    Write(' ',lst^.data);
    lst := lst^.next;
  end;
end;
 
procedure sDeleteEven(lst: PNode);
var t,t1: PNode;
begin
  while (lst<>nil) and (lst^.next<>nil) do begin
    t:=lst^.next;
    t1 := lst;
    lst^.next:=lst^.next^.next;
    Dispose(t);
    lst:=lst^.next;
    if lst<>nil then lst^.prev := t1;
  end;
end;
procedure sDeleteOdd(var lst: PNode);
var t : PNode;
begin
  if lst<>nil then begin
     t := lst;
     lst := lst^.next;
     lst^.prev := nil;
     dispose(t);
     sDeleteEven(lst);
  end;
end;
var
  st: pNode;
  e: TElement;
  i: Integer;
begin
  clrscr;
  st := nil;
  Randomize;
  for i:=1 to 10 do sPush(st,-Random(101)+50);
  sWrite(st); WriteLn;
  sDeleteOdd(st);
  sWrite(st); WriteLn;
  while st<>nil do sPop(st);
  readln;
end.

@ighor 15 / 15 / 21 Регистрация: 13.11.2014 Сообщений: 275
	28.02.2015, 13:56 [ТС]	3
	volvo, Если вам не трудно, можете всю программу целеком написать. 0

Опции темы