Необходимо разработать программу для валидации банковских карт

//{$Define DEBUG} //переменная DEBUG, для вывода отладочной информации удалить "//" в начале строки
 
type
    index = (bank_name, BINs); //тип для сепарации имени банка и его БИНов
 
const
    //платёжные системы
    payment_system: array['0'..'9'] of string[80] = (
        'неизвестна',
        'какая-то авиалиния',
        'какая-то авиалиния',
        'American Express или какая-то организациия сферы путешествий и развлечений',
        'Visa',
        'Mastercard',
        'Union Pay или какая-то мерчендайзинговая компания',
        'какая-то топливная компания',
        'какое-то предприятие в сфере телекоммуникаций',
        'государственные ассигнации');
 
    //названия и БИНы банков, каждый БИН должен быть обрамлён пробелами
    bank_count = 10; //количество банков
    banks: array[1..bank_count, bank_name..BINs] of string[80] = (
        ('Альфа-Банк', ' 521178 548673 548601 2245841 415428 676371 477964 '),
        ('Газпромбанк', ' 548999 526483 '),
        ('МТС Банк', ' 533736 540616 '),
        ('Открытие', ' 434146 405870 544573 532301 '),
        ('Райффайзен Банк', ' 2262730 462729 '),
        ('Тинькофф банк', ' 521324 437773 '),
        ('Сбербанк', ' 427683 2263900 2267758 427901 2254693 427644 427601 427901 427631 489798 '),
        ('Хоум Кредит', ' 445435 '),
        ('Яндекс-Деньги', ' 518901 '),
        ('Промсвязьбанк', ' 447817 447818 476208 476206 554759 520373 '));
 
var
    number, BIN: string; //строки с номером карты и БИНом
    i, d, s: integer; //счётчик, число, сумма
    correct, found: boolean; //флаги корректности (отсутствия ошибок) и наличия БИН
