Исправить код вычисления элементов одномерного массива

program make_vector_c;
{https://www.cyberforum.ru/pascal/thread3092812.html}
 
{$mode objfpc}{$H+}
 
uses math;
 
type
  TVectorC = array of double;
  TMatrixA = array of array of double;
 
function getDemension( ): Integer;
begin
  {запросить у пользователя, или прочитать из файла размерность.
  размерность должна быть > 0, но не слишком большой, чтобы
  можно было отобразить на экране}
  Result:= 10;
end;
 
function getMatrixA(const dem: integer): TMatrixA;
var
  i, j : integer;
begin
  SetLength(Result, dem, dem);
  {запросить у пользователя значения матрицы A или прочитать из файла}
  Randomize;
  for i:= 0 to pred(dem) do
      for j:= 0 to pred(dem) do begin
          Result[i,j]:= Random * 100 * RandomFrom([1.0, -1.0]);
      end;
end;
 
function calculateVectorC(const a: TMatrixA): TVectorC;
var
  i, j, k, n : integer;
  devider, devidend: double;
begin
  n:= Length(a[0]);
  SetLength(Result, n);
  {знаминатель формулы (делитель) не зависит от порядкового номера элемента
   вектора по этому рассчитываем его один раз}
  devider:= 0.0; //делитель
  for i:= 0 to pred(n) do
      for j:= 0 to pred(n) do
          devider += cos(sqr(a[i,j]));
 
  devidend:= 0.0; // делимое
  for k:= 0 to pred(n) do begin
 
      for i:= 0 to pred(n) do
          devidend += sqr(a[i,k]) * sin(a[k,i]);
 
      Result[k]:= devidend / devider;
  end;
end;
 
procedure printVectorC(const v: TVectorC);
var
  value: Double;
begin
  write(' C = [ ');
  for value in v do
      write(value:6:2, ' ');
  writeln(']');
end;
 
procedure printMatrixA(const m: TMatrixA);
var
  i, j, n: integer;
begin
  n:= Length(m[0]);
  for i:= 0 to pred(n) do begin
    for j:= 0 to pred(n) do
        write(m[i, j]:6:2, ' ');
    writeln;
  end;
end;
 
var
  demension: Integer; //размерность матрицы/вектора
  vectorC:   TVectorC = nil; //вектор  C
  matrixA:   TMatrixA = nil; //матрица A
 
begin
  //получить размерность матрицы/вектора
  demension:= getDemension();
  //получить матрицу
  matrixA:= getMatrixA(demension);
  //вычислить вектор
  vectorC:= calculateVectorC(matrixA);
  //вывести на экран матрицу
  printMatrixA(matrixA);
  //вывести на экран вектор
  writeln;
  printVectorC(vectorC);
 
  readln;
end.