Проверка делимости 3 чисел на 11

@Chelove234 · Регистрация: 19.12.2022

Студворк — интернет-сервис помощи студентам

Добрый день. Помогите решить задачу Известен следующий признак делимости числа n на 11:
для делимости на 11 необходимо, чтобы разность между суммой цифр, стоящих на четных местах, и суммой цифр, стоящих на нечетных местах, делилась на 11.
Написать процедуры проверки признака делимости. Даны три натуральных числа. Проверить для каждого из них, делятся ли они на 11.
Вот моя программа:

Pascal

procedure kr11(a: integer);
Var i, snc, sch: integer;
Begin
While a>0 do Begin
 inc(i);
 if i mod 2 =0 then sch:= sch + (a mod 10)
               else snc:= snc + (a mod 10);
 a:= a div 10;
 end;
 if (sch-snc) mod 11 = 0 then writeln('YES')
                       else writeln('NO')
end;
Var a,b,c: integer;
Begin
 readln(a);
 kr11(a);
 readln(b);
 kr11(b);
 readln(c);
 kr11(c);
end.

Проблема в том, что она не всегда работает корректно для трёх чисел. Как это исправить?

@AHBAR · 01.03.2023, 13:25

Сообщение от Chelove234

Проблема в том, что она не всегда работает корректно для трёх чисел. Как это исправить?

В целом вроде все верно, но вы забыли проинициировать переменные. и они у вас скорее всего в начале процедуры принимают рандомные значения.

Pascal

1
2
3

  i := 0;
  sch := 0;
  snc := 0;

Добавлено через 1 минуту

Pascal

procedure kr11(a: integer);
Var i, snc, sch: integer;
Begin
 
  i := 0;
  sch := 0;
  snc := 0;
 
While a>0 do Begin
 inc(i);
 if i mod 2 =0 then sch:= sch + (a mod 10)
               else snc:= snc + (a mod 10);
 a:= a div 10;
 end;
 if (sch-snc) mod 11 = 0 then writeln('YES')
                       else writeln('NO')
end;
Var a,b,c: integer;
Begin
 readln(a);
 kr11(a);
 readln(b);
 kr11(b);
 readln(c);
 kr11(c);
 readln;
end.

@bormant · 01.03.2023, 20:16

Порассуждаем.
1)
Основной блок программы: три числа -- это же цикл?

Pascal

1
2
3

for i:=2 downto 0 do begin
  Read(t); kr11(t);
end;

2) разность цифр на четных и нечетных местах -- ее можно вычислять сразу, без отдельных сумм

Причём, для чередования знака очередной цифры значительно проще менять знак суммы

Pascal

s:=0;
while n<>0 do begin
  s:=-s+n mod 10;
  n:=n div 10;
end;

3) по хорошему, вместо процедуры просится функция:

Pascal

function IsMultiple11(n: Integer): Boolean;
var s: Integer;
begin
  s:=0;
  while n<>0 do begin
    s:=-s+n mod 10;
    n:=n div 10;
  end;
  IsMultiple11:=0=s mod 11;
end;
 
var i, t: Integer;
begin
  for i:=2 downto 0 do begin
    Read(t);
    WriteLn(IsMultiple11(t));
  end;
end.

Добавлено через 7 минут
4)
С третьей стороны для влезающих в Integer чисел легко ведь написать

Pascal

function IsMultiple11(n: Integer): Boolean;
begin
  IsMultiple11:=0=n mod 11;
end;

Тоже заметили, да? Смысл мудрить что-то с признаком делимости на 11 появляется только тогда, когда число длинное и не влазит в Integer:

Pascal

function IsMultiple11(const n: String): Boolean;
var s, i: Integer;
begin
  s:=0; for i:=1 to Length(n) do s:=-s+Ord(n[i])-Ord('0');
  IsMultiple11:=0=s mod 11;
end;

Здесь нет проверки на то, что в n только цифры, но и задание не требует проверки ввода на корректность

@Chelove234 · 02.03.2023, 14:25 **[ТС]**

У меня условие практической такое(и мы изучаем процедуры, поэтому функции использовать нельзя)

@bormant · 02.03.2023, 20:22

Pascal

procedure TestMultiple11(const n: String);
var s, i: Integer;
begin
  s:=0; for i:=1 to Length(n) do s:=-s+Ord(n[i])-Ord('0');
  WriteLn(0=s mod 11);
end;

@Chelove234 0 / 0 / 0 Регистрация: 19.12.2022 Сообщений: 25
	02.03.2023, 14:25 [ТС]	4
	У меня условие практической такое(и мы изучаем процедуры, поэтому функции использовать нельзя) 0

Опции темы

Проверка делимости 3 чисел на 11

Решение