создать стек в памяти из этих чисел таким образом, чтобы на вершине стека было самое большое число. Удалить из стека все отрицательные элементы.

program Project1;
 
const
  //Наибольшая глубина стека. Т. е. максимальное количество элементов,
  //которое может поместиться в стек.
  StSizeMax = 30;
 
type
  //Тип, описывающий стек.
  TStack = record
    //Указатель вершины стека. Это индекс последнего добавленного элемента.
    Pnt : Integer;
    //Контейнер данных стека.
    Data : array[1..StSizeMax] of Integer;
  end;
 
//Добавить в стек элемент.
function StackPush(var aStack : TStack; const aNum : Integer) : Boolean;
begin
  StackPush := False;
  with aStack do begin
    if Pnt < High(Data) then begin
      //Индекс добавляемого элемента.
      Inc(Pnt);
      //Добавляем элемент в массив (т. е. в стек).
      Data[Pnt] := aNum;
      StackPush := True;
    end;
  end;
end;
 
//Взять из стека элемент.
function StackPop(var aStack : TStack; var aNum : Integer) : Boolean;
begin
  StackPop := False;
  with aStack do begin
    if Pnt >= Low(Data) then begin
      aNum := Data[Pnt];
      Dec(Pnt);
      StackPop := True;
    end;
  end;
end;
 
const
  //Будем работать с M элементами стеков.
  M = 10;
 
const
  Fn = 'file.txt';
var
  F : Text;
  St1, St2 : TStack;
  i, Num1, Num2 : Integer;
begin
  Assign(F, Fn);
 
  Rewrite(F);
  Writeln('Содержимое файла:');
  Randomize;
  for i := 1 to M do begin
    Num1 := -30 + Random(101); //-30..70.
    Write(F, Num1);
    if i < M then Writeln(F);
    //Распечатка значений в окне консоли.
    if i > 1 then Write(', ');
    Write(Num1);
  end;
  Writeln;
  Flush(F);
 
  //Инициализация стеков.
  St1.Pnt := 0;
  St2.Pnt := 0;
 
  //Читаем данные из файла в первый стек и при этом "гоним пузырёк" по неубыванию
  //от дна стека - к вершине, по мере загрузки в стек значений.
  Reset(F);
  Num1 := 0;
  Num2 := 0;
  i := 0;
  while not Eof(F) do begin
    Inc(i);
    Num1 := Num2;
    Readln(F, Num2);
    if i < 2 then Continue;
    if Num1 <= Num2 then begin
      StackPush(St1, Num1);
    end else begin
      StackPush(St1, Num2);
      Num2 := Num1;
    end;
  end;
  //Дописываем в стек оставшееся число - оно и есть наибольшее из всех чисел в файле.
  if i > 0 then StackPush(St1, Num2);
 
  Close(F);
 
  //Распечатываем содержимое первого стека.
  //При этом, чтобы не потерять элементы, применяем переливание между стеками.
  Writeln('Содержимое стека после обработки данных из файла:');
  i := 0;
  while StackPop(St1, Num1) do begin
    Inc(i);
    StackPush(St2, Num1);
    if i > 1 then Write(', ');
    Write(Num1);
  end;
  Writeln;
  //Переливаем элементы обратно - из второго стека - в первый стек.
  while StackPop(St2, Num1) do StackPush(St1, Num1);
 
  //Теперь удаляем из первого стека отрицательные элементы.
  //Опять действуем через переливание.
  while StackPop(St1, Num1) do begin
    if Num1 < 0 then Continue;
    StackPush(St2, Num1)
  end;
  //Переливаем элементы обратно.
  while StackPop(St2, Num1) do StackPush(St1, Num1);
 
  //Распечатываем содержимое первого стека.
  Writeln('Содержимое стека после удаления отрицательных элементов:');
  i := 0;
  while StackPop(St1, Num1) do begin
    Inc(i);
    StackPush(St2, Num1);
    if i > 1 then Write(', ');
    Write(Num1);
  end;
  Writeln;
 
  Readln;
end.