Подсчитать в строке количество слов длиной пять символов

@NatashaSolo · Регистрация: 07.03.2016

Author24 — интернет-сервис помощи студентам

С клавиатуры вводится строка, состоящая из нескольких слов, отделенных друг от друга одним или несколькими пробелами. Подсчитать в строке количество слов длиной пять символов.

Решение:

Pascal

Procedure vvod(var s:string);
  Begin
   writeln('Введите несколько слов через пробел');
   readln(s);
  End;
Function Chet(var s: string): integer;
 var a: integer;
     b: string;
 Begin
   s := s + ' ';
   if pos(' ', s) <> 0 then   //Удаляет лишние пробелы
   delete(s, pos(' ', s), 1);
   while pos(' ', s) <> 0 do  //Ищем, есть ли слова, которые состоят из 5 букв
    Begin
     b:= copy(s, 1, pos(' ', s));
     if length(b) = 5 then
     a:= a + 1;
     delete(s, 1, pos(' ', s));
    End;
  Chet:= a;
  writeln(a); //Выводим кол-во слов из 5 букв
 End;
 
var s: string;
 Begin
  vvod(s);
  Chet(s);
  writeln(s);
 End.

@JuriiMW · 13.09.2016, 05:01

Если более-менее сохранять синтаксис паскаля, то можно так:

Pascal

begin
  var S := ReadLnString('Введите несколько слов через пробел:');
  var count := 0;
  foreach var Word in S.ToWords(#32) do
    if Word.Length = 5 then
      count += 1;
  WriteLn('Количество слов длиной 5 символов = ', count);
end.

@JuriiMW · 13.09.2016, 05:20

Хотя можно и одной строкой:

Pascal

1
2
3

begin
  WriteLn('Количество слов длиной 5 символов = ', ReadLnString('Введите несколько слов через пробел:').ToWords(#32).Where(w -> w.Length = 5).Count);
end.

@NatashaSolo · 13.09.2016, 19:36 **[ТС]**

Спасибо за Ваше решение, но мы так не решаем. Многого еще не проходили. Вот в том варианте, который выложен в исходном документе, что неправильно? Программа не работает. ((

Добавлено через 50 секунд
Сама не могу ошибку найти.

@Joy · 14.09.2016, 04:23

Сообщение от NatashaSolo

Сама не могу ошибку найти.

ошибки в комментариях

Pascal

Procedure vvod(var s:string);
  Begin
   writeln('Введите несколько слов через пробел');
   readln(s);
  End;
Function Chet(var s: string): integer;
 var a: integer;
     b: string;
 Begin
   s := s + ' ';
   if pos('  ', s) <> 0 then   //Удаляет лишние пробелы, искать надо сдвоенные пробелы и удалять один, а вы удаляли все пробелы
   delete(s, pos('  ', s), 1);
   while pos(' ', s) <> 0 do  //Ищем, есть ли слова, которые состоят из 5 букв
    Begin
     b:= copy(s, 1, pos(' ', s)-1);// копировать надо без пробела в конце поэтому -1!
     if length(b) = 5 then
     a:= a + 1;
     delete(s, 1, pos(' ', s));
    End;
  Chet:= a;
  writeln(a); //Выводим кол-во слов из 5 букв
 End;
 
var s: string;
 Begin
  vvod(s);
  Chet(s);
  writeln(s);
 End.

@NatashaSolo · 14.09.2016, 22:44 **[ТС]**

Заработала))) Спасибо огромное)))

@bormant · 18.09.2016, 10:05

NatashaSolo,
для подсчета слов совсем не обязательно модифицировать строку:

Pascal

const Delim=[' ']; WordLen=5;
var
  s: String;
  i, j, k: Integer;
begin
  Write('Строка: '); ReadLn(s); s:=s+' '; {j:=0; k:=0;}
  for i:=1 to Length(s) do
    if s[i] in Delim then begin
      if i-j=WordLen+1 then Inc(k); { между последним и текущим разделителем WordLen букв }
      j:=i; { запомним позицию последнего разделителя }
    end;
  WriteLn(k);
end.

Добавлено через 8 минут
или с функцией:

Pascal

type TChars = set of Char;
function WordLCnt(s: String; Len: Integer; Delim: TChars): Integer;
var i, j, k: Integer;
begin
  j:=0; k:=0; s:=s+' ';
  for i:=1 to Length(s) do
    if s[i] in Delim then begin
      if i-j=Len+1 then Inc(k);
      j:=i;
    end;
  WordLCnt:=k;
end;
var s: String;
begin
  Write('Строка: '); ReadLn(s);
  WriteLn(WordLCnt(s,5,[' ']));
end.

Добавлено через 1 минуту
или с заданием разделителей строкой вместо множества:

Pascal

function WordLCnt(s: String; Len: Integer; const Delim: String): Integer;
var i, j, k: Integer;
begin
  j:=0; k:=0; s:=s+' ';
  for i:=1 to Length(s) do
    if Pos(s[i],Delim)>0 then begin
      if i-j=Len+1 then Inc(k);
      j:=i;
    end;
  WordLCnt:=k;
end;
var s: String;
begin
  Write('Строка: '); ReadLn(s);
  WriteLn(WordLCnt(s,5,' '));
end.

Добавлено через 3 минуты
или без модификации строки:

Pascal

function WordLCnt(const s: String; Len: Integer; const Delim: String): Integer;
var i, j, k: Integer;
begin
  j:=0; k:=0;
  for i:=1 to Length(s) do
    if Pos(s[i],Delim)>0 then begin
      if i-j=Len+1 then Inc(k);
      j:=i;
    end;
  if Length(s)-j=Len then Inc(k);
  WordLCnt:=k;
end;
var s: String;
begin
  Write('Строка: '); ReadLn(s);
  WriteLn(WordLCnt(s,5,' '));
end.

Добавлено через 4 минуты
или чуть более оптимизированный последний вариант:

Pascal

function WordLCnt(const s: String; Len: Integer; const Delim: String): Integer;
var i, j, k: Integer;
begin
  j:=Length(s)+1; k:=0; Inc(Len);
  for i:=j-1 downto 1 do
    if Pos(s[i],Delim)>0 then begin
      if j-i=Len then Inc(k);
      j:=i;
    end;
  if j=Len then Inc(k);
  WordLCnt:=k;
end;
var s: String;
begin
  Write('Строка: '); ReadLn(s);
  WriteLn(WordLCnt(s,5,' '));
end.

@NatashaSolo · 18.09.2016, 20:10 **[ТС]**

Спасибо большое за разные варианты решения! Все пригодится!

@NatashaSolo 1 / 1 / 0 Регистрация: 07.03.2016 Сообщений: 20
	13.09.2016, 19:36 [ТС]	4
	Спасибо за Ваше решение, но мы так не решаем. Многого еще не проходили. Вот в том варианте, который выложен в исходном документе, что неправильно? Программа не работает. (( Добавлено через 50 секунд Сама не могу ошибку найти. 0

@NatashaSolo 1 / 1 / 0 Регистрация: 07.03.2016 Сообщений: 20
	14.09.2016, 22:44 [ТС]	6
	Заработала))) Спасибо огромное))) 0

@NatashaSolo 1 / 1 / 0 Регистрация: 07.03.2016 Сообщений: 20
	18.09.2016, 20:10 [ТС]	8
	Спасибо большое за разные варианты решения! Все пригодится! 0