Даны две матрицы размером 3x3. Написать программу получения коммутатора AB-BA и антикоммутатора AB+BA этих матриц

program Project1;
type
  TArr = array [1..3,1..3] of integer;
 
procedure RandomInfInMatrix (var arr: TArr; narr,marr,leftval,rightval: integer);
// Процедура для заполнения двумерного массива случайными числами в заданном диапазоне.
var
   i,j: integer;
begin
for i:= 1 to narr do
    for j:= 1 to marr do
      arr[i,j]:= leftval + random(rightval - leftval + 1) ;
 
end;
 
procedure InfOutMatrix (arr: TArr; narr,marr: integer);
// Процедура для вывода элементов массива на экран.
var
   i,j: integer;
begin
  for i:= 1 to narr do
    begin
    for j:= 1 to marr do
      Write(arr[i,j]:5);
    writeln;
    end;
end;
 
 
procedure MatrixPowMatrix(arr,brr:TArr; narr: integer; var crr: TArr);
// Процедура для перемножения матрицы на матрицу (используются только квадратные матрицы).
var
  i,j,k: integer;
begin
for i:=1 to narr do
  for j:=1 to narr do
    begin
      crr[i,j]:= 0;
      for k:=1 to narr do
        crr[i,j]:= crr[i,j] + arr[i,k]*brr[k,j];
    end;
end;
 
 
procedure MatrixSubtractionAdditionMatrix(arr,brr:TArr; narr,add: integer; var crr: TArr);
// Процедура для вычитания (сложения) матрицы из матрицы (используются только квадратные матрицы).
var
  i,j: integer;
begin
    case add of
      1: begin
           for i:=1 to narr do
             for j:=1 to narr do
                crr[i,j]:= arr[i,j] - brr[i,j];
          end;
      2:  begin
           for i:=1 to narr do
             for j:=1 to narr do
                crr[i,j]:= arr[i,j] + brr[i,j];
          end;
    end;
end;
 
var
  a,b,c1,c2,c3,c4: TArr; // Переменные для хранения двумерных массивов.
  leftv: integer;        // Левая граница диапазона генератора случайных чисел.
  rightv: integer;       // Правая граница диапазона генератора случайных чисел.
 
begin
  randomize;
  leftv:= -10;                            // Значение левой границы диапазона генератора случайных чисел.
  rightv:= 10;                            // Значение правой границы диапазона генератора случайных чисел.
  RandomInfInMatrix(a,3,3,leftv,rightv);  // Заполнение матрицы А случайными числами.
  writeln('Matrix A:');
  InfOutMatrix(a,3,3);                    //  Вывод элементов матрицы А на экран.
  RandomInfInMatrix(b,3,3,leftv,rightv);  //  Заполнение матрицы В случайными числами.
  writeln('Matrix B:');
  InfOutMatrix(b,3,3);                     //  Вывод элементов матрицы В на экран.
  MatrixPowMatrix(a,b,3,c1);               //  Перемножение матрицы А на матрицу В.
  writeln('Matrix C1 = A*B:');
  InfOutMatrix(c1,3,3);                    //  Вывод элементов матрицы С1 на экран.
  MatrixPowMatrix(b,a,3,c2);               //  Перемножение матрицы В на матрицу А.
  writeln('Matrix C2 = B*A:');
  InfOutMatrix(c2,3,3);                     //   Вывод элементов матрицы С2 на экран.
  MatrixSubtractionAdditionMatrix(c1,c2,3,1,c3);   // Вычитание матрицы С2 из матрицы С1.
  writeln('Matrix C3 = AB - BA:');
  InfOutMatrix(c3,3,3);                             // Вывод элементов матрицы С3 на экран.
  MatrixSubtractionAdditionMatrix(c1,c2,3,2,c4);    //  Сложение матрицы С2 с матрицей С1.
  writeln('Matrix C4 = AB + BA:');
  InfOutMatrix(c4,3,3);                             //  Вывод элементов матрицы С4 на экран.
  readln;
end.