Определить, входят ли некоторые цифры в число.

program Project1;
 
type
  TDig = 0..9;
var
  CDig, VDig : set of TDig;
  Dig : TDig;
  i, Num : Longint;
  S : String;
begin
  repeat
    Writeln('Задайте перечень цифр через пробел и нажмите Enter:');
    CDig := [];
    repeat
      Read(Dig);
      CDig := CDig + [Dig];
    until Eoln(Input);
    Readln;
 
    Writeln('Задайте целое число:');
    Readln(Num);
 
    Num := Abs(Num); //Избавляемся от знака.
    VDig := [];
    repeat
      //Очередная цифра справа.
      Dig := Num mod 10;
      //Удаляем из числа очередной разряд справа.
      Num := Num div 10;
      //Если цифра принадлежит заданному множеству цифр, то добавляем её
      //в результирующее множество.
      if Dig in CDig then VDig := VDig + [Dig];
    until Num = 0;
 
    if VDig = [] then
      Writeln('В записи числа нет ни одной цифры из заданного множества.')
    else begin
      Writeln('В записи числа обнаружены следующие заданные цифры:');
      i := 0;
      for Dig := 0 to 9 do begin
        if Dig in VDig then begin
          Inc(i);
          if i > 1 then Write(', ');
          Write(Dig);
        end;
      end;
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

until Eoln(Input);

uses crt;
var n,i:integer;
    m:set of byte;
begin
clrscr;
repeat
write('Введите трехзначное число n=');
readln(n);
until(abs(n)>99)and(abs(n)<1000);
n:=abs(n);
m:=[];
while n>0 do
 begin
  if n mod 10 in [3,6,9] then m:=m+[n mod 10];
  n:=n div 10;
 end;
if m=[] then write('Цифры 3,6,9 не входят в число')
else
 begin
  writeln('В число входят цифры:');
  for i:=3 to 9 do
  if i in m then write(i,' ');
 end;
readln
end.