Длинная арифметика разность

@IceCream44 · Регистрация: 02.03.2018

Author24 — интернет-сервис помощи студентам

Код

Function Difference(s1,s2:string):integer; 
var
   a,length1,length2,i:integer;
   b:boolean;
begin
   a:=0;
   b:=true;
   length1:=length(s1);
   length2:=length(s2);
   if length1>length2 then begin a:= 1; b:=false; end;
   if length1<length2 then begin a:=-1; b:=false; end;
   if b then
   for i:=1 to length1 do 
    begin
      if Ord(s1[i])-48>Ord(s2[i])-48 then begin a:= 1; break; end;
      if s1[i]<s2[i] then begin a:=-1; break; end;
    end;
   Difference:=a;
end;

var
   s1,s2:string;
   i,length3,c,x:integer;
   N,M:array[1..1000] of integer;
begin
   readln(s1);
   readln(s2);
   while s1[1] = '0' do Delete(s1,1,1);
   while s2[1] = '0' do Delete(s2,1,1);
   if (s1 < s2) and (length(s1) <= length(s2)) then write('-');
   c:=0;
   length3:=length(s2);
   for i:=1 to length3 do
      M[length3-i+1]:=Ord(s2[i])-48;
   length3:=length(s1);
   
   for i:=1 to length3 do
      N[length3-i+1]:=Ord(s1[i])-48;
   if Difference(s1,s2)<0 then begin
      length3:=length(s2);
      for i:=1 to length3 do begin
         x:=N[i];
         N[i]:=M[i];
         M[i]:=x;
      end;
   end;
   for i:=1 to length3 do
    begin
      c:=c+N[i]-M[i]+10;
      N[i]:= c mod 10;                       
      if c < 10 then c:=-1 else c:=0;
    end;
   while (N[length3]=0) and (length3>1) do length3:=length3-1;
   for i:=length3 downto 1 do 
      Write(N[i]);
end.

Не ставится минус , когда считаю 2-15 , помогите пожалуйста решить эту проблему

@JuriiMW · 22.07.2020, 06:42

Pascal

function inputNumber : String;
begin
  Result := ReadLnString;
  Result := Result.TrimStart('0');
  if (Result.Length = 0) or (Result.Count(c->Not Char.IsDigit(c)) > 0) then
    begin
      'Число состоит только из цифр и ≠ 0.'.Println;
      Halt;
    end;
end;
 
function Compare(a, b : String) : Integer;
begin
  Result := Sign(a.Length - b.Length);
  if Result = 0 then
    for var i := 1 to a.Length do
      begin
        Result := Sign(Ord(a[i]) - Ord(b[i]));
        if Result <> 0 then Exit;
      end;
end;
 
begin
  var s1 := inputNumber;
  var s2 := inputNumber;
  
  var sign := Compare(s1, s2);
  if sign = 0 then
    begin
      '0'.Println;
      Exit;
    end;
    
  if sign = -1 then
    Swap(s1, s2);
    
  s2 := '0'*(s1.Length - s2.Length) + s2;
  
  var d := False;
  for var i := s1.Length downto 1 do
    begin
      var n := Ord(s1[i]) - Ord(s2[i]);
      if d then n -= 1;
      d := n < 0;
      if d then n += 10;
      s1[i] := Chr(n + Ord('0'));
    end;
  
  s1 := (sign = -1 ? '-' : '') + s1.TrimStart('0');
  
  s1.Println;
end.

Добавлено через 1 минуту
Как смог разбил на более простые операции…

	22.07.2020, 06:42