Ошибка при выполнении: "Индекс находился вне границ массива"

@AtomJ2 · Регистрация: 11.05.2020

Студворк — интернет-сервис помощи студентам

Здравствуйте всем! Имеется данная программа, при ее выполнении выдается данная ошибка после ввода переменной m:
умножение.pas(22) : Ошибка времени выполнения: Индекс находился вне границ массива.
Когда в первый раз запускаю все почти работает, но на второй и последующие разы выдается эта ошибка.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
------------
program multiplicate;
var a:array[1..101] of longint;
m,i,k,l:integer;
begin
  randomize;
  for i:=1 to 100 do
    a[i] := random(1,9); 
  write('Первый множитель: ');
  for i:=1 to 100 do
    write(a[i]);
  writeln;
  writeln('Введите второй множитель: ');
  readln(m);
  i:=100;
  while i>0 do begin
    a[i]:=a[i]*m;
    if a[i]>9 then begin
      l:=1;
      k:=a[i];
      a[i]:=k mod 10;
      while k>9 do begin
        a[i-l]:=a[i-l]+(k div (Trunc(exp(ln(10)*l))))-(k mod (Trunc(exp(ln(10)*l))));
        l:=l+1;
        k:=k div 10;
      end;
    end;
    i:=i-1;
  end;
  for i:=1 to 100 do
    write(a[i]);
end.

@JuriiMW · 24.10.2020, 14:18

У меня ошибки не выскочило…
Ввёл 2 и получил: -886-868446-46800-2886-2428-4866660026820604262-1088482062-12864480842-1286660284002224-28-246-66048426880002428422

Добавлено через 51 секунду
В чём суть задания?
Приведите его так как его вам задали!

@AtomJ2 · 24.10.2020, 14:34 **[ТС]**

Есть какое-то длинное число, условно состоящее из 100 цифр. Это число представлено в виде элементов массива. Т.е. к примеру первый элемент 3, 2 элемент 6, 3 элемент 7 и т.д., короче не от 1 до 9 включительно. И есть второе число которое помещается в размерность integer. Нужно перемножить эти два числа и вывести результат. Моя идея заключалась в том что я каждый элемент массива (получается, что каждую цифру большого числа) перемножаю на второе число, и в том случае если получившееся число больше 9, то я просто оставляю x mod 10, а оставшуюся часть перебрасываю на следующие элементы пока x не станет </= 9. И так каждый элемент. Естественно, в первом элементе получится большое число. Тут еще думаю что сделать, пока что надо подумать над ошибкой.

@JuriiMW · 24.10.2020, 16:43

AtomJ2, во-первых, вы читать не умеете?
Я же спрашивал:

Сообщение от JuriiMW

Приведите его так как его вам задали!

Я не спрашивал вашего вольного перевода.

Во-вторых, вот тут зачем такая сложность?

Сообщение от AtomJ2

a[i-l]:=a[i-l]+(k div (Trunc(exp(ln(10)*l))))-(k mod (Trunc(exp(ln(10)*l))))

В-третьих, вы используете функцию random(1,9), а это говорит о том, что используете не PascalABC, а PascalABC.NET!
А в последнем есть тип BigInteger, который позволяет легко решить эту задачу:

Pascal
1
2
3
4
## var N := Biginteger.Zero;
N += Random(1,9); loop 99 do N := N * 10 + Random(0,9);
WriteLn(N);
WriteLn(N * ReadInteger);

Ладно. Представим, что вы хотите решить это задание как в ТР.
Тогда давайте с начала:

Число имеет 100 знаков.
Второе число, которое помещается в integer.

В PABC.NET в integer помещаются числа от -2147483648 до +2147483647.
(К сведению, тип longint в этом IDE является синонимом integer. Поэтому смысл использовать longint вместо integer совершенно отсутствует.)

Значит к 100 знакам нужно добавить ещё 10 значащих цифр (9·2147483647=19327352823).

