Оставить в строке только первое вхождение каждого символа. Взаимный порядок оставленных символов сохранить

@Александр Летов · Регистрация: 06.02.2016

Студворк — интернет-сервис помощи студентам

Решил данную задачу так:

Кликните здесь для просмотра всего текста

Pascal

//Оставить в строке только первое вхождение каждого символа. Взаимный порядок оставленных символов сохранить
Procedure write_in_set(var str_IN, str_OUT : string);
Var
    i : integer;
    position : set of integer;
begin
    position := [];
    for i:=1 to length(str_IN) do //Цикл для перебора каждого символа
        if not (Pos(str_IN[i],str_IN) in position) then // Если символ новый, то записываем в строку
        begin   
            position := position + [Pos(str_IN[i],str_IN)]; // Записываем позицию во множество позиций
            str_OUT := str_OUT + Copy (str_IN, Pos(str_IN[i],str_IN), 1); // В итоговую строку копируем новый символ
    end;
end;
Var
    str_IN, str_OUT : string;
BEGIN
    str_OUT := '';
    write('Введите строку: ');
    readln(str_IN);
    write_in_set(str_IN, str_OUT);
    writeln(str_OUT); // Вывод строки состоящей из символов, входящих в исходную строку
    readln();
END.

Она работает и работает правильно, но хотелось бы обойтись только одной строкой, которую вводит пользователь. И удалить из неё лишние символы встроеной функцией delete.
Как ни бился, так ничего и не получилось. То выход за границу цикла, то удаление всех символов из строки получалось...

@JuriiMW · 24.02.2016, 10:32

Pascal

begin
  var S := ReadLnString('Введите строку:');
  var i := 1;
  while i <= S.Length do
    begin
      var p := S.LastIndexOf(S[i]);
      if p >= i then
        Delete(S, p+1, 1)
      else
        i += 1;
    end;
  WriteLn(S);
end.

Т.к. функция Delete в модуле PABCSystem определена вот так:

Pascal

procedure Delete(var s: string; index, count: integer);
// Delete никогда не возвращает исключения
begin
  if (index < 1) or (index > s.Length) or (count <= 0) then
    Exit;
  if index + count - 1 > s.Length then
    count := s.Length - index + 1;
  s := s.Remove(index - 1, count);
end;

То программу можно переписать вот так:

Pascal

begin
  var S := ReadLnString('Введите строку:');
  var i := 1;
  while i <= S.Length do
    begin
      var p := S.LastIndexOf(S[i]);
      if p >= i then
        S := S.Remove(p, 1)
      else
        i += 1;
    end;
  WriteLn(S);
end.

@Александр Летов · 24.02.2016, 10:49 **[ТС]**

Пришлось немного переделать ибо:
Ошибка компилятора ABC.NET:
Вторая строка - нельзя преобразовать тип string к text.

Но теперь работает так как мне хотелось. СПАСИБО!

P.S мы не изучали не все функции классов или как это называется. Поэтому про LastIndexOf я попросту не знал.

Только я кое-что не понял - почему p+1 я догадался, просмотрев прогу пошагово. Но ведь в описании LastIndexOf сказано, что она возвращает индекс последнего вхождения символа. А запустив прогу с выводом p после каждого прохода цикла, я увидел, что получается, что она возвращает индекс предыдущего символа... почему так?
В строке "оалдфвыоалджвфыолдажфвы" символ "о" стоит на 16-м месте, а p = 15

Кликните здесь для просмотра всего текста

Pascal

Var
    s : string;
    i, p  : integer;
begin
    write('Введите строку: ');
    readln(S);
    i:=1;
    while i <= Length(s) do
        begin
            p := S.LastIndexOf(S[i]);
            if p >= i then
            begin
                Delete(S, p+1, 1);
            {   
                writeln(s);
                writeln(p); // вывод последнего вхождения i-того символа 
                readln();
            }   
            end
            else
                inc(i);
    end;
  writeln(s);
end.

@JuriiMW · 24.02.2016, 11:06

Сообщение от Александр Летов

Пришлось немного переделать ибо:
Ошибка компилятора ABC.NET:

Попробуйте обновить PABC.NET. (На оффсайте уже версия 3.1… У меня самого пока 3.0 ;–)

Сообщение от Александр Летов

мы не изучали не все функции классов или как это называется

LastIndexOf — это метод.
Если переменная уже определена, то после неё достаточно поставить точку и выскочит контекстная подсказка, в которой можно найти и выбрать необходимый метод…
А ещё есть MSDN…
К примеру, тип String (lда простят меня модераторы) вот здесь: String - класс

Ещё, чтобы посмотреть как реализована та или иная подпрограмма в PABC.NET, достаточно на имени подпрограммы нажать ПКМ и выбрать «Перейти к реализации»…
К примеру: вот так работает процедура Read для строки

Pascal

procedure read(var x: string);
begin
  if input.sr <> nil then
    read(input, x)
  else 
    try
      CurrentIOSystem.read(x)
    except
      on e: Exception do
        raise e;
    end;
end;

… а вот так функция ReadLnString :

Pascal

function ReadlnString(prompt: string): string;
begin
  Print(prompt);
  Result := ReadlnString;
end;

Где, в свою очередь, ReadString :

Pascal

function ReadString: string;
begin
  var x: string;
  read(x);
  readln();
  Result := x;
end;

Оставить в строке только первое вхождение каждого символа. Взаимный порядок оставленных символов сохранить

Решение

Решение

Опции темы