Программа перемножения двух целых чисел в столбик

Const
  N = 255;
  TabMul : array[0..9,0..9] of Byte = ((0, 0, 0, 0, 0, 0, 0, 0, 0, 0),
                                       (0, 1, 2, 3, 4, 5, 6, 7, 8, 9),
                                       (0, 2, 4, 6, 8,10,12,14,16,18),
                                       (0, 3, 6, 9,12,15,18,21,24,27),
                                       (0, 4, 8,12,16,20,24,28,32,36),
                                       (0, 5,10,15,20,25,30,35,40,45),
                                       (0, 6,12,18,24,30,36,42,48,54),
                                       (0, 7,14,21,28,35,42,49,56,63),
                                       (0, 8,16,24,32,40,48,56,64,72),
                                       (0, 9,18,27,36,45,54,63,72,81));
Type
  cif = 0..9;
  tmas = array[1..N] of cif;
 
Var
  a,a1,a2 : tmas;
  an1,an2 : Longint;
 
Procedure ResetTM(var mm : tmas);
Var ii : Integer;
Begin
  For ii:=1 to N do mm[ii]:=0;
End;
 
Procedure GetLongNumSt(S : String; var m : tmas);
Var i : Integer;
Begin
  For i:=1 to N-Length(S) do m[i]:=0;
  For i:=Length(S) downto 1 do m[N-Length(S)+i]:=Ord(S[i])-Ord('0');
End;
 
Procedure GetLongNumInt(SL : Longint; var m : tmas);
Var i,k : Integer;
Begin
  ResetTM(m);
  k:=SL; i:=N;
  While (k>0) and (i>0) do
  Begin
    m[i]:=k mod 10;
    k:=k div 10;
    Dec(i);
  End;
End;
 
Procedure LongNumInSt(m : tmas; var S : String);
Var i,k : Integer;
Begin
  S:='';
  For k:=1 to N do If m[k]<>0 then Break;
  For i:=N downto k do S:=Chr(m[i]+Ord('0'))+S;
End;
 
Procedure ShowLongNum(m : tmas);
Var S : String;
Begin
  LongNumInSt(m,S);
  Writeln(S);
End;
 
Procedure LongSum(m1,m2 : tmas; var m : tmas);
Var i,k : Integer;
Begin
  k:=0;
  For i:=N downto 1 do
  Begin
    If m1[i]+m2[i]+k>9 then
    Begin
      m[i]:=(m1[i]+m2[i]+k) mod 10;
      k:=1;
    End
      else
      Begin
        m[i]:=m1[i]+m2[i]+k;
        k:=0;
      End;
  End;
End;
 
Function Mul10(m0 : tmas; k : Integer) : tmas; { shift to left }
Var
  m : tmas;
  i : Integer;
Begin
  If k=0 then Mul10:=m0 else
  Begin
    m:=m0;
    For i:=k+1 to N-k do m[i]:=m[i+k];
    For i:=N-k+1 to N do m[i]:=0;
    Mul10:=m;
  End;
End;
 
Procedure Mul(m1,m2 : tmas; var m : tmas);
Var
  kk         : Byte;     { overflow }
  i,j,n1,n2  : Integer;
  tm         : tmas;
Begin
  For i:=1 to N do If m1[i]<>0 then Break;
  n1:=i;
  For i:=1 to N do If m2[i]<>0 then Break;
  n2:=i;
  kk:=0;
  ResetTM(m);
  For j:=N downto n2 do
  Begin
    ResetTM(tm);
    For i:=N downto n1 do
    Begin
      If TabMul[m1[i],m2[j]]+kk>9 then
      Begin
        tm[i]:=(TabMul[m1[i],m2[j]]+kk) mod 10;
        kk:=(TabMul[m1[i],m2[j]]+kk) div 10;
      End
        else
        Begin
          tm[i]:=TabMul[m1[i],m2[j]]+kk;
          kk:=0;
        End;
    End;
    If (kk<>0) and (n1>1) then tm[n1-1]:=kk;
    LongSum(m,Mul10(tm,N-j),m);
  End;
End;
 
Begin
  { == DEMO-TEST == }
  GetLongNumSt('1234567890',a1);
  GetLongNumInt(987654321,a2);   
  ShowLongNum(a1);
  ShowLongNum(a2);
  ShowLongNum(Mul10(a1,10));     { a1*10000000000 }
  LongSum(a1,a2,a);              { a1+a2 = 2222222211 }
  ShowLongNum(a);
  Mul(a1,a2,a);                  { a1*a2 = 1219326311126352690 }
  ShowLongNum(a);
  { =============== }
End.