Найти в массиве минимальный по модулю элемент. Заменить им элементы с нечетными номерами - Assembler - Ответ 11252692

@stack  segment para stack
        db      1024 dup(?)
@stack  ends
 
@data   segment
        A       dw      15, -58, 61, 88, -70, -96, 75, -14
        LenA    equ     ($-A)/2
@data   ends
 
@code   segment
        assume  cs:@code, ds:@data, ss:@stack
main    proc
        ;инициализация сегментного регистра данных
        mov     ax,     @data
        mov     ds,     ax
        ;поиск минимального по модулю элемента
        mov     cx,     LenA
        lea     si,     [A]
        call    GetMinAbs
        ;замена на это значение всех элементов с нечётными номерами
        mov     cx,     LenA
        lea     si,     [A]
        mov     ax,     ax
        call    Replace
        ;завершение программы
        mov     ax,     4C00h
        int 21h
main    endp
 
;Функция возвращает минимальный по модулю элемент массива
;на входе:
;  cx    - длина массива
;  ds:si - адрес массива
;на выходе:
;  ax    - минимальный по модулю элемент
GetMinAbs       proc
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     dx,     0       ;если элементов нет
        jcxz    @@BreakMin      ;результат (-1) и выйти
 
        mov     ax,     [si]    ;ax:=abs(A[0])
        neg     ax
        jl      $-2
        mov     bx,     ax      ;bx:=abs(A[0])
        mov     dx,     [si]    ;dx:=A[0]
        ;пропускаем первый элемент (с индексом 0)
        dec     cx
        jcxz    @@BreakMin
        add     si,     2
        @@FindMin:
                mov     ax,     [si]    ;ax:=abs(A[i])
                neg     ax
                jl      $-2
 
                cmp     ax,     bx      ;if MinAbs>abs(A[si])
                jae     @@NextMin       ;  then
                mov     bx,     ax      ;    MinAbs:=abs(A[si])
                mov     dx,     [si]    ;    dx:=A[si]
 
        @@NextMin:
                add     si,     2
        loop    @@FindMin
@@BreakMin:
 
        mov     ax,     dx
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        ret
GetMinAbs       endp
 
;Процедура заменяет элементы с нечётными индексами на заданное число
;на входе:
;  cx    - длина массива
;  ds:si - адрес массива
;  ax    - число, на которое будут заменнены элементы массива
;на выходе:
;  -
Replace         proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     di,     0
        @@Change:
                test    di,     1
                jz      @@Next
 
                mov     [si],   ax
 
        @@Next:
                add     si,     2
                add     di,     1
        loop    @@Change
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Replace         endp
 
@code   ends
 
        end     main