Найти и вывести фамилии тех студентов, которые все экзамены сдали на 9

const
  LessonsCount = 4;
  Lessons : array [1..LessonsCount] of String[15] =
           ('алгебра', 'геометрия', 'философия', 'информатика');
 
type
  tStudents = class
    Name : String[20];
    Ball : array [1..LessonsCount] of Byte;
    Next : tStudents;
    
    constructor (N : Integer);
    begin
      Name := ReadLnString('Введите ФИО студента № ' + N.ToString + ' :');
      for var L := 1 to LessonsCount do
        Ball[L] := ReadLnInteger('Введите оценку за предмет «' + Lessons[L] + '» =');
      Next := nil;
    end;
    
    function SumBalls : Integer;
    begin
      Result := 0;
      for var L := 1 to LessonsCount do
        Result += Ball[L];
    end;
    
    procedure OutStudent(N : Integer);
    begin
      Write(N:5, Name:20);
      for var L := 1 to LessonsCount do
        Write('   ', Lessons[L], ' : ', Ball[L]);
      WriteLn;
    end;
  end;
 
function ContinueEntering : Boolean;
begin
  var S : String;
  repeat
    S := ReadLnString(NewLine +
      '1 / Y - yes / Д - да : Продолжить ввод следующего студента' + NewLine +
      '0 / N - no / Н - нет : Закончить ввод данных' + NewLine +
      'Ваш выбор:');
  until (S.Length > 0) and '1yYдД0nNнН'.Contains(S[1]);
  Result := '0nNнН'.IndexOf(S[1]) < 0;
end;
 
function InputGroup : tStudents;
begin
  var N := 1;
  Result := new tStudents(N);
  var Last := Result;
  while ContinueEntering do
    begin
      N += 1;
      Last.Next := new tStudents(N);
      Last := Last.Next;
    end;
end;
  
procedure OutNumbersOfBalls(List : tStudents);
begin
  WriteLn;
  var Sum := ReadLnInteger('Сколько баллов:');
  WriteLn('Список студентов, набравших ', Sum, ' баллов:');
  var Count := 0;
  repeat
    if List.SumBalls = Sum then
      begin
        Count += 1;
        List.OutStudent(Count);
      end;
    List := List.Next;
  until List = nil;
  if Count = 0 then
    WriteLn('Нет таких студентов.');
end;
  
var
  List : tStudents;
begin
  List := InputGroup;
  OutNumbersOfBalls(List);
end.