Упростить цикл while

{
  Дано натуральное N (1<=N<=10), целочисленный квадратный массив-матрица (aij), 
  0<= i ,j <N. Отсортировать элементы матрицы так, чтобы при прохождении по 
  схеме, они были бы упорядочены по не убыванию. При сортировке элементов 
  не разрешается использовать дополнительные структуры данных (массивы).
  Сортировка вставками «с конца массива».
  
}
 
const m = 10;
var n, v, i, j, p, q, k, t, w, old: integer;
    a: array [0..m-1, 0..m-1] of integer;
 
{процедура вычисления индексов матрицы, исходя из условного номера элемента матрицы}
{согласно указанной схемы (считаем, что матрица пронумерована по змейке от 0 до n * n - 1)}
procedure snake(var x, y: integer; z: integer);
begin
  x := z mod n;  //строка
  y := z div n;  //столбец
  if odd(y) then //если у - нечётный
    x := n - x - 1;
end;
 
begin
  {ввод n}
  repeat
    write('Размер матрицы: n в [1..', m, '];  n = ');
    readln(n)
  until n in [1..m];
  {выводим матрицу }
  randomize;
  writeln('Исходная матрица:');
  for i := 0 to n - 1 do
    begin
      for j := 0 to n - 1 do
        begin
          a[i, j] := random(10);
          write(a[i, j]:5)
        end;
      writeln;
    end;
    
  {сортировка вставками, начиная с конца, змейкой, по неубыванию}
  v := n * n - 1; //последний элемент
  for k := v - 1 downto 0 do //идём к началу инд
    begin
      snake(i, j, k); //найдем коор. индекса К (предыдущ.)
      t := a[i, j];  
      w := k + 1;  //найдём индекс W (последний)
      snake(p, q, w);
      while (w <= v) and (a[p, q] < t) do //пока индекс не выходит за предел и знач. не меньше т
        begin
          snake(i, j, w - 1);  //коорд. в-1
          a[i, j] := a[p, q];  //запишем в в-1 значение в
          old:= w;
          inc(w);  //переход на 1 шаг вперед по змейке
          snake(p, q, w);  //ищем в+1
          //writeln('В цикле: w = ',w,', k = ',k);
        end;
      snake(i, j, w - 1); //ищем в-1 
      //writeln('w = ',w,', k = ',k);
      a[i, j] := t
      
    end;
//запомнить значение с первой итерации и использовать его в следующей    
    
    
  {вывод}
  writeln;
  writeln('Новая матрица:');
  for i := 0 to n - 1 do
    begin
      for j := 0 to n - 1 do write(a[i, j]:5);
      writeln
    end;
end.

  {сортировка вставками, начиная с конца, змейкой, по неубыванию}
  v := n * n - 1;
  for k := v - 1 downto 0 do
    begin
      snake(i, j, k);
      t := a[i, j];
      w := k + 1;
      snake(p, q, w);
      while (w <= v) and (a[p, q] < t) do
        begin
          a[i, j] := a[p, q];
          i := p;
          j := q;
          inc(w);
          snake(p, q, w)
        end;
      a[i, j] := t
    end;

{
  Дано натуральное N (1<=N<=10), целочисленный квадратный массив-матрица (aij), 
  0<= i ,j <N. Отсортировать элементы матрицы так, чтобы при прохождении по 
  схеме, они были бы упорядочены по не убыванию. При сортировке элементов 
  не разрешается использовать дополнительные структуры данных (массивы).
  Сортировка вставками «с конца массива».
  
   |0  7  8  15 |
   |1  6  9  14 | 
   |2  5  10 13 |
   |3  4  11 12 |
  
  Автор - Суворов А.А. 05.11.15
  Вариант 8
  
}
 
const m = 10;
var n, v, i, j, p, q, k, t, w, ptemp, qtemp: integer;
    a: array [0..m-1, 0..m-1] of integer;
 
{процедура вычисления индексов матрицы, исходя из условного номера элемента матрицы}
{согласно указанной схемы (считаем, что матрица пронумерована по змейке от 0 до n * n - 1)}
procedure snake(var x, y: integer; z: integer);
begin
  x := z mod n;  //строка
  y := z div n;  //столбец
  if odd(y) then //если у - нечётный
    x := n - x - 1;
end;
 
begin
  {ввод n}
  repeat
    write('Размер матрицы: n в [1..', m, '];  n = ');
    readln(n)
  until n in [1..m];
  {выводим матрицу }
  randomize;
  writeln('Исходная матрица:');
  for i := 0 to n - 1 do
    begin
      for j := 0 to n - 1 do
        begin
          a[i, j] := random(10);
          write(a[i, j]:5)
        end;
      writeln;
    end;
    
   {сортировка вставками, начиная с конца, змейкой, по неубыванию}
   v := n * n - 1;
   for k := v - 1 downto 0 do
    begin
      snake(i, j, k);
      t := a[i, j];
      w := k + 1;
      snake(p, q, w);
      while (w <= v) and (a[p, q] < t) do
        begin
          a[i, j] := a[p, q];
          i := p;
          j := q;
          inc(w);
          snake(p, q, w)
        end;
      a[i, j] := t
     end;  
    
  {вывод}
  writeln;
  writeln('Новая матрица:');
  for i := 0 to n - 1 do
    begin
      for j := 0 to n - 1 do write(a[i, j]:5);
      writeln
    end;
end.