Определить, каких букв — гласных или согласных больше в строке

@weh · Регистрация: 01.06.2016

Author24 — интернет-сервис помощи студентам

Задание: Ввести строку, содержащую цифры и буквы латинского алфавита. Определить, каких букв - гласных или согласных больше. Напечатать встречающиеся гласные и согласные, отсутствующие гласные и согласные (каждую по одному разу).

@JokeR.BY · 02.06.2016, 12:50

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
const
    VOWELS: Set Of Char = ['a', 'o', 'e', 'i', 'u', 'y']; //если мне не изменяет память, 'y' может быть и гласной, и согласной
    CONSONANTS: Set Of Char = ['b'..'d', 'f'..'h', 'j'..'n', 'p'..'t', 'v'..'z'];
var
    vowelsCount, consonantsCount, i: Word;
    s: String;
    alphabet: Set Of Char;
    c: Char;
begin
    vowelsCount := 0; consonantsCount := 0;
    alphabet := [#97..#122];
    Write('Input s: '); ReadLn(s);
    for i := 1 to Length(s) do
    begin
        if (s[i] in ['A'..'Z'])
        then
            Inc(s[i], 32);
        if (s[i] in VOWELS)
        then
            Inc(vowelsCount);
        if (s[i] in CONSONANTS)
        then
            Inc(consonantsCount);
        Exclude(alphabet, s[i]);
    end;
    if (vowelsCount > consonantsCount)
    then
        WriteLn('Vowels')
    else
        if (vowelsCount = consonantsCount)
        then
            WriteLn('Equal')
        else
            WriteLn('Consonants');
    Write('String does include: ');
    for c := #97 to #122 do
        if Not (c in alphabet)
        then
            Write(c:2);
    WriteLn;
    Write('String doesn'#39't include:');
    for c := #97 to #122 do
        if (c in alphabet)
        then
            Write(c:2);
    WriteLn;
end.

@bormant · 02.06.2016, 16:39

JokeR.BY,
лучше так:

Pascal
1
2
3
4
5
6
7
const
    VOWELS = ['A', 'O', 'E', 'I', 'U'];
    CONSONANTS = ['A'..'Z']-VOWELS;
...
  s[i]:=UpCase(s[i]);
  if s[i] in VOWELS then Inc(vCount)
  else if s[i] in CONSONANT then Inc(cCount);

В сухом остатке:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
const
  vChar = ['A','O','E','I','U'];
  cChar = ['A'..'Z']-vChar;
var
  vCnt, cCnt, i: Word;
  s: String;
  a: set of Char;
  c: Char;
begin
  Write('Input s: '); ReadLn(s);
  for i:=1 to Length(s) do begin
    s[i]:=UpCase(s[i]); Include(a,s[i]);
    if      s[i] in vChar then Inc(vCnt)
    else if s[i] in cChar then Inc(cCnt);
  end;
  Write('Vowels ');
  if      vCnt>cCnt then Write('>')
  else if vCnt<cCnt then Write('<')
  else                   Write('=');
  WriteLn(' Consonants');
  Write('String does    include: ');
  for c:='A' to 'Z' do if c in a then Write(c); WriteLn;
  Write('String doesn''t include: ');
  for c:='A' to 'Z' do if not (c in a) then Write(c); WriteLn;
end.

Добавлено через 10 минут
Возможно, имелась в виду чуть более подробная статистика:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
const
  aChar = ['A'..'Z'];
  vChar = ['A','O','E','I','U'];
  cChar = aChar-vChar;
var
  vCnt, cCnt, i: Word;
  s: String;
  a, t: set of Char;
  c: Char;
begin
  Write('Input s: '); ReadLn(s);
  for i:=1 to Length(s) do begin
    s[i]:=UpCase(s[i]); Include(a,s[i]);
    if      s[i] in vChar then Inc(vCnt)
    else if s[i] in cChar then Inc(cCnt);
  end;
  Write('Vowels ');
  if      vCnt>cCnt then Write('>')
  else if vCnt<cCnt then Write('<')
  else                   Write('=');
  WriteLn(' Consonants');
  Write('Present vowels: ':30);
  t:=a*vChar; for c:='A' to 'Z' do if c in t then Write(c); WriteLn;
  Write('Present consonants: ':30);
  t:=a*cChar; for c:='A' to 'Z' do if c in t then Write(c); WriteLn;
  Write('Absent vowels: ':30);
  t:=(aChar-a)*vChar; for c:='A' to 'Z' do if c in t then Write(c); WriteLn;
  Write('Absent consonants: ':30);
  t:=(aChar-a)*cChar; for c:='A' to 'Z' do if c in t then Write(c); WriteLn;
end.

Добавлено через 8 минут
или чуть более читаемо:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
type TChars = set of Char;
procedure WriteChars(const t: TChars);
var c: Char;
begin
  for c:='A' to 'Z' do if c in t then Write(c); WriteLn;
end;
const
  aChar = ['A'..'Z'];
  vChar = ['A','O','E','I','U'];
  cChar = aChar-vChar;
var
  vCnt, cCnt, i: Word;
  s: String;
  a: TChars;
begin
  Write('Input s: '); ReadLn(s);
  for i:=1 to Length(s) do begin
    s[i]:=UpCase(s[i]); Include(a,s[i]);
    if      s[i] in vChar then Inc(vCnt)
    else if s[i] in cChar then Inc(cCnt);
  end;
  Write('Vowels (',vCnt,') ');
  if      vCnt>cCnt then Write('>')
  else if vCnt<cCnt then Write('<')
  else                   Write('=');
  WriteLn(' Consonants (',cCnt,')');
  Write('Present vowels: ':30);     WriteChars(vChar*a);
  Write('Absent  vowels: ':30);     WriteChars(vChar*(aChar-a));
  Write('Present consonants: ':30); WriteChars(cChar*a);
  Write('Absent  consonants: ':30); WriteChars(cChar*(aChar-a));
end.

Новые блоги и статьи Все статьи Все блоги /
Реализация Domain-Driven Design с Java Javaican 20.05.2025 DDD — это настоящий спасательный круг для проектов со сложной бизнес-логикой. Подход, предложенный Эриком Эвансом, позволяет создавать элегантные решения, которые точно отражают реальную предметную. . .	Возможности и нововведения C# 14 stackOverflow 20.05.2025 Выход версии C# 14, который ожидается вместе с . NET 10, приносит ряд интересных нововведений, действительно упрощающих жизнь разработчиков. Вы уже хотите опробовать эти новшества? Не проблема! Просто. . .	Собеседование по Node.js - вопросы и ответы Reangularity 20.05.2025 Каждому разработчику рано или поздно приходится сталкиватся с техническими собеседованиями - этим стрессовым испытанием, где решается судьба карьерного роста и зарплатных ожиданий. В этой статье я. . .	Cython и C (СИ) расширения Python для максимальной производительности py-thonny 20.05.2025 Python невероятно дружелюбен к начинающим и одновременно мощный для профи. Но стоит лишь заикнуться о высокопроизводительных вычислениях — и энтузиазм быстро улетучивается. Да, Питон медлительнее. . .	Безопасное программирование в Java и предотвращение уязвимостей (SQL-инъекции, XSS и др.) Javaican 19.05.2025 Самые распространёные векторы атак на Java-приложения за последний год выглядят как классический "топ-3 хакерских фаворитов": SQL-инъекции (31%), межсайтовый скриптинг или XSS (28%) и CSRF-атаки. . .
Введение в Q# - язык квантовых вычислений от Microsoft EggHead 19.05.2025 Microsoft вошла в гонку технологических гигантов с собственным языком программирования Q#, специально созданным для разработки квантовых алгоритмов. Но прежде чем погружаться в синтаксические дебри. . .	Безопасность Kubernetes с Falco и обнаружение вторжений Mr. Docker 18.05.2025 Переход организаций к микросервисной архитектуре и контейнерным технологиям сопровождается лавинообразным ростом векторов атак — от тривиальных попыток взлома до многоступенчатых кибератак, способных. . .	Аугментация изображений с Python AI_Generated 18.05.2025 Собрать достаточно большой датасет для обучения нейронной сети — та ещё головная боль. Часами вручную размечать картинки, скармливать их ненасытным алгоритмам и молиться, чтобы модель не сдулась при. . .	Исключения в Java: советы, примеры кода и многое другое Javaican 18.05.2025 Исключения — это объекты, созданные когда программа сталкивается с непредвиденной ситуацией: файл не найден, сетевое соединение разорвано, деление на ноль. . . Список можно продолжать до бесконечности. . . .	Как сделать SSO (Single Sign-On) в C# приложении stackOverflow 18.05.2025 SSO — это механизм, позволяющий пользователю пройти аутентификацию один раз и получить доступ к нескольким приложениям без повторного ввода учетных данных. Вы наверняка сталкивались с ним, когда. . .

@weh 0 / 0 / 0 Регистрация: 01.06.2016 Сообщений: 6

	Определить, каких букв — гласных или согласных больше в строке 02.06.2016, 11:51. Показов 2337. Ответов 2 Метки нет (Все метки) Задание: Ввести строку, содержащую цифры и буквы латинского алфавита. Определить, каких букв - гласных или согласных больше. Напечатать встречающиеся гласные и согласные, отсутствующие гласные и согласные (каждую по одному разу). 0

Опции темы

Определить, каких букв — гласных или согласных больше в строке

Решение