Даны два массива. Сравнить множество их значений.

uses crt;
const nmax=100;
type mas=array[1..nmax] of 1..100;
     mnoz=set of byte;
{ввода с клавиатуры числового массива}
procedure VvodMas(var a:mas;var n:byte;c:char);
var i:byte;
begin
writeln('Массив ',c);
repeat
write('Размер массива до ',nmax,' n=');
readln(n);
until n in [1..nmax];
writeln('Введите ',n,' элементов массива, чисел от 1 до 100:');
for i:=1 to n do
  repeat
  write('el[',i,']=');
  readln(a[i]);
  until a[i] in [1..100];
clrscr;
end;
{вывода числового массива на экран}
procedure VyvodMas(var a:mas;n:byte;c:char);
var i:byte;
begin
writeln('Массив ',c,':');
for i:=1 to n do
write(a[i]:4);
writeln;
writeln;
end;
{перевода числового массива в числовое множество из тех же элементов}
procedure MasMnz(a:mas;n:byte;var m:mnoz);
var i:byte;
begin
m:=[];
for i:=1 to n do
m:=m+[a[i]];
end;
{вывода числового множества на экран}
procedure VyvodMnz(m:mnoz;c:char);
var i:byte;
begin
writeln('Множество ',c,':');
for i:=1 to 100 do
if i in m then write(i:4);
writeln;
writeln;
end;
var a,b:mas;
    ma,mb:mnoz;
    na,nb:byte;
begin
clrscr;
VvodMas(a,na,'A');
VvodMas(b,nb,'B');
VyvodMas(a,na,'A');
VyvodMas(b,nb,'B');
MasMnz(a,na,ma);
MasMnz(b,nb,mb);
VyvodMnz(ma,'A');
VyvodMnz(mb,'B');
if ma=mb then write('Множества равны')
else if ma-mb=[] then write('Множество А входит в множество В')
else if mb-ma=[] then write('Множество B входит в множество A')
else write('Множества не равны и не являются подмножествами');
readln
end.