Функция Бесселя первого рода порядка n (нужны комментарии)

function J(n: longint; x: real): real;
const eps = 1e-20;
var i,k: longint;
    a, s: real;
begin
  x := x / 2;
  a := 1;
  for i := n downto 1 do a := a * x / i;
  s := a;
  k := 0;
  x := -x * x;
  while abs(a) >= eps do
    begin
      inc(k);
      a := x / k * a / (n + k);
      s := s + a
    end;
  J := s
end;
 
//процедура ввода числа с плавающей точкой с проверкой
procedure readln_check(s: string; var z: real; sep: boolean);
begin
  repeat
    write(s, ' >');
    if sep then write('=');
    write(' 0;  ', s, ' = ');
    readln(z)
  until (z > 0) or sep and (z = 0)
end;
 
//вызывающая программа
const lin = '+---------------------+---------------------+';
      fn = 'bessel.txt';
var a, b, h, x: real;
    n: longint;
    s: string;
    f: text;
begin
  readln_check('a', a, true);
  readln_check('b', b, true);
  if a > b
    then begin
      x := a;
      a := b;
      b := x
    end;
  readln_check('h', h, false);
  repeat
    write('n >= 0;  n = ');
    readln(n)
  until n >= 0;
  x := a;
  assign(f, fn);
  rewrite(f);
  writeln(f, 'Таблица значений функции Бесселя первого рода J', n, '(x) на интервале');
  writeln(f, 'от ', a, ' до ', b);
  writeln(f, 'с шагом ', h);
  b := b + h / 2;
  writeln(f, lin);
  writeln(f, '|          x          |        Jn(x)        |');
  writeln(f, lin);
  while x < b do
    begin
      writeln(f, '| ', x:19, ' | ', J(n, x):19:16, ' |');
      x := x + h
    end;
  writeln(f, lin);
  writeln('Файл ', fn, ' создан.');
  close(f);
  assign(f, fn);
  reset(f);
  while not eof(f) do
    begin
      readln(f, s);
      writeln(s)
    end;
  close(f);
  readln
end.