begin
    write('Введите номер банковской карты: ');
    readln(number); //ввод номера банковской карты
    {$Ifdef DEBUG}
    writeln('Введён номер карты: ', number);
    writeln('Проверка длины номера карты...');
    {$Endif}
    correct := length(number) = 19; //длина номера вместе с пробелами должна быть 19
    if not correct then //если длина номера неверная, то...
        begin
            {$Ifdef DEBUG}
            writeln('Неправильная длина номера (', length(number), ').') //сообщаем об этом
            {$Endif}
        end
    else //иначе (если длина номера верная)
        begin  //проверяем символы
            {$Ifdef DEBUG}
            writeln('Длина номера карты корректна.');
            writeln('Проверка символов...');
            {$Endif}
            i := 1; //пока первый символ
            while i <= 19 do //цикл проверки символлов
                begin
                    correct := (i mod 5 = 0) and (number[i] = ' ') //на позициях. кратных 5, должен быть пробел,
                        or (i mod 5 <> 0) and (number[i] in ['0'..'9']); //на остальных позициях цифры
                    if correct then //если символ верный, то
                        inc(i) //переходим к следующему
                    else //иначе (если символ не верный)
                        break //прекращаем проверку
                end;
            if not correct then //если есть некорректный символ, то
                begin
                    {$Ifdef DEBUG}
                    writeln('Номер не соответствует шаблону 0000 0000 0000 0000.'); //сообщаем об этом
                    writeln(number); //печатаем номер
                    for i := 1 to i-1 do //переходим на позицию перед символом
                        write(' ');
                    writeln('|'); //печатаем указатель на символ
                    writeln('Некорректный символ') //сообщаем о некорректном символе
                    {$Endif}
                end
            else //иначе (если нет некорректного символа)
                begin
                    {$Ifdef DEBUG}
                    writeln('Символы корректны.');
                    writeln('Удаление пробелов...');
                    {$Endif}
                    for i := 3 downto 1 do //удаляем пробелы
                        delete(number, 5*i, 1);
                    {$Ifdef DEBUG}
                    writeln('Пробелы удалены.');
                    writeln('Проверка корректности номера алгоритмом Луна...');
                    {$Endif}
                    s := 0; //контрольная сумма пока равна 0
                    for i := 1 to 16 do //цикл проверки номера алгоритмом Луна
                        begin
                            d := ord(number[i]) - ord('0'); //переводим символ в число
                            if odd(i) then //если номер символа нечётный, то
                                begin
                                    d := d * 2; //умножаем число на 2
                                    if d > 9 then  //если число больше 9, то
                                        dec(d, 9); //вычитаем из числа 9
                                end;
                            inc(s, d) //добавляем число к контрольной сумме
                        end;
                    correct := s mod 10 = 0 //контрольная сумма должна быть кратна 10
                end;
        end;
    if not correct then //если номер некорректен, то
        writeln('Номер не корректен') //сообщаем об этом
    else //если номер корректен, то
        begin
            writeln('Номер корректен.'); //сообщаем об этом
            write('Платёжная система: '); //определяем и печатаем платёжную систему
            if copy(number, 1, 2) = '22' then //если первые две цифры "22", то
                writeln('Мир') //это "Мир"
            else //иначе (если первые две цифры не "22")
                writeln(payment_system[number[1]]); //печатаем платёжную систему
            if number[1] > '0' then //если первая цифра номера не "0", то
                begin //определяем банк по БИН
                    write('Банк-эмитент: ');
                    if copy(number, 1, 2) = '22' then //если первые две цифры "22", то
                        BIN := ' ' + copy(number, 1, 7) + ' ' //БИН состоит из первых 7 цифр
                    else //иначе (если первые две цифры не "22")
                        BIN := ' ' + copy(number, 1, 6) + ' '; //БИН состоит из первых 6 цифр
                    i := 0; //номер банка, пока 0
                    repeat //цикл поиска банка
                        inc(i); //следующий банк
                        found := pos(BIN, banks[i, BINs]) > 0; //проверяем, есть ли БИН
                    until found or (i = bank_count) //Выходим из цикла, если банк найден, или банки кончились
                end;
            if found then //если банк найден, то
                writeln(banks[i, bank_name]) //печатаем название найденного банка
            else //иначе (если банк не найден)
                writeln('неизвестен') //печатаем, что банк неизвестен
        end;
    write('Нажмите клавишу <Enter> для завершения программы...');
    readln
end.

function CheckCode(cardcode: String): boolean;
var
  i, length_of_number, number_of_digit, digit, sum: integer;
begin
  length_of_number := length(cardcode);
  sum := 0;
  for i := 1 to length_of_number do
    begin
      number_of_digit := length_of_number - i + 1;
      digit := StrToInt(cardcode[i]);
      if not odd(number_of_digit) then
        begin
          digit := digit * 2;
          if digit > 9 then dec(digit, 9)
        end;
      inc(sum, digit)
    end;
  CheckCode := sum mod 10 = 0
end;

function CheckCode(cardcode: string): boolean;
var
  i, n, sum, digit: integer;
begin
  n := 0;
  sum := 0;
  for i := cardcode.Length downto 1 do
    if cardcode[i] <> ' ' then
      begin
        n += 1;
        digit := StrToInt(cardcode[i]) * (2 - n and 1); //можно n mod 2, но это медленнее
        if digit > 9 then digit -= 9;
        sum += digit
      end;
  Result := sum mod 10 = 0
end;

function CheckCode(cardcode: String): Boolean;
var
  i, n, sum, digit: Integer;
begin
  n := 0; sum := 0;
  for i := Length(cardcode) downto 1 do
    if cardcode[i] in ['0'..'9'] then begin
      Inc(n);
      digit := (Ord(cardcode[i]) - Ord('0')) * (2 - n and 1);
      if digit > 9 then Dec(digit, 9);
      Inc(sum, digit);
    end;
  CheckCode := sum mod 10 = 0
end;