Построить круговую диаграмму количества машин по маркам

uses graph;
type
  Auto = (Opel, Renault, Seat, Fiat, Volvo, Toyota);
const
  R  = 150;
  RT = 175;
 
  title: array[Auto]of string = (
    'Opel', 'Renault', 'Seat', 'Fiat', 'Volvo', 'Toyota'
  );
  count: array[Auto] of integer = (
    3, 6, 2, 9, 8, 7
  );
 
function inttostr(i: integer): string;
var s: string;
begin
  str(i, s);
  inttostr := s;
end;
 
var
  i: Auto;
  cx, cy: integer;
  gd, gm, total, angle_s, angle_f: integer;
  angle_m: real;
 
 
begin
  initgraph(gd, gm, '');
  if graphresult <> grok then begin
    writeln('graphics error'); readln; halt(100);
  end;
 
  total := 0;
  for i := low(auto) to high(auto) do
    inc(total, count[i]);
 
  cx := getmaxx div 2; cy := getmaxy div 2;
  angle_s := 0;
  settextjustify(centertext, centertext);
  for i := low(auto) to high(auto) do begin
    setfillstyle(solidfill, ord(i) + 1);
 
    if i = high(auto) then angle_f := 360
    else
      angle_f := angle_s + trunc(count[i] * (360 / total));
 
    pieslice(cx, cy, angle_s, angle_f, R);
    angle_m := angle_s + (angle_f - angle_s) / 2;
    outtextxy(
      cx + Trunc(RT * cos(angle_m * pi / 180)),
      cy - Trunc(RT * sin(angle_m * pi / 180)),
      title[i] + '(' + inttostr(trunc(count[i] / total * 100)) + '%)'
    );
 
    angle_s := angle_f;
  end;
  readln;
  closegraph;
end.