Хотя это не важно! Мы вполне можем зарезервировать и 200 и хоть 2000 под значащие символы.
Но хранить будем по одной цифре в каждой ячейке числа, а в нулевой ячейке будем хранить число значащих цифр.

Pascal
1
2
3
4
const
  maxLengthInteger = 1000;
type
  tLongInteger = array [0..maxLengthInteger] of Integer;

Теперь создадим случайное число заданной длины, в котором могут быть любые цифры (в т.ч. и 0, но только не первый):

Pascal
1
2
3
4
5
6
7
function RandomLong(L : Integer) : tLongInteger;
begin
  for var i := 1 to L-1 do
    Result[i] := Random(0,9);
  Result[L] := Random(1,9);
  Result[0] := L;
end;

Нужно ещё вывести полученное число:

Pascal
1
2
3
4
5
procedure OutLong(L : tLongInteger);
begin
  for var i := L[0] downto 1 do Write(L[i]);
  WriteLn;
end;

Заготовка есть:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
const
  maxLengthInteger = 1000;
  genLength = 10;
type
  tLongInteger = array [0..maxLengthInteger] of Integer;
  
function RandomLong(L : Integer) : tLongInteger;
begin
  for var i := 1 to L-1 do
    Result[i] := Random(0,9);
  Result[L] := Random(1,9);
  Result[0] := L;
end;
 
procedure OutLong(L : tLongInteger);
begin
  for var i := L[0] downto 1 do Write(L[i]);
  WriteLn;
end;
 
var
  Long : tLongInteger;
begin
  Randomize;
  Long := RandomLong(GenLength);
  OutLong(Long);
end.

Теперь создадим функцию, которая умножает длинное число на одну цифру:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
function MulN(N : Integer; L : tLongInteger) : tLongInteger;
begin
  var d := 0; // Это чтобы выполнять перенос.
  for var i := 1 to L[0] do
    begin
      d := d + L[i] * N;
      Result[i] := d mod 10;
      d := d div 10;
    end;
  Result[0] := L[0];
  if d > 0 then // при умножении на одну цифру, если добавится, то только одна цифра
    begin
      Inc(Result[0]);
      Result[Result[0]] := d;
    end;
end;

Вернее цифра, на которую умножаем, идёт первой.
Ещё потребуется умножение на 10, создание копии числа и сложение двух длинных чисел:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
const
  maxLengthInteger = 1000;
  genLength = 10;
type
  tLongInteger = array [0..maxLengthInteger] of Integer;
 
function CreateLong : tLongInteger;
begin
  Result[0] := 1;
  Result[1] := 0;
end;
  
function RandomLong(L : Integer) : tLongInteger;
begin
  for var i := 1 to L-1 do
    Result[i] := Random(0,9);
  Result[L] := Random(1,9);
  Result[0] := L;
end;
 
procedure OutLong(L : tLongInteger);
begin
  for var i := L[0] downto 1 do Write(L[i]);
  WriteLn;
end;
 
function MulN(N : Integer; L : tLongInteger) : tLongInteger;
begin
  var d := 0; // Это чтобы выполнять перенос.
  for var i := 1 to L[0] do
    begin
      d := d + L[i] * N;
      Result[i] := d mod 10;
      d := d div 10;
    end;
  Result[0] := L[0];
  if d > 0 then // при умножении на одну цифру, если добавится, то только одна цифра
    begin
      Inc(Result[0]);
      Result[Result[0]] := d;
    end;
end;
 
procedure Mul10(var L : tLongInteger);
begin
  Inc(L[0]);
  for var i := L[0] downto 2 do
    L[i] := L[i-1];
  L[1] := 0;
end;
 
function CopyLong(L : tLongInteger) : tLongInteger;
begin
  Result[0] := L[0];
  for var i := 1 to L[0] do
    Result[i] := L[i];
end;
 
