Как в Pascal ABC сделать так, чтобы можно было двигать форму без границ (FormBorderStyle.None)?

{$apptype windows}
{$reference 'System.Windows.Forms.dll'}
{$reference 'System.Drawing.dll'}
uses
  System.Windows.Forms,
  System.Drawing;
 
var
  MainForm: System.Windows.Forms.Form;
  X, Y, cX, cY: integer;
  Down: boolean := False;
 
procedure MainForm_MouseDown(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  Down := True; {Зажали кнопку}
  
  // Запоминаем координаты формы
  X := MainForm.Left;
  Y := MainForm.Top;
  
  // Запоминаем координаты курсора
  cX := System.Windows.Forms.Cursor.Position.X;
  cY := System.Windows.Forms.Cursor.Position.Y;
end;
 
procedure MainForm_MouseUp(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  Down := False; {Отпустили кнопку}
end;
 
procedure MainForm_MouseMove(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  if Down then {Если кнопка нажата}
  begin
  // Двигаем форму относительно курсора
    MainForm.Left := System.Windows.Forms.Cursor.Position.X - cX + X;
    MainForm.Top := System.Windows.Forms.Cursor.Position.Y - cY + Y;
  end;
end;
 
begin
  
  MainForm := new Form;
  MainForm.StartPosition := FormStartPosition.CenterScreen;
  MainForm.FormBorderStyle := FormBorderStyle.None;
  MainForm.MouseDown += MainForm_MouseDown;
  MainForm.MouseUp += MainForm_MouseUp;
  MainForm.MouseMove += MainForm_MouseMove;
  
  Application.Run(MainForm);
end.

{$apptype windows}
{$reference 'System.Windows.Forms.dll'}
{$reference 'System.Drawing.dll'}
uses
  System.Windows.Forms,
  System.Drawing;
 
var
  MainForm: System.Windows.Forms.Form;
 
function SendMessage(hWnd: System.IntPtr; Msg, wParam, lParam: integer): integer; external 'user32.dll';
function ReleaseCapture: boolean; external 'user32.dll';
 
procedure MainForm_MouseDown(sender: object; args: System.Windows.Forms.MouseEventArgs);
const
  WM_NCLBUTTONDOWN = $A1;
  HT_CAPTION = $2;
begin
  if args.Button = MouseButtons.Left then
  begin
    ReleaseCapture();
    SendMessage(MainForm.Handle, WM_NCLBUTTONDOWN, HT_CAPTION, 0);
  end;
end;
 
begin
  
  MainForm := new Form;
  MainForm.StartPosition := FormStartPosition.CenterScreen;
  MainForm.FormBorderStyle := FormBorderStyle.None;
  MainForm.MouseDown += MainForm_MouseDown;
  
  Application.Run(MainForm);
end.

{
Решение основывается на том, что сначала мы найдем вектор AB от точки A (с координатами курсора) и до B (с координатами верхнего левого угла формы).
Дальше, задача состоит в том, что зная текущие координаты курсора угол формы сдвигать на вектор AB.
}
{$apptype windows}
{$reference 'System.Windows.Forms.dll'}
{$reference 'System.Drawing.dll'}
uses
  System.Windows.Forms,
  System.Drawing;
 
var
  MainForm: System.Windows.Forms.Form;
  X, Y, dX, dY: integer;
  Down: boolean := False;
 
procedure MainForm_MouseDown(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  Down := True;
  
  X := MainForm.Left;
  Y := MainForm.Top;
  
  {Находим разницу координат курсора и угла окна:}
  dX := System.Windows.Forms.Cursor.Position.X - X; 
  dY := System.Windows.Forms.Cursor.Position.Y - Y;
end;
 
procedure MainForm_MouseUp(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  Down := False;
end;
 
procedure MainForm_MouseMove(sender: object; args: System.Windows.Forms.MouseEventArgs);
begin
  if Down then
  begin
    {По сути, нам надо просто сдвинуть координаты окна относительно текущих координат курсора на dX и dY.}
    MainForm.Left := System.Windows.Forms.Cursor.Position.X - dX;
    MainForm.Top := System.Windows.Forms.Cursor.Position.Y - dY;
  end;
end;
 
begin
  MainForm := new Form;
  MainForm.StartPosition := FormStartPosition.CenterScreen;
  MainForm.FormBorderStyle := FormBorderStyle.None;
  MainForm.MouseDown += MainForm_MouseDown;
  MainForm.MouseUp += MainForm_MouseUp;
  MainForm.MouseMove += MainForm_MouseMove;
  
  Application.Run(MainForm);
end.