Построить линейный список из входной последовательности чисел

type Tinf = integer; {тип данных, который будет храниться в элементе списка}
     List = ^TList;  {Указатель на элемент типа TList}
     TList = record {А это наименование нашего типа "запись", обычно динамические структуры описываются через запись}
               data: TInf; {данные, хранимые в элементе}
               next: List {указатель на следующий элемент списка}
             end;
 
{Процедура добавления нового элемента в односвязный список}
procedure AddElem(var spis1: List; znach1: TInf);
var tmp: List;
begin
  if spis1 = nil {Проверяем не пуст ли список, если пуст, то }
    then begin
      GetMem(spis1, sizeof(TList)); {создаём его первый элемент}
      tmp := spis1
    end
    else begin {в случае если список не пуст}
      tmp := spis1;
      while tmp^.next <> nil do tmp := tmp^.next; {ставим tmp на последний элемент списка}
      GetMem(tmp^.next, sizeof(TList)); {создаём следующий элемент}
      tmp := tmp^.next   {переносим tmp на новый элемент}
    end;
  tmp^.next := nil; {зануляем указатель}
  tmp^.data := znach1 {заносим значение}
end;
 
{процедура печати списка}
procedure Print(s: string; spis1: List);
begin
  writeln(s);
  if spis1 = nil {проверка на пустоту списка}
    then begin
      write('Список пуст.');
      exit
    end;
  while spis1 <> nil do {пока указатель spis1 не станет указывать в пустоту}
    begin   {а это произойдёт как только он перейдёт по ссылке последнего элемента}
      Write(spis1^.data:10); {выводить данне}
      spis1 := spis1^.next  {и переносить указатель на следующий элемент}
    end;
  writeln
end;
 
{процедура удаления списка}
Procedure FreeList(spis1: List);
var tmp: List;
begin
  while spis1 <> nil do {пока spis1 не станет указывать в "пустоту" делать}
    begin
      tmp := spis1; {указатель tmp направим на текущий первый элемент}
      spis1 := spis1^.next; {указатель перенесём на следующий элемент}
      FreeMem(tmp, SizeOf(Tlist)) {освободим память, занятую под текущий первый элемент}
    end
end;
 
{процедура перестроения списка}
procedure SortList(spis1: List);
var tmp, negative, positive: List;
begin
  if spis1 = nil then exit; {если список пуст, то сортировать его незачем}
  tmp := spis1; {указатель на начало списка}
  negative := nil; {список отрицательных элементов, пока пустой}
  positive := nil; {список положительных элементов, пока пустой}
  while tmp <> nil do
    begin
      if tmp^.data < 0 {если элемент отрицательный,}
        then AddElem(negative, tmp^.data)  {то добавляем его в список отрицательных элементов,}
        else AddElem(positive, tmp^.data); {иначе добавляем его в список положительных элементов}
      tmp := tmp^.next {перемещаем указатель на следующий элемент}
    end;
  tmp := spis1; {указатель на начало списка}
  {копируем списки}
  while negative <> nil do
    begin
      tmp^.data := negative^.data;
      tmp := tmp^.next;
      negative := negative^.next
    end;
  while positive <> nil do
    begin
      tmp^.data := positive^.data;
      tmp := tmp^.next;
      positive := positive^.next
    end
end;
 
var Spis: List;
    znach: integer;
begin
  Spis := nil;
  writeln('Введите элементы списка (целые числа), окончание ввода - число 0');
  repeat
    write('? ');
    readln(znach);
    if znach <> 0 then AddElem(Spis, znach)
  until znach = 0;
  Print('Исходный список:', Spis);
  SortList(Spis);
  Print('Перестроенный список:', Spis);
  FreeList(Spis);
  readln
end.