Как добавлять и удалять элементы из очереди? - PascalABC.NET - Ответ 10550045

unit Graph;
 
uses GraphABC;
 
const
  Radius = 5;
 
type
  ///Location object
  Location = class
  private 
    dx, dy: integer;
    
    function XpositionRead()  := dx;
    
    function YpositionRead()  := dy;
    
    procedure XpositionWrite(v: integer);
    begin
      dx := v;
    end;
    
    procedure YpositionWrite(v: integer);
    begin
      dy := v;
    end;
  
  public 
    constructor(x, y: integer);
    begin
      dx := x;dy := y;
    end;
    
    ///X
    property Xposition: integer read XpositionRead write XpositionWrite;
    ///Y
    property Yposition: integer read YpositionRead write YpositionWrite;
  end;
  
  
  ///Graph's vertex
  GraphVertex = class
  private 
    p: Location;
    n: string;
    marked: boolean;
    Lev: integer;
    function PositionRead()  := p;
    
    procedure PositionWrite(v: Location);
    begin
      p := v;
    end;
    
    function NameRead()  := n;
    
    procedure NameWrite(v: string);
    begin
      n := v;
    end;
    
    function IsMarkedRead()  := marked;
    
    procedure IsMarkedWrite(v: boolean);
    begin
      marked := v;
    end;
    
    function LevelRead()  := Lev;
    
    procedure LevelWrite(v: integer);
    begin
      Lev := v;
    end;
  
  public 
    ///List of linked vertexes
    Vertexes: array of GraphVertex;
    
    constructor(x, y: integer);
    begin
      p := new Location(x, y); marked:=false;
    end;
    
    ///Position of the vertex
    property Position: Location read PositionRead write PositionWrite;
    ///Vertex'es name
    property Name: string read NameRead write NameWrite;
    ///The vertex is marked
    property IsMarked: boolean read IsMarkedRead write IsMarkedWrite;
    ///Level value (for DFS and other seaching algorithms)
    property Level: integer read LevelRead write LevelWrite;
    
    ///Draw free vertex
    procedure Draw(v: GraphVertex);
    begin
      SetPenColor(clBlack);
      SetPenWidth(1);
      SetBrushColor(clRed);
      FillCircle(v.Position.Xposition, v.Position.Yposition, Radius);
      DrawCircle(v.Position.Xposition, v.Position.Yposition, Radius);
      SetBrushColor(ARGB(0, 0, 0, 0));
      TextOut(v.Position.Xposition + 10, v.Position.Yposition + 10, v.Name+' L:'+IntToStr(Lev));
    end;
    
    ///Draw all vertexes, those are liked to the current vertex.
    procedure DrawLinked();
    begin
      for var i := 0 to Length(Vertexes) - 1 do Draw(Vertexes[i]);
    end;
    
    ///Draw vertex
    procedure DrawSelf() := Draw(self);
    
    ///Draw all lines those connect the current vertex to the others
    procedure DrawLines();
    begin
      Draw(self);
      for var i := 0 to Length(Vertexes) - 1 do
        if Vertexes[i] <> nil then
          Line(self.Position.Xposition, self.Position.Yposition, self.Vertexes[i].Position.Xposition, self.Vertexes[i].Position.Yposition);
    end;
    
    ///Add new vertex
    procedure AddVertex(v: GraphVertex);
    begin
      SetLength(Vertexes, Length(Vertexes) + 1);
      Vertexes[Length(Vertexes) - 1] := v;
    end;
    
    ///Add new vertex in any array
    class procedure AddVertex(var a: array of GraphVertex; v: GraphVertex);
    begin
      SetLength(a, Length(a) + 1);
      a[Length(a) - 1] := v;
    end;
    
    ///Replace the first vertex with the second one
    procedure ResetVertex(v, v2: GraphVertex);
    var
      l, i: integer;
    begin
      l := Length(Vertexes);
      i := 0;
      while (i < l) and (Vertexes[i] <> v) do Inc(i);
      Vertexes[i] := v2;
    end;
    
    ///Replace the first vertex with the second one in any array
    procedure ResetVertex(var a: array of GraphVertex; v, v2: GraphVertex);
    var
      l, i: integer;
    begin
      l := Length(a);
      i := 0;
      while (i < l) and (a[i] <> v) do Inc(i);
      a[i] := v2;
    end;
    
    ///Get vertex by it's id (name).
    class function GetVertex(a: array of GraphVertex; id: string): GraphVertex;
    var
      l, i: integer;
    begin
      l := Length(a);
      i := 0;
      while (i < l) and (a[i].Name <> id) do Inc(i);
      if i < l then GetVertex := a[i] else GetVertex := nil;
    end;
    
    ///Get all marked (not marked) vertexes from Vertexes.
    function GetMarkedVertexes(t: boolean): array of GraphVertex;
    var
      a: array of GraphVertex;
    begin
      for var i := 0 to Length(Vertexes) - 1 do
        if Vertexes[i].IsMarked = t then AddVertex(a, Vertexes[i]);
      GetMarkedVertexes := a;
    end;
  end;
end.