действительное число в нормализованной форме

var a: string;
 
procedure NZ(var a: string);
var k: byte := 0;
begin
  for var i:=1 to length(a) do begin
    if (a[i] = '.') then break;
    inc(k); end;
  delete(a,k+1,1);
  if (a[1] = '-') then begin
    insert('0.',a,2);
    dec(k); end
  else 
    insert('0.',a,1);
    
  writeln('Нормализованная форма действительного числа');
  writeln(a,' * (10 ^ ',k,');');
end;
 
begin
  write('Введите десятичную дробь (через точку):');
  readln(a);
  NZ(a);
end.

procedure NZ(var a: string);
begin
  
  // k не получится объявить внутри цикла, потому что тогда к нему не будет доступа вне цикла
  // Поэтому ближайшее место к первому использованию - это прямо перед циклом
  // И тип вообще не надо указывать, компилятор сам разберётся какой тип лучше подходит
  var k := 0;
  for var i := 1 to a.Length do
  begin
    if a[i] = '.' then break;
    k += 1; // inc(k) это старый синтаксис, для += не нужны скобки, поэтому его легче читать когда привыкните
  end;
  
  Delete(a, k + 1, 1);
  if a[1] = '-' then
  begin
    Insert('0.', a, 2);
    k -= 1;
  end else
    Insert('0.', a, 1);
  
  Writeln('Нормализованная форма действительного числа');
  // Чтоб не сувать кучу запятых и апострофов - лучше использовать $''
  // Так строка вывода выглядит значительно проще
  Writeln($'{a} * (10 ^ {k})');
end;
 
begin
  Write('Введите десятичную дробь (через точку): ');
  // Чтоб не разделять строчку объявления и инициализации переменной
  // есть специальные Read, которые работают как процедуры а не функции
  var a := ReadString;
  NZ(a);
end.

// Не к чему экономить символы программы,
// лучше сделать название длиннее, но понятнее
// А ещё лучше добавить описание, вот так:
 
/// Принимает десятичную дробь и меняет её формат на:
/// 0. * (10 ^ n)
function Normalize(number: string): string;
begin
  var negative := number.StartsWith('-');
  if negative then
    number := number.TrimStart('-');
  
  var dot_index := number.IndexOf('.');
  if dot_index = -1 then
    dot_index := number.Length else
    number := number.Remove(dot_index,1);
  
  Result := $'0.{number} * (10 ^ {dot_index})';
end;
 
begin
  var num := ReadString('Введите десятичную дробь (через точку): ');
  $'Нормализованная форма действительного числа: {Normalize(num)}'.Println;
end.