Вычислить значение выражения

@Арткр · Регистрация: 31.03.2015

Студворк — интернет-сервис помощи студентам

$https://www.cyberforum.ru/cgi-bin/latex.cgi? s=-\frac{(2x)^3}{3!}+...+(-1)^n\cdot \frac{(2x)^{2n+1}}{(2n+1)!}+...\,;\quad y=\sin 2x-2x\,;\quad x\in [0.1,\,0.9]\,;\quad \Delta x=0.2 $

Вывести рекуррентную формулу для вычесления членов ряда, для всех "х", принадлежащих [a, b], вычислить и напечатать значения "s" и "y":
1)при заданном n
2)при заданной погрешности вычислений, не превышающей eps.

@Cyborg Drone · 07.04.2015, 01:19

Ряд

$https://www.cyberforum.ru/cgi-bin/latex.cgi? s=\sum_{n=1}^\infty \frac{(-1)^n(2x)^{2n+1}}{(2n+1)!}=\sum_{n=1}^\infty a_n $

Ищем рекуррентное соотношение для членов ряда.

$https://www.cyberforum.ru/cgi-bin/latex.cgi? a_1=\frac{-(2x)^3}{3!}=\frac{-{4x}^3}{3}\,;\quad a_n=\frac{(-1)^n(2x)^{2n+1}}{(2n+1)!}\,; $

$https://www.cyberforum.ru/cgi-bin/latex.cgi? a_{n+1}=\frac{(-1)^{n+1}(2x)^{2(n+1)+1}}{(2(n+1)+1)!}=\frac{(-1)(-1)^n(2x)^2(2x)^{2n+1}}{(2n+2)(2n+3)(2n+1)!}=\\\\=\left. \frac{-(2x)^2a_n}{(2n+2)(2n+3)}=\frac{-x^2a_n}{(n+1)(n+1.5)}=\right|_{n:=n+1}=\frac{-x^2a_n}{n(n+0.5)} $

Программа:

1)

Pascal

const lin = '+-----+-----------------+-----------------+-----------------+';
      x0 = 0.1;
var x, a, s, y: real;
    i, j, n: integer;
begin
  repeat
    write('Введите количество членов ряда n > 0; n = ');
    readln(n)
  until n > 0;
  writeln;
  writeln(lin);
  writeln('|  x  |  s, сумма ряда  |  y=sin(2x)-2x   | s-y, погрешность|');
  writeln(lin);
  for i := 0 to 4 do
    begin
      x := x0 + 0.2 * i;
      a := -4 * x * x * x / 3;
      s := a;
      for j := 2 to n do
        begin
          a := -x * x * a / j / (j + 0.5);
          s := s + a
        end;
      y := sin(2 * x) - 2 * x;
      writeln('|', x:4:1, ' |', s:16:12, ' |', y:16:12, ' |', s - y:16:12, ' |')
    end;
  writeln(lin);
  readln
end.

2)

Pascal

const lin = '+-----+-----------------+-----------------+-----------------+';
      x0 = 0.1;
var x, a, s, e, y: real;
    i, n: integer;
begin
  repeat
    write('eps > 0 - точность вычисления суммы ряда; eps = ');
    readln(e)
  until e > 0;
  writeln;
  writeln(lin);
  writeln('|  x  |  s, сумма ряда  |  y=sin(2x)-2x   | s-y, погрешность|');
  writeln(lin);
  for i := 0 to 4 do
    begin
      x := x0 + 0.2 * i;
      a := -4 * x * x * x / 3;
      s := a;
      n := 2; {n:=n+1}
      while abs(a) > e do
        begin
          a := -x * x * a / n / (n + 0.5);
          s := s + a;
          inc(n)
        end;
      y := sin(2 * x) - 2 * x;
      writeln('|', x:4:1, ' |', s:16:12, ' |', y:16:12, ' |', s - y:16:12, ' |')
    end;
  writeln(lin);
  readln
end.

Добавлено через 26 минут

Не по теме:

Арткр, не дублируйте темы. Для того, чтобы поднять актуальность темы, в неё просто нужно написать новое сообщение, например, уточнение задания, или одно слово "Актуально". Создавать новую тему для поднятия актуальности старой темы бессмысленно и запрещено.

Рекомендую Вам перечитать правила форума.

Будете нарушать правила форума - я с Вами нехорошо поступлю.

@Арткр 0 / 0 / 0 Регистрация: 31.03.2015 Сообщений: 6
		1
	Вычислить значение выражения 02.04.2015, 15:50. Показов 1238. Ответов 1 Метки нет (Все метки) $https://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> s=-\frac{(2x)^3}{3!}+...+(-1)^n\cdot \frac{(2x)^{2n+1}}{(2n+1)!}+...\,;\quad y=\sin 2x-2x\,;\quad x\in [0.1,\,0.9]\,;\quad \Delta x=0.2<br />$ Вывести рекуррентную формулу для вычесления членов ряда, для всех "х", принадлежащих [a, b], вычислить и напечатать значения "s" и "y": 1)при заданном n 2)при заданной погрешности вычислений, не превышающей eps. 0

	07.04.2015, 01:19

Опции темы

Вычислить значение выражения

Решение