function AddLong(A, B :tLongInteger) : tLongInteger;
begin
  var d := 0;
  for var i := 1 to Min(A[0], B[0]) do
    begin
      d := d + A[i] + B[i];
      Result[i] := d mod 10;
      d := d div 10;
    end;
  if A[0] > B[0] then
    for var i := B[0] + 1 to A[0] do
      begin
        d := d + A[i];
        Result[i] := d mod 10;
        d := d div 10;
      end
  else if A[0] < B[0] then
    for var i := A[0] + 1 to B[0] do
      begin
        d := d + B[i];
        Result[i] := d mod 10;
        d := d div 10;
      end;
  Result[0] := Max(A[0], B[0]);
  if d > 0 then
    begin
      Inc(Result[0]);
      Result[Result[0]] := d;
    end;
end;
 
var
  Long, Res : tLongInteger;
begin
  Randomize;
  Long := RandomLong(GenLength);
  OutLong(Long);
  var N := ReadInteger;
  // получим число с переставленными цифрами в обратном порядке:
  var n0 := n;
  var r := 0;
  repeat
    r := r * 10 + n0 mod 10;
    n0 := n0 div 10;
  until n0 = 0;
  // создадим число 0
  Res := CreateLong;
  repeat
    Mul10(Res); // умножить на 10
    Res := AddLong(Res, MulN(r mod 10, Long)); // сложить два числа: результат и умноженное на цифру
    r := r div 10;
  until r = 0;
  // готово
  OutLong(Res);
end.

Добавлено через 3 минуты
У меня осталось после отладки длина числа 10 цифр (genLength), но вы можете его заменить спокойно на 100 (или 200 (или 300)) и без проблем получить результат.
Хотя для проверки правильности (с помощью обыкновенного калькулятора) нужна небольшая длина.

@AtomJ2 · 24.10.2020, 16:46 **[ТС]**

Да, я ошибся что-то. Прошу прощения!
Спасибо Вам огромное за решение!
Удачи!

Новые блоги и статьи Все статьи Все блоги /
Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .	Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .	Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .
Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .	Фото: Daniel Greenwood kumehtar 13.11.2025	Расскажи мне о Мире, бродяга kumehtar 12.11.2025 — Расскажи мне о Мире, бродяга, Ты же видел моря и метели. Как сменялись короны и стяги, Как эпохи стрелою летели. - Этот мир — это крылья и горы, Снег и пламя, любовь и тревоги, И бескрайние. . .

@JuriiMW 5095 / 2661 / 2355 Регистрация: 10.12.2014 Сообщений: 10,059
	24.10.2020, 14:18
	У меня ошибки не выскочило… Ввёл 2 и получил: -886-868446-46800-2886-2428-4866660026820604262-1088482062-12864480842-1286660284002224-28-246-66048426880002428422 Добавлено через 51 секунду В чём суть задания? Приведите его так как его вам задали! 0

@AtomJ2 5 / 3 / 2 Регистрация: 11.05.2020 Сообщений: 47
	24.10.2020, 14:34 [ТС]
	Есть какое-то длинное число, условно состоящее из 100 цифр. Это число представлено в виде элементов массива. Т.е. к примеру первый элемент 3, 2 элемент 6, 3 элемент 7 и т.д., короче не от 1 до 9 включительно. И есть второе число которое помещается в размерность integer. Нужно перемножить эти два числа и вывести результат. Моя идея заключалась в том что я каждый элемент массива (получается, что каждую цифру большого числа) перемножаю на второе число, и в том случае если получившееся число больше 9, то я просто оставляю x mod 10, а оставшуюся часть перебрасываю на следующие элементы пока x не станет </= 9. И так каждый элемент. Естественно, в первом элементе получится большое число. Тут еще думаю что сделать, пока что надо подумать над ошибкой. 0

@AtomJ2 5 / 3 / 2 Регистрация: 11.05.2020 Сообщений: 47
	24.10.2020, 16:46 [ТС]
	Да, я ошибся что-то. Прошу прощения! Спасибо Вам огромное за решение! Удачи! 0

Ошибка при выполнении: "Индекс находился вне границ массива"

Решение