Обработка растровых изображений. Фильтры. (PascalABC)

uses ABCObjects,GraphABC;
const
  filterSize = 5;
  half = 2; 
type
  filter = array [0..filterSize-1,0..filterSize-1] of real;
procedure filterApply (s,t: Picture; filterMatrix: filter);
var
  i,j,ip,jp: integer;
  dv: real;
  rr,rg,rb: real;
  pnt: Color;
begin
  dv:=0;
  for i:=0 to filterSize-1 do
    for j:=0 to filterSize-1 do
      dv:= dv + filterMatrix[i,j];
  if dv = 0 then dv:= 1;
  for ip:= half to s.Height-half-1 do
    for jp:= half to s.Width-half-1 do
    begin
      rr:= 0;
      rg:= 0;
      rb:= 0;
      for i:= -half to half do
        for j:= -half to half do
        begin
          pnt:= s.GetPixel(jp+j,ip+i);
          rr:= rr + pnt.R*filterMatrix[i+half,j+half];
          rg:= rg + pnt.G*filterMatrix[i+half,j+half];
          rb:= rb + pnt.B*filterMatrix[i+half,j+half];
        end;
        t.SetPixel(jp,ip,RGB(round(rr/dv),round(rg/dv),round(rb/dv)));
    end; 
end;
 
var
  p,r: Picture;
  blur : filter := ( (1,1,1,1,1),(1,1,1,1,1),(1,1,1,1,1),(1,1,1,1,1),(1,1,1,1,1) );
begin
  p:= new Picture('example.jpg');
  r:= new Picture(p.Width,p.Height);
  filterApply(p,r,blur);
  p.Draw(0,0);
  while true do;
end.